Office: Einträge mengengenau erzwingen

Helfe beim Thema Einträge mengengenau erzwingen in Microsoft Excel Tutorials um das Problem gemeinsam zu lösen; Einleitung Es gibt Themen, bei denen alle Teilnehmer einer Menge genau einmal jedoch nichts darüber hinaus ausgewählt werden müssen. Beispiele und... Dieses Thema im Forum "Microsoft Excel Tutorials" wurde erstellt von lupo1, 19. November 2017.

  1. lupo1
    lupo1 Tutorial Guru

    Einträge mengengenau erzwingen


    Einleitung

    Es gibt Themen, bei denen

    • alle Teilnehmer einer Menge genau einmal
    • jedoch nichts darüber hinaus
    ausgewählt werden müssen.

    Beispiele und Lösungen

    Nehmen wir die Vergabe von Schichten F,T,S,N eines Tages auf sechs Mitarbeiter in A1:A6.

    In A8 ergibt sich 1 (für zulässig) xOder 0 (für unzulässig), ben.def. oder bed. formatierbar.

    Variante 1: Jede dieser Schichten soll genau einmal vergeben werden:

    A8: =
    (ANZAHL2(A1:A6)=4)*
    PRODUKT(ZÄHLENWENN(A1:A6;{"F";"N";"S";"T"}))


    Erklärung der Formel:
    • PRODUKT sorgt dafür, dass jeder der 4 Buchstaben mindestens einmal berücksichtigt wird
    • ANZAHL2=4 sorgt dafür, dass a) keine Fremdeinträge zusätzlich bestehen, und dass b) gleichzeitig auch "höchstens je einmal" gilt

    Variante 2: Entweder soll das Set F,S oder das Set T,N gewählt sein:

    A8: =
    (ANZAHL2(A1:A6)=2)*(
    PRODUKT(ZÄHLENWENN(A1:A6;{"F";"S"}))+
    PRODUKT(ZÄHLENWENN(A1:A6;{"T";"N"})))


    Erklärung der Formel:
    • PRODUKT sorgt dafür, dass jeder der 2 Buchstaben des gewählten Sets mindestens einmal berücksichtigt wird
    • ANZAHL2=2 funktioniert entsprechend Variante 1

    Variante 3: Entweder Schichtdienst F,S,N zu dritt oder Tagesdienst T mit einer Person:

    A8: =
    (ANZAHL2(A1:A6)=3)*PRODUKT(ZÄHLENWENN(A1:A6;{"F";"S";"N"}))+
    (ANZAHL2(A1:A6)=1)*PRODUKT(ZÄHLENWENN(A1:A6;"T"))


    Erklärung der Formel:
    • PRODUKT kann im zweiten Term (Sonderfall: Nur ein Eintrag) auch weggelassen werden (Unterstreichung)
    • ANZAHL2 muss jedem Term einzeln zugeordnet werden, da die Anzahlen von Zwangseinträgen mit 3 oder 1 jetzt unterschiedlich sind

    Variante 4: Entweder genau 5 Leute im Schichtdienst F,S,S,N,N oder genau 4 im Tagesdienst T,T,T,T:

    A8: =
    (ANZAHL2(A1:A6)=5)*PRODUKT(N(ZÄHLENWENN(A1:A6;{"F";"S";"N"})={1;2;2}))+
    (ANZAHL2(A1:A6)=4)*PRODUKT(N(ZÄHLENWENN(A1:A6;"T")=4))


    Erklärung der Formel:
    • ist anhand der Vorgänger selbsterklärend
    • Jeder durch + getrennte Term kann auch für sich allein funktionieren

    Variante 5: Weg vom Schichtdienst: Aus 5 Paaren müssen 2 genannt werden (10 Kombinationen sind möglich, z.B. EFIJ oder ABGH):

    A8: =N(0<(ANZAHL2(A1:A6)=4)*(
    PRODUKT(ZÄHLENWENN(A1:A6;{"A";"B"}))+
    PRODUKT(ZÄHLENWENN(A1:A6;{"C";"D"}))+
    PRODUKT(ZÄHLENWENN(A1:A6;{"E";"F"}))+
    PRODUKT(ZÄHLENWENN(A1:A6;{"G";"H"}))+
    PRODUKT(ZÄHLENWENN(A1:A6;{"I";"J"}))))



    Veranlasst durch:
    http://www.herber.de/forum/archiv/1588to1592/t1591632.htm#1591711
     
    Zuletzt bearbeitet: 19. November 2017
