Mit VBA Bildschimrpräsentation (pps) öffnen :: Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office

Einloggen, um private Nachrichten zu lesen

Downloads

[Access 2002] Mit VBA Bildschimrpräsentation (pps) öffnen

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Access Hilfe

Autor

Nachricht

egonszepoks
Newbie
Newbie

Anmeldedatum: 31.08.2007
Beiträge: 7

Verfasst am: 30.06.2008, 11:51

Hallo Schatzis,

wie kann ich in ACCESS mit VBA eine Bildschirmpräsentqation (PPS-Format) öffnen? Mit der Shell-Funktion gelingt es nicht.

Gruße Egon Szepoks

miriki
Schlauberger

Anmeldedatum: 05.03.2007
Beiträge: 303
Wohnort: Kiel

Verfasst am: 08.07.2008, 09:41

egonszepoks hat Folgendes geschrieben:

wie kann ich in ACCESS mit VBA eine Bildschirmpräsentqation (PPS-Format) öffnen?

Mit folgender Routine "LaunchDocument" bin ich bislang recht zufrieden. Ich weiß jetzt nicht mehr genau, wo ich die her hab, aber ich würde mal in Richtung "knowledge base" tippen.

Code:

Option Compare Database

Private Const SE_ERR_NOASSOC As Long = 31&

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
ByVal hWnd As Long, _
ByVal Operation As String, _
ByVal Filename As String, _
Optional ByVal Parameters As String, _
Optional ByVal Directory As String, _
Optional ByVal WindowsStyle As Long = vbMaximizedFocus _
) As Long

Public Function LaunchDocument( _
ByRef Filename As String, _
Optional ByVal ParentForm As Form, _
Optional ByVal ShowOpenWithDialog As Boolean = False, _
Optional ByVal WindowStyle As VBA.VbAppWinStyle = vbMaximizedFocus _
) As Boolean

Dim lSuccess As Long
Dim hWndParent As Long

If Not ParentForm Is Nothing Then
hWndParent = ParentForm.hWnd
End If

lSuccess = ShellExecute(hWndParent, "Open", Filename, vbNullString, vbNullString, WindowStyle)

Select Case lSuccess
Case Is > 32
LaunchDocument = True
Case SE_ERR_NOASSOC
If ShowOpenWithDialog Then
Shell "rundll32 shell32.dll,openas_rundll " & Filename
LaunchDocument = True
End If
Case Else
LaunchDocument = False
End Select

End Function

egonszepoks
Newbie
Newbie

Anmeldedatum: 31.08.2007
Beiträge: 7

Verfasst am: 09.07.2008, 12:01

Hallo,
ich habe die Funktion gerade gelesen und ausprobiert. Es funktioniert.

Ganz herzlichen Dank.

Office-Hilfe.com - Wir lösen Ihre Probleme mit Microsoft Office Foren-Übersicht » Microsoft Access Hilfe

Thema		Autor	Forum	Antworten	Verfasst am
Ähnliche Beiträge
	Beim öffnen von Word erscheint immer ...	Alfff	Microsoft Word Hilfe	1	28.08.2008, 10:54
	MS Word lässt sich nicht mehr öffnen	andrea_1980	Microsoft Word Hilfe	0	17.08.2008, 17:32
	Excel-Datei mit fortlaufender Nummer ...	derhornist	Microsoft Excel Hilfe	3	14.08.2008, 16:03
	Datenauswertung ohne Excel-Dateien zu...	Manolo99	Microsoft Excel Hilfe	1	08.08.2008, 21:59
	Schreibgeschützte Datei über ein Makr...	Randy7	Microsoft Excel Hilfe	1	22.07.2008, 20:16

Gehe zu:

Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
Du kannst deine Beiträge in diesem Forum nicht bearbeiten.
Du kannst deine Beiträge in diesem Forum nicht löschen.
Du kannst an Umfragen in diesem Forum nicht mitmachen.
Du kannst Dateien in diesem Forum posten
Du kannst Dateien in diesem Forum herunterladen

Powered by phpBB © 2001, 2002 phpBB Group :: FI Theme :: Alle Zeiten sind GMT + 1 Stunde
Deutsche Übersetzung von phpBB.de