Automatische Anpassung der Summenformel :: Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office

Einloggen, um private Nachrichten zu lesen

Downloads

[Excel 2003] Automatische Anpassung der Summenformel

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Excel Hilfe

Gehe zu Seite 1, 2 Weiter

Autor

Nachricht

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 19.02.2008, 00:17

Hallo liebe Helfer,

ich hätte da eine wichtige Frage:
Wie kann ich Summefunktion für eine dynamische Anzahl an Zellen anwenden?

Wenn z.B. in der Zelle A1 steht =Summe(A2:A4) ist ja bekanntlich in Ordnung. Nur wenn dieser Bereich sich weiter durch die VBA-Codes erweitert, wie kann dann auch diese Formel angepasst werden, z.B. auf A2:A3?

Mit dankenden Grüße aus Sachsen

Ag.man

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5749

Verfasst am: 19.02.2008, 01:14

Hallo Ag.man!

Ich kenne deinen Code nicht, daher kann das "simple"
=SUMME(INDIREKT("A2:A"&G17))
schon reichen.
(Wenn in G17 der Wert "123" steht, dann ergibt das =SUMME(A2:A123)
Sonst schau doch mal ins Tutorial dynamischer Bereichsname.

_________________

Viele Grüße vom Schatzi
------------------------
Ich bin nur noch sporadisch erreichbar!
Bitte hofft nicht auf eine schnelle Beantwortung einer Rückfrage meinerseits!
Jeder andere Helfer darf Rückfragen gerne übernehmen und hilft sicher gerne weiter!

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 19.02.2008, 20:08

Hallo Schatzi (im wahrsten Sinne des Wortes!),

ich habe mal die Sache mit der Summe und Indirekt ausprobiert, funktioniert nur bedingt, da ich mehrere Summen habe, die vertikal angeordnet sind.
Diese Formel funktioniert leider nur bei der untersten Summenformel.

Mit dankbaren Grüßen

Ag.man

20080205_Forum.xls

Beschreibung:

Download

Dateiname:

20080205_Forum.xls

Dateigröße:

41.5 KB

Heruntergeladen:

20 mal

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5749

Verfasst am: 19.02.2008, 20:28

Hallo!

Diese Formel kannst du in allen Summenzellen anwenden:

=SUMME(INDIREKT("F"&ZEILE()+1&":F"&VERGLEICH("?*";INDIREKT("A"&ZEILE()+1&":A1000");)+ZEILE()-1))

Damit sie auch bei der untersten Summe funktioniert, musst du in A1000 einen beliebigen Eintrag setzen, z.B. "x".

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 19.02.2008, 20:41

Schatzi, wie kommt man auf solche ungeheuere Formeln? That is crazy! It works. Ich kann es nicht glauben.

Lieben Dank Schatzi!!!

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 19.02.2008, 21:40

Hallo Schatzi,

ich will Dir jetzt nicht auf die Nerven gehen, aber was ist wenn ich die Tabelle erweitere in dem die automatische Erweiterung in Anspruch nehme, dann verlagert sich auch x aus A1000 in A1001?

Liebe Grüße

Ag.man

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5749

Verfasst am: 19.02.2008, 21:44

Hallo!

Das hatte ich nicht bedacht...
Dann ändere in der Formel einfach den Bereich auf 2000.
(Mehr als 1000 Zeilen wirst du ja wohl nicht einfügen, oder?)

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 19.02.2008, 21:56

Danke für die schnelle Antwort.
Ich meinte Schatzi was ganz anderes. Wenn, wie in der Tabelle die Wochentage mittels der DropDownListe automatisch erweitert werden, verschiebt es jede darunterliegende Zeile um eine Stelle nach unten.
Wenn also die Wochentage hinzugefügt werden, dann ist x nicht mehr auf 1000 sondern auf A1001-Position.

Verstehst Du mich jetzt?

Liebe Grüße

Alex

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5749

Verfasst am: 19.02.2008, 22:02

Ja, das habe ich schon richtig verstanden!
Lass das x in Zeile 1000 und ändere die Formel in

=SUMME(INDIREKT("F"&ZEILE()+1&":F"&VERGLEICH("?*";INDIREKT("A"&ZEILE()+1&":A2000");)+ZEILE()-1))

Wo genau das "x" steht, ist der Formel egal; es muss nur irgendwo weiter unten irgendein Eintrag sein; ob in Zeile 1000, Zeile 1001 oder Zeile 1479 spielt keine Rolle...
So sucht die Formel bis Zeile 2000 und das sollte genügend Spielraum zum Zeileneinfügen sein.

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 19.02.2008, 22:27

Danke für den Hinweis.
Ich verstehe, vorhin schien das ganze nicht zu funktionieren doch jetzt funktioniert es wohl doch.

Da ich diese Formel, eigentlich zeigt mir excel, dass das keine richtige Formel ist, nicht genau entschlüsseln kann, möchte noch eins fragen: an welche Voraussetzungen ist diese Formel geknüpft. Worauf muss ich beim Einfügen in andere Projekte achten?

Liebe Grüße

Alex

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5749

Verfasst am: 19.02.2008, 22:47

Hallo!

Zitat:

dass das keine richtige Formel ist

Wie bitte??

Wir können sie ja mal aufdröseln (am Beispiel F4):
=SUMME(INDIREKT("F"&ZEILE()+1&":F"&VERGLEICH("?*";INDIREKT("A"&ZEILE()+1&":A2000");)+ZEILE()-1))

Von innen nach außen:
INDIREKT("A"&ZEILE()+1&":A2000")
ergibt den Bereich A5:A2000

VERGLEICH("?*";A5:A2000;)
sucht den ersten Eintrag in diesem Bereich und gibt die Zeile zurück.
Der erste Eintrag in diesem Bereich ist in A12, also liefert dieser Teil 8 (8. Zeile von A5:A2000).
Da dieser Bereich aber erst in Zeile 5 beginnt, müssen wir noch ein bisschen tricksen:
VERGLEICH("?*";A5:A2000;)+ZEILE()-1 = 8+4-1
ergibt 11.
Also haben wir
=SUMME(INDIREKT("F"&ZEILE()+1&":F"&11))
Das ergibt
=SUMME(F5:F11)

Und das ist genau der Bereich, den du summieren möchtest.

Ich hoffe, das war halbwegs verständlich.

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 19.02.2008, 23:13

Danke Schatzi für die Aufklärung.
Mit "keine richtige Formel" meinte ich, dass Excel diese Formel als ungültig angesehen hat.

Deinen ausführlichen Ausführungen konnte ich folgen und ich hoffe ich dieses System auch in andere Sheets einbauen.
Gibt es eigentlich eine noch einfachere Lösung für dieses Problemstellung?
Ach und bei dieser Lösung muss man natürlich auch darauf achten, dass man die unter der Spalte F keine Zahlen einträgt, sonst könnte es natürlich zu unlogischen Summierungen kommen.

Liebe Grüße

Alex

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5749

Verfasst am: 19.02.2008, 23:24

Tja, wenn mir etwas einfacheres eingefallen wäre, dann hätte ich das sicher gepostet...

Apropos einfach:
In F3 kannst du die Gesamtsumme errechnen mit
=SUMME(F4:F1000)/2

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 19.02.2008, 23:37

Also Schatzi,

danken kann ich Dir wohl nie genug. Bist ja besser als der Bernd Held. ;)