Thema:

Einträge mengengenau erzwingen

Die Seite wird geladen...
  1. Einträge mengengenau erzwingen - Similar Threads - Einträge mengengenau erzwingen

  2. Zähle Einträge die in einen Uhrzeitbereich liegen

    in Microsoft Excel Hilfe
    Zähle Einträge die in einen Uhrzeitbereich liegen: Hallo zusammen, ich bin in excel absoluter beginner. ich habe mir für die steuerberechnung eine kleine tabelle angefertigt die diverse inhalte berechnet und ich diese zur abgabe an das finanzamt...
  3. Letzten Eintrag aus verschiedenen Zellen in A1

    in Microsoft Excel Hilfe
    Letzten Eintrag aus verschiedenen Zellen in A1: Hallo an alle, Brauche bitte Hilfe. Ich möchte, dass in Zelle A2 immer der letzte Eintrag aus Zelle B2 bis K2 steht. Das heißt, wenn ich in E2 zum Beispiel "456" schreibe, dann soll es in A2...
  4. Bedingte Formatierung, Leere Zelle ab best. Zeit einfärben und bei Eintrag Farbe weg.

    in Microsoft Excel Hilfe
    Bedingte Formatierung, Leere Zelle ab best. Zeit einfärben und bei Eintrag Farbe weg.: Guten Tag, ich habe, eigentlich, ein simples Problem und bekomme einfach nicht die Funktion korrekt geschrieben. Ich würde gerne eine Bedingte Formatierung durchführen für eine Zelle, die Bezug...
  5. zu jedem Eintrag einer drop & down Liste ein bestimmter Betrag in der Nebenspalte

    in Microsoft Excel Hilfe
    zu jedem Eintrag einer drop & down Liste ein bestimmter Betrag in der Nebenspalte: Hallo Zusammen, ich bräuchte bitte Hilfe, steh total an und finde keine Lösung.... ich habe eine kleine einfache drop & down Liste mit 4 Einträgen, je nachdem welchen Eintrag man auswählt, soll in...
  6. VBA - Wenn Eintrag in Spalte vorhanden dann aktualisieren, sonst neue Zeile

    in Microsoft Excel Hilfe
    VBA - Wenn Eintrag in Spalte vorhanden dann aktualisieren, sonst neue Zeile: Hallo an Alle, ich habe ein Problem und finde keine Lösung in den Foren. Ich hoffe, dass mir jemand hier helfen kann. Ich habe in einer Datei zwei Blätter - eins "TC_Template" ist optisch wie...
  7. Felder markieren, wenn Eintrag nicht gleich ist

    in Microsoft Excel Hilfe
    Felder markieren, wenn Eintrag nicht gleich ist: Hallo Community, ich bin noch relativ neu im Thema Excel und hänge gerade an einer Anforderung: In einer Tabelle gibt es eine Spalte mit den Kürzeln für die Geschlechter M W D. Es soll farbig...
  8. Eintrag im RibbonMenü per VBA

    in Microsoft PowerPoint Hilfe
    Eintrag im RibbonMenü per VBA: Hallo zusammen, ich würde gerne mit einem PPT-VBA-Add-in beim Öffnen von PowerPoint einen Eintrag im RibbonMenü vornehmen lassen. Damit die Funktionen des AddIns generell genutzt werden können....
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden