Button der eine gewünschte Word Datei öffnet :: Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office

Einloggen, um private Nachrichten zu lesen

Downloads

[Access 2002] Button der eine gewünschte Word Datei öffnet

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Access Hilfe

Autor

Nachricht

cgsk01
Newbie
Newbie

Anmeldedatum: 26.08.2008
Beiträge: 7
Wohnort: Insel Poel

Verfasst am: 24.09.2008, 10:24

Hallo ACCESS-Junkies Shocked

,

ich brauche dringend eure Hilfe!!!

Wie kann ich in einem Access 2002-Formular einen Button erstellen, der mich beim Klicken direkt automatisch in eine WORD Datei bringt?

Ich habs soweit schon mit der Hyperlink Funktion hinbekommen, aber es müsste ja auch irgendwie anders gehen...?!?

Für eure Hilfe im Voraus schonmal danke.

MfG cgsk01

miriki
Schlauberger

Anmeldedatum: 05.03.2007
Beiträge: 432
Wohnort: Kiel

Verfasst am: 24.09.2008, 12:21

cgsk01 hat Folgendes geschrieben:

Wie kann ich in einem Access 2002-Formular einen Button erstellen, der mich beim Klicken direkt automatisch in eine WORD Datei bringt?

damit:

Code:

Option Compare Database

Private Const SE_ERR_NOASSOC As Long = 31&

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
ByVal hWnd As Long, _
ByVal Operation As String, _
ByVal Filename As String, _
Optional ByVal Parameters As String, _
Optional ByVal Directory As String, _
Optional ByVal WindowsStyle As Long = vbMaximizedFocus _
) As Long

Public Function LaunchDocument( _
ByRef Filename As String, _
Optional ByVal ParentForm As Form, _
Optional ByVal ShowOpenWithDialog As Boolean = False, _
Optional ByVal WindowStyle As VBA.VbAppWinStyle = vbMaximizedFocus _
) As Boolean

Dim lSuccess As Long
Dim hWndParent As Long

If Not ParentForm Is Nothing Then
hWndParent = ParentForm.hWnd
End If

lSuccess = ShellExecute(hWndParent, "Open", Filename, vbNullString, vbNullString, WindowStyle)

Select Case lSuccess
Case Is > 32
LaunchDocument = True
Case SE_ERR_NOASSOC
If ShowOpenWithDialog Then
Shell "rundll32 shell32.dll,openas_rundll " & Filename
LaunchDocument = True
End If
Case Else
LaunchDocument = False
End Select

End Function

Gruß, Michael

cgsk01
Newbie
Newbie

Anmeldedatum: 26.08.2008
Beiträge: 7
Wohnort: Insel Poel

Verfasst am: 24.09.2008, 13:26

Danke für die schnelle Antwort Michael, aber irgendwie bekomme ich das trotzdem nicht hin.

Könntest du mir den gewünschten Pfad gleich miteinbauen?

J:\06 Timmendorf II\Teilrechnungen\Vorbereitung Teilrechnung 1.doc

Und muss ich erst einen Button erstellen und deinen Code zuweisen oder funktioniert der Code auch ohne Button??? (Hab Null Ahnung von VBA Rolling Eyes

)

MfG Christian

miriki
Schlauberger

Anmeldedatum: 05.03.2007
Beiträge: 432
Wohnort: Kiel

Verfasst am: 24.09.2008, 13:49

cgsk01 hat Folgendes geschrieben:

Und muss ich erst einen Button erstellen und deinen Code zuweisen oder funktioniert der Code auch ohne Button???

Ne, ne... Einen Button brauchste schon. Woher soll Access denn wissen, wann er das Dokument öffnen soll?

Ok, die Frage ließe sich auch mit "Beim Öffnen des Formulars" beantworten, womit ein anderes Ereignis als der Button-Klick möglich wäre.

Aber bau mal einen Button auf das Formular, brech aber den Assistenten sofort ab. Klicke dann rechts auf den Button und wähle "Ereignis", dann, falls er noch was nachfragt, die unterste Auswahl aktivieren und weiter.

Im VBA-Editor wirst Du einen Prozedur-Rumpf sehen, der nur aus "Private Sub ..." und "End Sub" besteht, dazwischen der Cursor.

Gib dort einfach

Code:

launchdocument filename

ein, wobei "filename" natürlich der (komplette) Pfad zu Deinem Dokument ist.

Wenn Du Return drückst und vorher auch schon den obigen "LaunchDocument"-Code in ein eigenes Modul (1) gepackt hast, sollte sich die Zeile in

Code:

LaunchDocument filename

(beachte die beiden Großbuchstaben) ändern. Damit steht einem Button-Klick nichts mehr im Wege.

(1) eigenes Modul: Wähle "Module" im Datenbankfenster, dann "Neu". Kopiere den obigen Source in das neue Modul.

Gruß, Michael

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Access Hilfe

Thema		Autor	Forum	Antworten	Verfasst am
Ähnliche Beiträge
	Vierecke in Word	Limited	Microsoft Word Hilfe	0	20.11.2008, 11:07
	Eine Auswahlliste mit Verknüpfung zu ...	anscfz06	Microsoft Excel Hilfe	4	19.11.2008, 22:36
	Button "Dateispeicherort" a...	tobias.s	Microsoft Word Hilfe	0	19.11.2008, 15:44
	Autotext in Word 2007	Ted	Microsoft Word Hilfe	0	18.11.2008, 13:42
	Outlook öffnet keine Hyperlinks mehr	Dariusz	Microsoft Outlook Hilfe	3	17.11.2008, 22:42

Gehe zu:

Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum posten
Du kannst Dateien in diesem Forum herunterladen

Powered by phpBB © 2001, 2002 phpBB Group :: FI Theme :: Alle Zeiten sind GMT + 1 Stunde
Deutsche Übersetzung von phpBB.de