UND Zeichen :: Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office

Einloggen, um private Nachrichten zu lesen

Downloads

[Excel 2003] UND Zeichen

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Excel Hilfe

Autor

Nachricht

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 02.04.2008, 10:02

Hallo Freunde,

ich hätte wieder einmal eine ganz einfache Frage, die mich aber zum Verzweifeln bringt.

Ich möchte gern diese Formel verwenden, wobei nur die Zellen D135 und D137 angesprochen werden sollen =wenn(zählenwenn(D135hiermmusswasstehenD137);WAHR)=2;0,5;0)
Ich habe schon + und - und * und UND probiert. Immer wieder kommt dabei nichts positives zustande. Solche D135:D137 möchte ich extra vermeiden, weil nur die oberen Grenzen betrachtet werden sollen.

Ich hoffe auf Eure Hilfe

Liebe Grüße

Euer Ag.man

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 02.04.2008, 11:14

Habe mit Hilfe eines netten Helfers das Problem mit

wenn(summe(D135=wahr;D137=wahr)=2;0,5;0) gelöst. Wenn jemand noch eine andere Lösung dazu hätte- lerne ich gern noch etwas dazu.

Liebe Grüße und einen schönen Tag wünscht

Ag.man

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5729

Verfasst am: 02.04.2008, 13:41

Hallo!

Ich glaube, hier hätte ausnahmsweise ein Blick in die Excel-Hilfe genügt (Stichwort: UND):

=WENN(UND(D135;D137);5;0)

_________________

Viele Grüße vom Schatzi
------------------------
Ich bin nur noch sporadisch erreichbar!
Bitte hofft nicht auf eine schnelle Beantwortung einer Rückfrage meinerseits!
Jeder andere Helfer darf Rückfragen gerne übernehmen und hilft sicher gerne weiter!

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 09.04.2008, 09:40

Danke Schatzi, habe gerade noch mal reingeschaut.
Mit Hilfe hatte ich damals auch probiert, aber da bin ich nicht fündig geworden, auch mit dem Stichwort UND.

Liebe Grüße

Ag.man

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 09.04.2008, 10:32

Hallo nocheinmal.
Hier habe ich so etwas Ähnliches:

Habe eine Formel geschrieben, die durch die Pluszeichen miteinander verbunden werden soll. Diese funktioniert aber nicht richtig. Diese Formel gibt einen falschen Wert heraus.
"=WENN(ZÄHLENWENN(D133:D136;WAHR)=4;0,9;WENN(UND(D133;D134;D135);0,7;
WENN(UND(D133;D134;D136);0,7;WENN(UND(D133;D135;D136);0,7;
WENN(ZÄHLENWENN(D134:D136;WAHR)=3;0,6;)))))+WENN(ZÄHLENWENN(D133:D134;WAHR)=2;0,5;
WENN(UND(D133;D135);0,5;WENN(UND(D133;D136);0,5;WENN(ZÄHLENWENN(D134:D135;WAHR)=2;0,4;
WENN(UND(D134;D136);0,4;WENN(UND(D135;D136);0,4;+WENN(ZÄHLENWENN(D133;WAHR)=1;0,3;)))))))
+WENN(ZÄHLENWENN(D134:D136;WAHR)=1;0,2;)"

Habe ich hier nun wieder einmal was übersehen?

Liebe Grüße

Ag.man

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5729

Verfasst am: 09.04.2008, 11:44

Hallo!

Wenn ich die Formel richtig verstehe, dann ist das Problem, dass sich die Bedingungen nicht alle gegenseitig aussschließen, dadurch werden ungewollt mehrere Teile addiert.

Mein Vorschlag wäre, jedesmal wirklich alle vier Zellen abzufragen und dann auch ganz auf WENN zu verzichten:

0,9*UND(D133;D134;D135;D136)+0,7*UND(D133;D134;D135;NICHT(D136))+0,7*UND(D133;D134;NICHT(D135);D136)+...

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 09.04.2008, 11:58