Diese Formel ist ja wirklich logisch. Die Zahlen kommen ja doppelt vor und einfach durch 2 Teilen, da ist schon die Summe. Kompliziert kann jeder, aber einfache Zusammenhänge herstellen, das ist die wahre Kunst.

Einen wunderschönen Abend wünsche ich Dir und bis zum nächsten maaaaaaaaaaaal liebe Schatzi.

Alex

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5749

Verfasst am: 19.02.2008, 23:50

Hallo nochmal!

Wenn du die Zwischensummen nach Spalte G "auslagern" kannst, dann geht's doch einfacher:
Lösche alle "INDIREKT-Formeln" aus Spalte F und schreibe in G4

=WENN(A4="";"";SUMME(F5:F$999)-SUMME(G5:G$999))
(großzügig runterkopieren)

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Excel Hilfe

Gehe zu Seite 1, 2 Weiter

Thema		Autor	Forum	Antworten	Verfasst am
Ähnliche Beiträge
	Anpassung von Diagrammen per Makro?	gassi83	Microsoft Excel Hilfe	0	19.12.2008, 12:31
	Keine automatische Absenderangabe in ...	franzpeter17	Microsoft Outlook Hilfe	2	17.12.2008, 18:40
	automatische Vervollständigung	Michael61	Microsoft Excel Hilfe	2	16.12.2008, 18:24
	automatische mail an email senden	excelloser	Microsoft Excel Hilfe	2	04.12.2008, 23:22
	Automatische Kopieren in andere Zeilen	Deltar	Microsoft Excel Hilfe	1	26.11.2008, 18:24

Gehe zu:

Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum posten
Du kannst Dateien in diesem Forum herunterladen

Powered by phpBB © 2001, 2002 phpBB Group :: FI Theme :: Alle Zeiten sind GMT + 1 Stunde
Deutsche Übersetzung von phpBB.de