Ergebnis 1 bis 1 von 1

Thema: Kalender mit nur einer Formel

  1. #1
    Office-Hilfe.com - Durchblicker
    Registriert seit
    30.12.2016
    Beiträge
    231

    Kalender mit nur einer Formel

    a) Folgender Kalender benötigt 37 Plätze für die Tage, damit gleiche Wochentage der Monate nebeneinander stehen:

    A1[:X38]: =WAHL(1+(ZEILE()>1)+(SPALTE()>1)*2;2018;
    TEXT(REST(ZEILE()-2;7);"TTT");
    TEXT("1."&REST(SPALTE()-2;12)+1;"MMM");WENN(REST("1."
    &A$1&-($A$1+KÜRZEN((SPALTE()-2)/12));7)=ZEILE()-2;1;WENN(ISTZAHL(
    INDEX(A:A;ZEILE()-1))*ISTZAHL(--(
    INDEX(A:A;ZEILE()-1)+1&"."
    &A$1&-($A$1+KÜRZEN((SPALTE()-2)/12))));
    INDEX(A:A;ZEILE()-1)+1;"")))


    b) Der zweite Kalender benötigt nur 31 Plätze, wie üblich:

    A1[:X32]: =WAHL(1+(ZEILE()>1)+(SPALTE()>1)*2;2018;"";
    TEXT("1."&REST(SPALTE()-2;12)+1;"MMM");TEXT(WENN(ISTZAHL(
    --((ZEILE()-1)&"."&A$1&"."&($A$1+KÜRZEN((SPALTE()-2)/12))));
    --((ZEILE()-1)&"."&A$1&"."&($A$1+KÜRZEN((SPALTE()-2)/12)));"");"TTT TT"))


    Beide Kalender werden bis X statt nur bis M ausgefüllt (also über 23 statt 12 Monate). Damit kann der Kalenderjahres-Beginn auf jeden anderen der 12 Monate verschoben sein, wofür man die nicht zutreffenden Spalten einfach ausblendet.

    Das Jahr steht als Konstante in der Formel, benötigt also keine eigene Zelle.

    Die Formel selbst bedient mittels WAHL 4 verschiedene Felder: Eck-Titel, Vorspalte, Kopfzeile, Werte.

    http://www.excelformeln.de/formeln.html?welcher=284 hat auch so etwas.

    Hier noch eine Verkürzung von a), die allerdings nicht so simpel zu kopieren ist:
    • A2[:X39]:
      =WAHL(MIN(3;ZEILE())*2+(SPALTE()>1)-1;2018;DATUM($A2;SPALTE()-1;1);;;TEXT(REST(ZEILE()-3;7);"TTT");((TEXT(A$1;"TTT")=$A2)*(ZEILE(A2)<10)*A$1+(A1+1)*(A1>31))*(TAG(MONATSENDE(A$1;0))>TAG(A1)))
    • Kopiere Zeile 2 auf Zeile 1. Achtung: Dadurch entstehen absichtlich #BEZUG!-Fehler.
    • B2[:X39]: benDefFmt T;;
    • B1[:X1]: benDefFmt MMM
    Geändert von lupo1 (21.10.2018 um 10:11 Uhr)

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •  
Excel Ticker - News, Tipps und Tricks zu Microsoft Excel | SMS kostenlos versenden | Forenuser - Die Foren Findmaschine