Automatischer Such- Button in Excel Tabelle einrichten :: Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office

Einloggen, um private Nachrichten zu lesen

Downloads

Automatischer Such- Button in Excel Tabelle einrichten

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Excel Hilfe

Autor

Nachricht

ManuS
Newbie
Newbie

Anmeldedatum: 21.08.2007
Beiträge: 9

Verfasst am: 17.11.2007, 13:04

Hallo zusammen,

Ich habe eine Tabelle mit sehr vielen Namen. Jetzt möchte ich nicht immer über die Menüs und dann suchen, sondern ich hätte gerne ein Feld in meiner Tabelle in der ich einen Namen eingeben kann und neben dran einen Knopf mit "suchen" und dann springt der Kurser automatisch auf die Zeile mit dem Namen.

Kann mir jemand von euch Profis helfen.

Vielen Dank.

ManuS

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5509

Verfasst am: 17.11.2007, 13:46

Hallo!

Hier ein VBA-freier Vorschlag:
Dein Suchbegriff steht in I1.
Durchsucht wird der Bereich A1:F9.

Findet den ersten von oben:
=HYPERLINK("#"&ADRESSE(MIN(WENN(A1:F9=I1;ZEILE(1:9)+SPALTE(A:F)%%));REST(MIN(WENN(A1:F9=I1;ZEILE(1:9)+SPALTE(A:F)%%));1)/1%%);"Suche")

Findet den ersten von unten:
=HYPERLINK("#"&ADRESSE(MAX((A1:F9=I1)*(ZEILE(1:9)+SPALTE(A:F)%%));REST(MAX((A1:F9=I1)*(ZEILE(1:9)+SPALTE(A:F)%%));1)/1%%);"Suche")

Findet den ersten von links:
=HYPERLINK("#"&ADRESSE(REST(MIN(WENN(A1:F9=I1;SPALTE(A:F)+ZEILE(1:9)%%));1)/1%%;MIN(WENN(A1:F9=I1;SPALTE(A:F)+ZEILE(1:9)%%)));"Suche")

Findet den ersten von rechts:
=HYPERLINK("#"&ADRESSE(REST(MAX((A1:F9=I1)*(SPALTE(A:F)+ZEILE(1:9)%%));1)/1%%;MAX((A1:F9=I1)*(SPALTE(A:F)+ZEILE(1:9)%%)));"Suche")

Alle Formeln mit der Tastenkombination Strg+Shift+Enter abschließen!

Die Bereiche sind (beinahe) beliebig anpassbar, du solltest nur darauf achten, dass sich die Zelle mit dem Suchbegriff NICHT in dem zu durchsuchenden Bereich befindet.

_________________

Viele Grüße vom Schatzi
------------------------
Dies ist meine Signatur und sie trägt eigentlich nichts zur Lösung deines Problems bei. Sollte sie es dennoch tun, dann bist du definitiv im falschen Forum...

Ein Feedback zum ursprünglichen Problem wäre trotzdem nett!
Windows XP, Office2000, Office2007

ManuS
Newbie
Newbie

Anmeldedatum: 21.08.2007
Beiträge: 9

Verfasst am: 17.11.2007, 15:16

Hallo Schatzi,

Hat leider nicht geklappt. Wo sollte ich denn die Formel eingeben.

Da meine Tabelle mal ca. 6000 Zeilen haben wird, hätte mir gewünscht, dass ich z.B per Knopfdruck eine Art Makro oder so etwas auslöse, dass dann mein Eingabefeld mit der Spalte vergleicht und dann in die entsprechende Zeile springt.

Ich habe mal eine Datei angehängt:

In A1 gebe ich einen Namen ein und dann möchte ich dass dieser Name mit den Namen in Spalte A verglichen wird und anschließend der Cursor in die entsprechende Zeile springt.

Hab keine Ahnung ob das möglich ist. Wenn nicht, dann muss ich wohl weiterhin die Suchfunktion in der Menüleiste nutzen.

Vielen Dank für deine Mühe.

ManuS

Mappe2.xls

Beschreibung:

Download

Dateiname:

Mappe2.xls

Dateigröße:

127.5 KB

Heruntergeladen:

69 mal

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5509

Verfasst am: 17.11.2007, 19:03

Hallo!

Wenn es nur um eine Spalte geht, dann wird's noch kürzer.
Schreibe in A2 diese Formel und schließe die Eingabe mit Strg+Shift+Enter ab:

=HYPERLINK("#A"&MAX((A6:A999=A1)*ZEILE(6:999));"Suche")

Die obige Formel findet allerdings nur komplette Zellinhalte.
Wenn du z.B. nur "Holz" eingeben möchtest, um "Holzmann Petra" zu finden, dann nimm diese Formel:

=HYPERLINK("#A"&MAX(ISTZAHL(FINDEN(A1;A6:A999))*ZEILE(6:999));"Suchen")
(Auch mit Strg+Shift+Enter abschließen.)

Ein Feedback zum ursprünglichen Problem wäre trotzdem nett!
Windows XP, Office2000, Office2007

ManuS
Newbie
Newbie

Anmeldedatum: 21.08.2007
Beiträge: 9

Verfasst am: 18.11.2007, 09:47

Geil, Geil, Geil.

Wahnsinn. Ihr seid die Besten.

Vielen, vielen Dank.

ManuS

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Excel Hilfe

Thema		Autor	Forum	Antworten	Verfasst am
Ähnliche Beiträge
	Excel Tabelle aktualisiert sich auf D...	Dioxid123	Microsoft Excel Hilfe	4	28.08.2008, 10:43
	Daten aus Formular in Excel-Datei spe...	Christoph	Microsoft Excel Hilfe	7	25.08.2008, 20:37
	Excel Diagramm einteilen	Haintz	Microsoft Excel Hilfe	1	24.08.2008, 13:47
	Standardabweichung in EXCEL berechnen	Knueller	Microsoft Excel Hilfe	1	22.08.2008, 17:22
	Werte in neue Excel Tabelle übergeben...	xeader	Microsoft Excel Hilfe	18	22.08.2008, 13:17

Gehe zu:

Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum posten
Du kannst Dateien in diesem Forum herunterladen

Powered by phpBB © 2001, 2002 phpBB Group :: FI Theme :: Alle Zeiten sind GMT + 1 Stunde
Deutsche Übersetzung von phpBB.de