Ich probiere es gleich aus. Aber eigentlich muss ich doch alles berücksichtigt haben. Ich schaue es nochmal durch Schatzi.

Bis gleich

Ag.man

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5729

Verfasst am: 09.04.2008, 12:04

Hallo!

Zitat:

Aber eigentlich muss ich doch alles berücksichtigt haben.

Das bezweifel ich ja auch nicht, aber manches berücksichtigst du sogar doppelt:

Wenn in allen vier Zellen WAHR steht, dann ergeben z.B. diese roten Teile beide WAHR und werden fälschlicherweise addiert:

=WENN(ZÄHLENWENN(D133:D136;WAHR)=4;0,9;WENN(UND(D133;D134;D135);0,7;
WENN(UND(D133;D134;D136);0,7;WENN(UND(D133;D135;D136);0,7;
WENN(ZÄHLENWENN(D134:D136;WAHR)=3;0,6;)))))+WENN(ZÄHLENWENN(D133:D134;WAHR)=2;0,5;
WENN(UND(D133;D135);0,5;WENN(UND(D133;D136);0,5;WENN(ZÄHLENWENN(D134:D135;WAHR)=2;0,4;
WENN(UND(D134;D136);0,4;WENN(UND(D135;D136);0,4;+WENN(ZÄHLENWENN(D133;WAHR)=1;0,3;)))))))
+WENN(ZÄHLENWENN(D134:D136;WAHR)=1;0,2;)

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 09.04.2008, 13:23

Hallo Schatzi, eine Frage für Zwischendurch: Gibt es Möglichkeit, dass der Pfeil bei Drop-Down-Liste immer angezeigt wird und nicht erst, wenn die Zelle aktiv ist?

So, dank Schatzi habe ich folgendes Ergebnis erzielen könen:
istgleich0,9*UND(D133;D134;D135;D136)+0,7*UND(D133;D134;D135;NICHT(D136))+
0,7*UND(D133;D134;NICHT(D135);D136)+
0,7*UND(D133;D135;D136;NICHT(D134))+0,6*UND(D134;D135;D136;NICHT(D133))+
0,5*UND(D133;D134;NICHT(D135);NICHT(D136))+0,5*UND(D133;D135;NICHT(D134);NICHT(D136))+
0,5*UND(D133;D136;NICHT(D135);NICHT(D134))+0,4*UND(D134;D135;NICHT(D133);NICHT(D136))+
0,4*UND(D134;D136;NICHT(D133);NICHT(D135))+0,4*UND(D135;D136;NICHT(D133);NICHT(D134))+
0,3*UND(D133;NICHT(D134);NICHT(D135);NICHT(D136))+0,2*UND(D134;NICHT(D133);NICHT(D135);NICHT(D136))+
0,2*UND(D135;NICHT(D133);NICHT(D134);NICHT(D136))+0,2*UND(D136;NICHT(D133);NICHT(D134);NICHT(D135))

Aber es ging bestimmt auch leichter ;)
Ich habe die Formel überprüft und konnte leider keien Vergesslichkeiten feststellen. Wie auch immer, es funktioniert in der Tat!

Liebe Grüße

Ag.man

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 09.04.2008, 13:29

Jetzt beginne ich zu verstehen, wo der Fehler liegt!

Und wie schalte ich denn diesen Fehler aus?

Liebe Grüße

Alex

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5729

Verfasst am: 09.04.2008, 15:30

Hallo!

Wenn man die vier Zellen unterschiedlich gewichtet, dann geht wohl auch sowas:

=WAHL(8*D133+4*D134+2*D135+D136+1;0;0,2;0,2;0,4;0,2;0,4;0,4;0,6;0,3;0,5;0,5;0,7;0,5;0,7;0,7;0,9)

Ich glaube, das müsste passen, aber check das lieber nochmal gegen...

