Office: Daten dynamisch blockweise sortieren (mit SORTIEREN und INDEX; auch LET möglich)

Helfe beim Thema Daten dynamisch blockweise sortieren (mit SORTIEREN und INDEX; auch LET möglich) in Microsoft Excel Tutorials um das Problem gemeinsam zu lösen; In einer Zeile stehen 5er-Blöcke beginnend mit je einer PKW-Marke wie folgt: A1:AI1: VW 1 3 2 4 BMW 2 1 3 4 Mercedes 2 4 3 1 Opel 1 2 3 4 Ford 4 3 2 1... Dieses Thema im Forum "Microsoft Excel Tutorials" wurde erstellt von lupo1, 21. Juli 2020.

  1. lupo1
    lupo1 Tutorial Guru

    Daten dynamisch blockweise sortieren (mit SORTIEREN und INDEX; auch LET möglich)


    In einer Zeile stehen 5er-Blöcke beginnend mit je einer PKW-Marke wie folgt:

    A1:AI1: VW 1 3 2 4 BMW 2 1 3 4 Mercedes 2 4 3 1 Opel 1 2 3 4 Ford 4 3 2 1 Porsche 4 1 3 2 Audi 3 2 1 4

    Diese Blöcke sollen nach PKW-Marke umsortiert werden in:

    A2:AI2: Audi 3 2 1 4 BMW 2 1 3 4 Ford 4 3 2 1 Mercedes 2 4 3 1 Opel 1 2 3 4 Porsche 4 1 3 2 VW 1 3 2 4

    Das kann man mit einer einzigen Formel wie folgt:

    A2: =INDEX(SORTIEREN(INDEX(1:1;SEQUENZ(7;;1;5)+SEQUENZ(;5;0)));SEQUENZ(;35;5)/5;REST(SEQUENZ(;35;0);5)+1)

    In dieser Formel sind die Parameter 5 (Blocklänge) und 7 (Anzahl Blöcke) hart hineingeschrieben und müssten nun bei Änderungen überall händisch geändert werden.
    ____________________________
    Hier kommt - nach der Formelverkürzungs-Eigenschaft - eine zweite mögliche LET-Eigenschaft zum Tragen:

    A2: =LET(a;7;b;5;INDEX(SORTIEREN(INDEX(1:1;SEQUENZ(a;;1;b)+SEQUENZ(;b;0)));SEQUENZ(;a*b;b)/b;REST(SEQUENZ(;a*b;0);b)+1))

    Fehlervermeidend trägt man die Strukturparameter nur noch einmal vorn in der Formel ein!

    Stehen die Daten in einer Spalte A1:A35, ergibt sich entsprechend in Blöcken sortiert:

    B1: =LET(c;7;b;5;INDEX(SORTIEREN(INDEX(A:A;SEQUENZ(c;;1;b)+SEQUENZ(;b;0)));SEQUENZ(c*b;;b)/b;REST(SEQUENZ(c*b;;0);b)+1))

    Achtung: Warum c statt a? Leider kann LET die Registervariable a nicht vom Bereich A:A unterscheiden! Ein Bug? Abhilfe läge nur darin, A1:A9999 statt A:A zu verwenden. Also: Vorsicht bei zu kurzen Variablennamen und ganzen Spaltenreferenzen in einer LET-Formel! EDIT: Es ist kein Bug, sondern gewollt so, denn die Variable kann auch ein Anker innerhalb von Anker:Anker sein!

    Nachbemerkung: Lässt man das äußere INDEX() weg, bekommt man die Daten in auswertbarer Matrixanordnung.
     
    Zuletzt bearbeitet: 22. Juli 2020
    lupo1, 21. Juli 2020
    #1
Thema:

Daten dynamisch blockweise sortieren (mit SORTIEREN und INDEX; auch LET möglich)

Die Seite wird geladen...
  1. Daten dynamisch blockweise sortieren (mit SORTIEREN und INDEX; auch LET möglich) - Similar Threads - Daten dynamisch blockweise

  2. Ausgewählte daten aus Datenschnitt in Zelle anzeigen

    in Microsoft Excel Hilfe
    Ausgewählte daten aus Datenschnitt in Zelle anzeigen: Moin, ich erstelle gerade ein dynamisches Dashboard und habe dafür in der obersten Zeile eine Übersicht über die grundlegenden Daten erstellt. Nun würde ich dort innerhalb einer Zelle gerne die...
  3. Dynamische Daten

    in Microsoft Excel Hilfe
    Dynamische Daten: Hey zusammen, ich bräuchte mal Hilfe zu folgenden zwei Themen (ich muss dazu etwas ausholen - sorry dafür): ich habe zwei Excel-Dateien bei denen sich öfters der dateinamen und der Speicherort...
  4. Dynamischen Tabelle Daten entnehmen

    in Microsoft Excel Hilfe
    Dynamischen Tabelle Daten entnehmen: Hallo Profis, ich suche eine effektive Methode um bei sehr großen und dynamischen Tabellen eine Kategorie in ein neues Arbeitsblatt zu filtern. In der Spalte A sieht es in etwa so aus:...
  5. Uform Dynamisch nachladen klappt aber mit falschen Daten

    in Microsoft Access Hilfe
    Uform Dynamisch nachladen klappt aber mit falschen Daten: Hallo zusammen ich hab hier ein HF mit mehreren UF welche ich aus Geschwindigkeitsgründen ggfs dynamisch während der Laufzeit des HF nachladen möchte. Die UF´s sind relativ komplex was Code und...
  6. Word/Excel Formulare mit dynamischen Abruf von Daten aus geschlossenen Excel Dateien

    in Microsoft Excel Hilfe
    Word/Excel Formulare mit dynamischen Abruf von Daten aus geschlossenen Excel Dateien: Hallo zusammen, ich hoffe bei euch ist alles gut. Ich möchte verschiedene gesicherte Formulare in denen lediglich bestimmte Felder/Zellen bearbeitet werden können (Word oder Excel, am liebsten...
  7. Word Formular dynamisch mit Daten aus Access fuellen

    in Microsoft Access Hilfe
    Word Formular dynamisch mit Daten aus Access fuellen: Guten Morgen, ich muss gleich vorweg sagen, ich bin ein aboluter Access-Legastheniker und habe leider auch von VBA so gar keine Ahnung. Also bitte seid geduldig mit mir ;) Ein Kollege...
  8. Excel Daten Dynamisch anpassen

    in Microsoft Excel Hilfe
    Excel Daten Dynamisch anpassen: Ich habe eine Excel Datei, welche sich Daten aus einer anderen Datei zieht diese Formatiert und nach einem Muster zusammenrechnet. Nun habe ich folgendes Problem: Im Blatt 1 wird die Summe von...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden