Office: (Office 2013) Macro: Zeile einer Tabelle in Word bearbeiten

Hallo,

ich suche ein Marco, welches in einer Tabelle in Word 2013 alle Zeilen mit dem Wert #1# (oder einem anderen Wert, den kann ich selbst definieren) sucht, den Text dieser Zeilen fett markiert, alle Zellen dieser Zeile verbindet und den Begriff #1# aus der Zeile löscht.

Ich suche nach Beispielen, finde aber nicht wirklich etwas dazu. Jemand eine Idee?

 

Hallo Gernot,

ich wage mal einen Schuss ins Blaue. Wenn er nicht funktioniert oder nicht das tut, was du dachtest, beantworte bitte folgende Fragen, am besten mit Musterdokument:

• Hat die Tabelle bereits verbundene Zellen?
• Kann der Wert #1# in einer beliebigen Zelle einer Zeile stehen oder muss er in einer bestimmten stehen?
• Oder muss er sogar in allen Zellen einer Zeile stehen?

Aber hier erst mal der Schuss:

Code:

Sub TabelleBearbeiten()
'Schreibmarke muss irgendwo in der Tabelle stehen

Dim anzZeilen As Long, i As Long
Dim suchBereich As Range
Dim ohneAbsatz As String
    
    'Ausstieg, wenn Schreibmarke nicht in Tabelle
    If Selection.Information(wdWithInTable) = False Then
        MsgBox "Bitte die Schreibmarke in die zu durchsuchende Tabelle setzen!"
        Exit Sub
    End If

anzZeilen = Selection.Tables(1).Rows.Count

        'zeilenweise suchen
        For i = 1 To anzZeilen
            Set suchBereich = Selection.Tables(1).Rows(i).Range
        
            With suchBereich.Find
                .Text = "#1#"
                .Replacement.Text = ""
                .Execute Replace:=wdReplaceAll
            End With
                
                'bei Treffer: fett, verbinden...
                If suchBereich.Find.Found = True Then
                   With Selection.Tables(1)
                        .Rows(i).Range.Font.Bold = True
                        .Rows(i).Range.Cells.Merge
                        
                        '..und Folgendes nur bei Bedarf: Ersetze Absätze durch Leerzeichen
                        ohneAbsatz = Replace(.Rows(i).Range.Text, Chr(13), " ")
                        .Rows(i).Range.Text = ohneAbsatz
                    End With
                End If
        Next i
   
End Sub