Zu deiner Zwischenfrage wegen des Gültigkeits-DropDowns:
Hier wird der Pfeil nur angezeigt, wenn die Zelle aktiv ist; dies lässt sich meines Wissens auch nicht ändern.
Dafür müsstest du dann eine ComboBox erstellen (Symbolleiste: Steuerelemente-Toolbox).

PS: Ich glaube, ich habe jetzt sogar das System entdeckt, welches deiner Wertzuweisung zugrunde liegt!
Teste mal dies:

=0,2*ZÄHLENWENN(D133:D136;WAHR)+0,1*D133

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 09.04.2008, 17:39

Hallo Schatzi,

das ist schon ein nettes Excel-Niveau, auf dem Du Dich hier bewegst. Ich glaube, das nennt man Profi ;)
Die zweite Formel ist wirklich die Inkornation der Einfachheit, die erste ist der Gegenteil ;) Aber beide funktionieren!

Wie kamst Du mit auf diese Formel. Im Nachhinein erscheint es logisch, doch bis das Ergebnis steht, könnten bei mir einige Minuten vergehen.

Andere Gegenfrage: ich habe gerade festgestellt, dass man keine Drop-Down-Liste aus mehreren Zellen als Quellen erstellen kann. Den Trick mit der Namensvergabe ist mir bekannt, aber dieser hilft hier auch nicht. Offensichtlich kann Liste nur aus benachbarten Zellen erstellt werden. Ist das so?

Liebe Grüße, vielen Dank und bis später

Alex

schatzi
Moderator

Anmeldedatum: 09.12.2006
Beiträge: 5729

Verfasst am: 09.04.2008, 17:50

Hallo!

Auf die untere Formel kam ich, als ich die obere ausprobiert habe, ob sie mit deinen Ergebnissen übereinstimmt.
Dabei fiel mir auf, dass D133 offenbar eine Wertigkeit von 0,3 hat, während alle anderen Zellen mit 0,2 gewertet werden.

Somit müsste sogar diese rein mathematische Lösung funktionieren:
=0,3*D133+0,2*(D134+D135+D136)

Für ein Gültigkeits-DD müssen die Zellen benachbart sein, das ist zumindest mein Kenntnisstand.
Du kannst die Begriffe aber auch direkt bei "Quelle" eintragen und somit gänzlich auf Zellbezüge verzichten:

Menü Daten > Gültigkeit
Zulassen: Liste
Quelle: Hund;Katze;Maus

Aber diese Variante ist meist unflexibler.

Ag.man
User mit gefährlichem Halbwissen

Anmeldedatum: 19.07.2007
Beiträge: 106

Verfasst am: 09.04.2008, 18:21

Ja, ich habe das mit dem Nachbarnsystem gelöst, aber der mit den Namen ist auch brauchbar. Die mathematische Lösung gefällt besser als die erste Formel.

Lieben Dank für die Hilfe

Alex

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Excel Hilfe

Thema		Autor	Forum	Antworten	Verfasst am
Ähnliche Beiträge
	Anzahl an Zeichen abhängig von Wert g...	woerli	Microsoft Excel Hilfe	1	13.11.2008, 13:24
	Zeichen löschen	saschathede	Microsoft Excel Hilfe	2	21.10.2008, 13:30
	Ersetzten von Zeichen	saschathede	Microsoft Excel Hilfe	2	07.10.2008, 17:39
	Ganz merkwürdige Zeichen und Symbole	hasegoe	Microsoft Word Hilfe	0	11.09.2008, 06:14
	Autokorrektur mit tiefgestellten Zeichen	otti0305	Microsoft Word Hilfe	2	30.07.2008, 09:00

Gehe zu:

Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum posten
Du kannst Dateien in diesem Forum herunterladen

Powered by phpBB © 2001, 2002 phpBB Group :: FI Theme :: Alle Zeiten sind GMT + 1 Stunde
Deutsche Übersetzung von phpBB.de