zelle auslesen und verwendung des inhalts als formelteil :: Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office

Einloggen, um private Nachrichten zu lesen

Downloads

[Excel 2003] zelle auslesen und verwendung des inhalts als formelteil

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Excel Hilfe

Autor

Nachricht

freebreaker
Besserwisser

Anmeldedatum: 30.01.2008
Beiträge: 68

Verfasst am: 05.02.2008, 11:10

Hallo,

es geht um folgende Formel:

Zitat:

=IF(A2="","no department found",VLOOKUP(A2,overview!$A$2:$B$500,2,FALSE))

Die Formel sucht den Bereich A2:B500 ab.

Was moechte ich nun?
Ich will den Bereich ueber eine andere Zelle veraendern koennen ohne die Formel zu aendern.

Z.B. steht in der Zelle settings!E15 "500", dann soll die Formel nachher so aussehen bzw. ausgefuehrt werden:

Zitat:

=IF(A2="","no department found",VLOOKUP(A2,overview!$A$2:$B$500,2,FALSE))

ist settings!E15 = 1000 soll die Formel so ausgefuehrt werden

Zitat:

=IF(A2="","no department found",VLOOKUP(A2,overview!$A$2:$B$1000,2,FALSE))

Ich hoffe ihr versteht was ich meine?

Denke es geht irgendwie ueber INDIREKT() aber bin noch nicht dahintergekommen wie ich das einbauen soll, mein letzter erfolgloser versuch war der hier:

Zitat:

=IF(A2="","no department found",VLOOKUP(A2,overview!$A$2:INDIRECT("$B$"&settings!$E$15),2,FALSE))

Da kommt aber dann das Fehler-Ergebnis #WERT

So, any suggestions?

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5729

Verfasst am: 05.02.2008, 11:17

Hallo!

Suggested, but not tested yet:

VLOOKUP(A2,INDIRECT("overview!A2:B"&settings!$E$15),2,0)

_________________

Viele Grüße vom Schatzi
------------------------
Ich bin nur noch sporadisch erreichbar!
Bitte hofft nicht auf eine schnelle Beantwortung einer Rückfrage meinerseits!
Jeder andere Helfer darf Rückfragen gerne übernehmen und hilft sicher gerne weiter!

freebreaker
Besserwisser

Anmeldedatum: 30.01.2008
Beiträge: 68

Verfasst am: 05.02.2008, 11:30

as every of your suggestions - no matter whether it's tested or not - it works greatly!

big thanks again, "darling"!

freebreaker
Besserwisser

Anmeldedatum: 30.01.2008
Beiträge: 68

Verfasst am: 05.02.2008, 12:23

okay, bei den "kleineren" formeln habe ich INDIRECT einfuegen koennen,

aber bei der Formel hier steig ich nicht mehr dahinter:

Zitat:

=

IF(WEEKDAY(DATE(YEAR($A$8),ROW()-8,B$8))=1,"w",
IF(WEEKDAY(DATE(YEAR($A$8),ROW()-8,B$8))=7,"w",

IF( SUMPRODUCT( ($A$4=forms!$A$2:$A$499) * (DATE(YEAR($A$8),ROW()-8,B$8)=forms!$E$2:$E$499) * (forms!$F$2:$F$499="pm")),$N$28,
IF( SUMPRODUCT( ($A$4=forms!$A$2:$A$499) * (DATE(YEAR($A$8),ROW()-8,B$8)=forms!$G$2:$G$499) * (forms!$H$2:$H$499="am")),$N$29,

IF(SUMPRODUCT(($A$4=forms!$A$1:$A$499)*(DATE(YEAR($A$8),ROW()-8,B$8)>=forms!$E$1:$E$499)*(DATE(YEAR($A$8),ROW()-8,B$8)<=forms!$G$1:$G$499)),$N$30,"")

))))

gleiches spielchen hier:
ueberall wo "499" soll der wert nachher durch den inhalt der Zelle "settings!$E$15" ersetzt werden.

Habe versucht
a) nur den betreffenden Teil
b) nur den betreffenden Parameter / Argument
c) die gesamte uebergeordnete Funktion
in INDIRECT() einzubetten, aber es will trotzdem nicht?

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5729

Verfasst am: 05.02.2008, 12:34

Hallo!

Eigentlich sollte es so klappen:

...SUMPRODUCT(($A$4=INDIRECT("forms!A2:A"&settings!$E$15))*...

Achte aber darauf, dass deine Bereiche alle die gleiche Größe haben!!!
Momentan beginnen in deiner Formel einige Bereiche in Zeile 1 und andere in Zeile 2. Da aber alle Bereiche in Zeile 499 enden, muss dies zwangsläufig zu einem Fehler führen.

freebreaker
Besserwisser

Anmeldedatum: 30.01.2008
Beiträge: 68

Verfasst am: 05.02.2008, 14:29

ok, das klappt jetzt auch, ich hatte immer entweder zuviel oder zuwenig in die INDIREKT Funktion gepackt.

danke

freebreaker
Besserwisser

Anmeldedatum: 30.01.2008
Beiträge: 68

Verfasst am: 05.02.2008, 14:38

ich wollte nicht nochmal ein neues thema aufmachen (hab schon soviele gemacht die letzten tage ^^), daher hier eine neue frage in einem alten post:

es geht um folgendes:

Zitat:

=

IF(WEEKDAY(DATE(YEAR($A$8),ROW()-8,B$8))=1,"w",
IF(WEEKDAY(DATE(YEAR($A$8),ROW()-8,B$8))=7,"w",

IF(DATE(YEAR($A$8),ROW()-8,B$8)=settings!A:A,"h",

IF( SUMPRODUCT( ($A$4=INDIRECT("forms!$A$2:$A$"&settings!$E$15)) * (DATE(YEAR($A$8),ROW()-8,B$8)=INDIRECT("forms!$E$2:$E$"&settings!$E$15)) * (INDIRECT("forms!$F$2:$F$"&settings!$E$15)="pm")),$N$28,
IF( SUMPRODUCT( ($A$4=INDIRECT("forms!$A$2:$A$"&settings!$E$15)) * (DATE(YEAR($A$8),ROW()-8,B$8)=INDIRECT("forms!$G$2:$G$"&settings!$E$15)) * (INDIRECT("forms!$H$2:$H$"&settings!$E$15)="am")),$N$29,

IF(SUMPRODUCT(($A$4=forms!$A$2:$A$500)*(DATE(YEAR($A$8),ROW()-8,B$8)>=forms!$E$2:$E$500)*(DATE(YEAR($A$8),ROW()-8,B$8)<=forms!$G$2:$G$500)),$N$30,"")

)))))

ich habe den roten Teil hinzugefuegt und seitdem funktioniert die Formel nicht (davor gings), Excel zeigt mir dann, dass ein Fehler vorliegt und markiert automatisch das blaue YEAR unten. Warum?

Was der Rote Teil machen soll:
genauso wie

Zitat:

IF(WEEKDAY(DATE(YEAR($A$8),ROW()-8,B$8))=1,"w",

in jedes Feld, dessen Datum auf einen Sonntag faellt, ein "w" reinschreibt,

soll der rote Teil

Zitat:

IF(DATE(YEAR($A$8),ROW()-8,B$8)=settings!A:A,"h",

in jedes Feld, dessen Datum ein Feiertag ist, ein "h" reinschreiben.
Die Feiertage habe ich in die A Spalte der Tabelle settings in Form von Datumsangaben (eine pro Zelle) geschrieben.

ich mach drei kreuze wenn ich das ding dann endlich fertig habe ...

Wie immer:
Danke im Voraus fuer die Hilfe!

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5729

Verfasst am: 05.02.2008, 14:46

Hallo!

Mal wieder ungetestet:

IF(COUNTIF(settings!A:A,DATE(YEAR($A$8),ROW()-8,B$8)),"h"

freebreaker
Besserwisser

Anmeldedatum: 30.01.2008
Beiträge: 68

Verfasst am: 05.02.2008, 14:51

gleiche fehlermeldung und es wird auch wieder o.g. YEAR automatisch markiert

dass excel streikt, weil ihm die formel insg. zu lang ist, kann nicht sein oder??

Zuletzt bearbeitet von freebreaker am 05.02.2008, 15:01, insgesamt 2-mal bearbeitet

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5729

Verfasst am: 05.02.2008, 14:59

Doch natürlich!

Die maximale Verschachtelungstiefe ist 8. Dies erhöht sich erst bei Excel2007.
Du müsstest versuchen, deine IFs mit "&" zu verknüpfen, um das zu umgehen:

=IF(WEEKDAY(DATE(YEAR($A$8),ROW()-8,B$8))=1,"w","")&IF(WEEKDAY(DATE(YEAR($A$8),ROW()-8,B$8))=7,"w","")&...

freebreaker
Besserwisser

Anmeldedatum: 30.01.2008
Beiträge: 68

Verfasst am: 05.02.2008, 15:03

bevor wir uns in das IF-Verknuepfen reinstuerzen:

ich zaehle 5 verschachtelte IFs und einen "Start- bzw. Ueber-" IF, also insgesamt 6. Das liegt ja noch unter den insg 7 erlaubten verschachtelten IFs oder?

Habe auch mal einen Screenshot gemacht:

fehler.JPG

Beschreibung:

Dateigröße:

225.14 KB

Angeschaut:

101 mal

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5729

Verfasst am: 05.02.2008, 15:14

Du verschachtelst aber nicht nur IFs, sondern auch YEARs und DATEs und ROWs und SUMPRODUCTs...

Wenn ich deine Formel rückwärts lese, dann komme ich auf 10(!) geschlossene Klammern und nicht eine geöffnete...

...,ROW()-8,B$8)<=forms!$G$2:$G$500)),$N$30,""))))))

freebreaker
Besserwisser

Anmeldedatum: 30.01.2008
Beiträge: 68

Verfasst am: 05.02.2008, 16:18

ach menno,
das macht den ganzen kalender nur noch halb so schoen Sad

aber ich danke dir trotzdem! wieder was gelernt!

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Excel Hilfe

Thema		Autor	Forum	Antworten	Verfasst am
Ähnliche Beiträge
	Inhalt eines Kombinationsfeld in Zell...	Nicki11	Microsoft Excel Hilfe	3	01.12.2008, 19:00
	Eingabewert in selber Zelle mit feste...	senna94	Microsoft Excel Hilfe	1	28.11.2008, 13:13
	Zellen Inhalt Automatisch in ein ande...	Serdal	Microsoft Excel Hilfe	1	28.11.2008, 00:42
	Zelle per Formel färben?	enzo	Microsoft Excel Hilfe	2	24.11.2008, 09:06
	Verschiedene Wahlmöglichkeiten in ein...	danini	Microsoft Excel Hilfe	0	13.11.2008, 13:50

Gehe zu:

Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum posten
Du kannst Dateien in diesem Forum herunterladen

Powered by phpBB © 2001, 2002 phpBB Group :: FI Theme :: Alle Zeiten sind GMT + 1 Stunde
Deutsche Übersetzung von phpBB.de