Office: (Office 365) Berechnungen Stempel und Pausenzeiten

Helfe beim Thema Berechnungen Stempel und Pausenzeiten in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hi zusammen, ich wollte um Hilfe bitten bei der Aufgabe Berechnung von Anwesenheitszeit: Aufgabenstellung. (Dateikopie sende ich mit) Erste... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von MHS1002, 5. Oktober 2022.

  1. MHS1002 hat Ahnung

    Berechnungen Stempel und Pausenzeiten


    Hi zusammen,

    ich wollte um Hilfe bitten bei der Aufgabe Berechnung von Anwesenheitszeit:
    Aufgabenstellung. (Dateikopie sende ich mit)

    Erste Bedingung: In Spalte Q wird die Pausenzeit berechnet. Bedingt an einige Bedigungen.
    Hierfür ein Beispiel: Wenn B4 "SN" dann wird erst eine Pause von 30 Minuten abgezogen wenn die Anwesenheit in G4:H4 und/oder I4:J4 und oder K4:L4 zwischen21:30 Uhr und 22:00 Uhr ist

    Zweite Bedingung: Wenn B4 "N" dann wird erst eine Pause von 30 Minuten abgezogen wenn die Anwesenheit in G4:H4 und/oder I4:J4 und oder K4:L4 zwischen 03:30 Uhr und 04:00 Uhr ist

    Dritte Bedingung: Wenn B4 "F" oder "T" oder "S" wird eine Pause von 30 Minuten abgezogen wenn die Anwesenheit in G4:H4 größer 6h ist wenn eine weitere Anwesenheit bei I4:J4 und oder K4:L4 vorhanden ist, wird nichts abgezogen.

    Vierte Bedingung: Wenn B4="" also leer ist und die Anwesenheit in G4:H4 kleiner 6h ist wird nichts abgezogen, ist sie größer 6h werden 30 min Pause abgezogen, wenn eine weitere Anwesenheit bei I4:J4 und oder K4:L4 vorhanden ist, wird nichts abgezogen.

    Ich hoffe ich konnte es einigermaßen erklären. Sicherlich brauch ich noch weitere Hilfestellungen bei anderen Formeln, dazu aber später, sonst wird es zu umfangreich.

    Vielen Dank schonmal.
    LG
     
    MHS1002, 5. Oktober 2022
    #1
  2. {Boris} hat Ahnung
    Hi,

    und was genau ist nun Deine Frage? Welche Formeln in der Datei tun derzeit noch nicht, was sie sollen? Welche Ergebnisse (bitte händisch in einer separaten Spalte als "Wunschergebnis" eintragen) sollen sie konkret liefern?
     
    {Boris}, 5. Oktober 2022
    #2
  3. MHS1002 hat Ahnung
    Hallo Boris,

    danke für Deine Hilfestellung. ZB. ist aktuell in Q4 folgende Formel: =WENN((REST(L4-K4+J4-I4+H4-G4;1))>=0,25;0,020833333;"")

    Hier soll die Berechnung so aussehen, wie oben beschrieben. Die Bedingungen der unterschiedlichen Uhzeiten usw. werden leider nicht berücksichtigt.

    LG
     
    MHS1002, 5. Oktober 2022
    #3
  4. RPP63_neu hat Ahnung

    Berechnungen Stempel und Pausenzeiten

    Moin!
    Sorry, falsch gelesen!
    Gruß Ralf
     
    RPP63_neu, 5. Oktober 2022
    #4
  5. MHS1002 hat Ahnung
    Hallo Ralf,
    vielen Dank. Ich denke wir müssen die Formel komplett umbauen und die ganzen Bedingungen berücksichtigen, oder?
    LG
     
    MHS1002, 5. Oktober 2022
    #5
  6. RPP63_neu hat Ahnung
    Ich hatte meinen Post gelöscht, weil ich die Frage falsch verstanden hatte.
    =WENN((REST(L4-K4+J4-I4+H4-G4;1))>=0,25;0,020833333;"")
    Die Formel stimmt soweit, wenngleich ich sie besser lesbar schreiben würde:
    =WENN(REST(L4-K4+J4-I4+H4-G4;1)>=ZEIT(6;;);ZEIT(;30;);"")
    Der "kleine" Rest ist dann ziemliche Fleißarbeit …
     
    RPP63_neu, 5. Oktober 2022
    #6
  7. MHS1002 hat Ahnung
    Ich sag erstmal herzlichen Dank!

    Dennnoch möchte ich es nochmals versuchen anders zu erklären, oder ich steh aufm Schlach. Ich brauch ja noch den Bezug auf den Inhalt in C4. Die Formel müsste daher irgendwie so aussehen.

    Bezug auf C4, wenn Inhalz X,F,T,S und anwesenheit >6h dann 30min berechnen:
    =WENN(C4="X"oder"F"oder"T"oder"S" dann (REST(L4-K4+J4-I4+H4-G4;1)>=ZEIT(6;;);ZEIT(;30;);"")

    Dann sollte ja noch folgendes zusätzlich berechnet werden.
    Bezug auf C4 wenn Inhalt "SN" und Anwesenheit zwischen 21:30 und 22:00 Uhr dann 30min berechnen:
    =WENN(C4="SN" und (REST(L4-K4+J4-I4+H4-G4;1)=ZEIT(zwischen 21:30 uhr und 22:00 Uhr);ZEIT(;30;);"") dann (REST(L4-K4+J4-I4+H4-G4;1)>=ZEIT(6;;);ZEIT(;30;);"")

    Dann sollte ja noch folgendes zusätzlich berechnet werden.
    Bezug auf C4 wenn Inhalt "N" und Anwesenheit zwischen 03:30 und 04:00 Uhr dann 30min berechnen:
    =WENN(C4="N" und (REST(L4-K4+J4-I4+H4-G4;1)=ZEIT(zwischen 03:30 uhr und 04:00 Uhr);ZEIT(;30;);"") dann (REST(L4-K4+J4-I4+H4-G4;1)>=ZEIT(6;;);ZEIT(;30;);"")

    Bekommen wir das irgendwie in eine ;-) Sorry aber mir fehlt da etwas der Background
     
    MHS1002, 5. Oktober 2022
    #7
  8. MHS1002 hat Ahnung

    Berechnungen Stempel und Pausenzeiten

    Hi zusammen,
    hat hier noch jemand einen Lösungsansatz??

    LG
     
    MHS1002, 6. Oktober 2022
    #8
  9. MHS1002 hat Ahnung
    Nochmals hallo,

    also das erste würde denk ich so funktionieren oder?
    =WENN(ODER(C4="F";C4="T";C4="S";C4="X");WENN(REST(L4-K4+J4-I4+H4-G4;1)>=ZEIT(6;;);ZEIT(;30;);""))

    Wie geht denn das dann mit der Uhrzeit wenn Zeit zwischen?
    Bezug auf C4 wenn Inhalt "N" und Anwesenheit zwischen 03:30 und 04:00 Uhr dann 30min berechnen:
    =WENN(C4="N"(REST(L4-K4+J4-I4+H4-G4;1)=ZEIT(zwischen 03:30 uhr und 04:00 Uhr);ZEIT(;30;);"") ???

    Grüße
     
    MHS1002, 6. Oktober 2022
    #9
  10. Exl121150 Erfahrener User
    Hallo,

    da du völlig unbescheidene Ansprüche an die Formelerstellung gestellt hast, musste ich auf Funktionen aus Excel365 Insider Beta ausweichen, indem ich die LAMBDA-Funktion verwendete und damit 2 benutzerdefinierte Funktionen erstellte und sie in den Formelmanager einfügte:

    Die erste LAMBDA-Funktion: IstPause(SA;SE;NA;NE) benötigt 4 Parameter:
    SA=KommtZeit; SE=GehtZeit; NA=Anwesenheit.Anfang; NE=Anwesenheit.Ende.
    Sie lautet:
    =LAMBDA(SA;SE;NA;NE;LET(NEN;NE-(NE>NA); SEN;SE+(SA>SE); NZ;MAX(0;MIN(NEN+1;SEN)-MAX(NA;SA)) + MAX(0;MIN(NEN;SEN)-SA); WENN(UND(SA=0;SE=0);0;NZ)))

    Die zweite LAMBDA-Funktion: ZeitPause(KoGe;ZtA;ZtE) benötigt 3 Parameter:
    KoGe=ZeilenBereich für 6 Zellen (für 3x: KommtZeit;GehtZeit), ZtA=Anwesenheit.Anfang; ZtE=Anwesenheit.Ende
    Sie lautet:
    =LAMBDA(KoGe;ZtA;ZtE;LET(a;INDEX(KoGe;1;); IstPause(INDEX(a;;1);INDEX(a;;2);ZtA;ZtE) +IstPause(INDEX(a;;3);INDEX(a;;4);ZtA;ZtE) + IstPause(INDEX(a;;5);INDEX(a;;6);ZtA;ZtE)))
    Diese 2. LAMBDA-Funktion verwendet die erste 3x und addiert die sich ergebenden Werte. Kommt dabei eine Zeitdauer größer 0 heraus, liegt eine Pausenberechtigung von 1/2 h vor.

    Die eigentliche Formel in Zelle Q4 lautet:
    =LET(anw;REST(L4-K4+J4-I4+H4-G4;1);
    WENNS(UND(ODER(C4="X";C4="F";C4="T";C4="S");anw>=ZEIT(6;;));ZEIT(;30;);
    UND(C4="SN";ZeitPause(G4:L4;21,5/24;22/24)>0);ZEIT(;30;);
    UND(C4="N";ZeitPause(G4:L4;3,5/24;4/24)>0);ZEIT(;30;);
    WAHR;0))

    Diese kann in die Zellen darunter kopiert werden.

    Falls du die LAMBDA-Funktion noch nicht zur Verfügung hast, müsstest du dir selbst die entsprechenden Formeln zurecht legen. Um die Problematik zu zeigen, ist unter folgendem Link eine Formellösung anstelle der 1. Lambda-Formel (IstPause) zu sehen:
    Nachtschichtarbeitszeit ermitteln * (herber.de)

    Eine modifizierte Datei liegt bei.
     
    Exl121150, 6. Oktober 2022
    #10
  11. MHS1002 hat Ahnung
    Hi,

    vielen Dank für den Ansatz. Ich komm leider mit der Lamdaformel nicht zurecht (hab ich noch nie gemacht. Ich konnte mir aber duch Deinen Link auf die Herber Idee eine Brücke Bauen. In einen zusätzlichen Tabellenblatt habe ich nun folgende Formeln je in einer Zelle:


    Für die "SN" Schichten:
    =WENN(Berechnungen!C6="SN";MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!H6+(Berechnungen!G6>Berechnungen!H6))-MAX($L$3;Berechnungen!G6))+MAX(;(MIN($M$3;Berechnungen!H6+(Berechnungen!G6>Berechnungen!H6))-Berechnungen!G6)*($L$3>$M$3))+MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!H6+0)-$L$3)*(Berechnungen!G6>Berechnungen!H6);"")

    =WENN(Berechnungen!C6="SN";MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!J6+(Berechnungen!I6>Berechnungen!J6))-MAX($L$3;Berechnungen!I6))+MAX(;(MIN($M$3;Berechnungen!J6+(Berechnungen!I6>Berechnungen!J6))-Berechnungen!I6)*($L$3>$M$3))+MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!J6+0)-$L$3)*(Berechnungen!I6>Berechnungen!J6);"")

    =WENN(Berechnungen!C6="SN";MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!L6+(Berechnungen!K6>Berechnungen!L6))-MAX($L$3;Berechnungen!K6))+MAX(;(MIN($M$3;Berechnungen!L6+(Berechnungen!K6>Berechnungen!L6))-Berechnungen!K6)*($L$3>$M$3))+MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!L6+0)-$L$3)*(Berechnungen!K6>Berechnungen!L6);"")

    Für die "N" Schichten
    =WENN(Berechnungen!C6="N";MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!H6+(Berechnungen!G6>Berechnungen!H6))-MAX($L$3;Berechnungen!G6))+MAX(;(MIN($M$3;Berechnungen!H6+(Berechnungen!G6>Berechnungen!H6))-Berechnungen!G6)*($L$3>$M$3))+MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!H6+0)-$L$3)*(Berechnungen!G6>Berechnungen!H6);"")

    =WENN(Berechnungen!C6="N";MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!J6+(Berechnungen!I6>Berechnungen!J6))-MAX($L$3;Berechnungen!I6))+MAX(;(MIN($M$3;Berechnungen!J6+(Berechnungen!I6>Berechnungen!J6))-Berechnungen!I6)*($L$3>$M$3))+MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!J6+0)-$L$3)*(Berechnungen!I6>Berechnungen!J6);"")

    =WENN(Berechnungen!C6="N";MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!L6+(Berechnungen!K6>Berechnungen!L6))-MAX($L$3;Berechnungen!K6))+MAX(;(MIN($M$3;Berechnungen!L6+(Berechnungen!K6>Berechnungen!L6))-Berechnungen!K6)*($L$3>$M$3))+MAX(;MIN($M$3+($L$3>$M$3);Berechnungen!L6+0)-$L$3)*(Berechnungen!K6>Berechnungen!L6);"")

    Für die anderen Schichten:
    =WENN(ODER(Berechnungen!C6="F";Berechnungen!C6="T";Berechnungen!C6="S";Berechnungen!C6="X");WENN(REST(Berechnungen!L6-Berechnungen!K6+Berechnungen!J6-Berechnungen!I6+Berechnungen!H6-Berechnungen!G6;1)>=ZEIT(6;;);ZEIT(;30;);1);"")

    So wie es aussieht, funktioniert das nun ganz gut.
    Schön wäre noch wenn ich die 7 Berchnungen in eine bekommen könnte und ich das zusätzliche Tabellenblatt sparen könnte, aber ich glaub das wird etwas zu kopliziert, oder?
     
    MHS1002, 6. Oktober 2022
    #11
  12. Exl121150 Erfahrener User
    Hallo,

    folgende blaue Formel zur Gänze in deine Formelzelle anstelle meiner kurzen Formel kopieren:
    =LET(
    u; WENN(Berechnungen!$C6<>"SN"; 0; LET( NA;$L$3; NE;$M$3; NNxt;NA>NE; NENxt;NE+NNxt;
    LET(SA;Berechnungen!$G6; SE;Berechnungen!$H6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;Berechnungen!$I6; SE;Berechnungen!$J6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;Berechnungen!$K6; SE;Berechnungen!$L6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt))
    );
    v; WENN(Berechnungen!$C6<>"N"; 0; LET( NA;$N$3; NE;$O$3; NNxt;NA>NE; NENxt;NE+NNxt;
    LET(SA;Berechnungen!$G6; SE;Berechnungen!$H6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;Berechnungen!$I6; SE;Berechnungen!$J6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;Berechnungen!$K6; SE;Berechnungen!$L6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt))
    );
    w; WENN(ODER(Berechnungen!$C6="F";Berechnungen!$C6="T";Berechnungen!$C6="S";Berechnungen!$C6="X");
    REST(Berechnungen!$L6-Berechnungen!$K6+ Berechnungen!$J6-Berechnungen!$I6+ Berechnungen!$H6- Berechnungen!$G6;1)>=ZEIT(6;;);0);
    WENN(u+v+w>0;ZEIT(;30;);0)
    )

    Dazu noch folgende Bemerkung:
    In deinem ersten Posting hast du 2 verschiedene Zeiten für die beiden Schichten SN bzw. N angegeben (SN: von 21:30 bis 22:00; N: von 3:30 bis 4:00)
    Im Formel-Posting von gestern abends hast du statt dessen für beide Schichten die Zellen $L$3 und $M$3 verwendet.
    In meinen Formeln oben habe ich für Schicht SN die Zellen $L$3 und $M$3 und für Schicht N die Zellen $N$3 und $O$3 verwendet - ich habe sie dir oben fett+dunkelbau gekennzeichnet.

    Ich konnte die Formeln, die gemäß Herber anfallen würden, durch Verwendung der LET-Funktion doch entscheidend optimieren - sonst wären sie erheblich länger geworden.
     
    Exl121150, 7. Oktober 2022
    #12
  13. MHS1002 hat Ahnung

    Berechnungen Stempel und Pausenzeiten

    Hi,
    wow nun bin ich baff. Erstens ja da war noch eine falsche Zuordnung in meinem Post! Vielen Dank!
    Durch Deine Formel konnte ich mir die komplette Hilfstabelle schenken. Tausend Dank dafür!!



    Ich hab die Formel nun so angepasst, dass ich sie auf dem eigl. Tabellenblatt benutzen kann.

    =LET(
    u; WENN($C6<>"SN"; 0; LET( NA;$H$2; NE;$I$2; NNxt;NA>NE; NENxt;NE+NNxt;
    LET(SA;$G6; SE;$H6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$I6; SE;$J6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$K6; SE;$L6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt))
    );
    v; WENN($C6<>"N"; 0; LET( NA;$H$3; NE;$I$3; NNxt;NA>NE; NENxt;NE+NNxt;
    LET(SA;$G6; SE;$H6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$I6; SE;$J6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$K6; SE;$L6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt))
    );
    w; WENN(ODER($C6="F";$C6="T";$C6="S";$C6="X");
    REST($L6-$K6+ $J6-$I6+ $H6- $G6;1)>=ZEIT(6;;);0);
    WENN(u+v+w>0;ZEIT(;30;);0)
    )


    Ich hab noch einen Berechnungsfehler (liegt nicht an der Formel) den ich bis jetzt übersehen habe. Vielleicht lässt sich das noch modifizieren. Im allerletzten Teil

    WENN(ODER($C6="F";$C6="T";$C6="S";$C6="X");
    REST($L6-$K6+ $J6-$I6+ $H6- $G6;1)>=ZEIT(6;;);0);
    WENN(u+v+w>0;ZEIT(;30;);0)

    Hier möchte ich wenn mehrere Stempelungen vorhanden sind, (also wenn hier was steht "$J6-$I6+ $H6- $G6") die Regel >Zeit(6;;) außen vor lassen.
    Sprich wenn man auf Tagschicht mehrfach stempelt soll keine Pause abgezogen werden.

    Nochmals vielen vielen Dank!
     
    MHS1002, 7. Oktober 2022
    #13
  14. Exl121150 Erfahrener User
    Hallo,

    da ich aus deinem letzten Posting nicht genau entnehmen, wie deine letzte Zeitregel zu verstehen ist, habe ich dir 2 Varianten erstellt:

    1.Variante: Die 6-Stunden-Regel gilt nur dann, wenn nur eine einzige Stempelung vorliegt und diese dann mindestens 6 Stunden beinhaltet. Sobald eine zweite bzw. dritte Stempelung vorliegt, egal wieviel Zeit die einzelne Stempelung umfasst, gibt es keine Pausenberechnung:
    =LET(
    u; WENN($C6<>"SN"; 0; LET( NA;$H$2; NE;$I$2; NNxt;NA>NE; NENxt;NE+NNxt;
    LET(SA;$G6; SE;$H6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$I6; SE;$J6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$K6; SE;$L6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt))
    );
    v; WENN($C6<>"N"; 0; LET( NA;$H$3; NE;$I$3; NNxt;NA>NE; NENxt;NE+NNxt;
    LET(SA;$G6; SE;$H6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$I6; SE;$J6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$K6; SE;$L6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt))
    );
    w; WENN(ODER($C6="F";$C6="T";$C6="S";$C6="X");
    UND(ODER(REST($L6-$K6;1)>=ZEIT(6;;); REST($J6-$I6;1)>=ZEIT(6;;); REST( $H6- $G6;1)>=ZEIT(6;;)); ANZAHL2($G6:$L6)=2);0
    );
    WENN(u+v+w>0;ZEIT(;30;);0)
    )


    2.Variante: Die 6-Stunden-Regel gilt dann, wenn mindestens eine Stempelung die 6 Stunden beinhaltet, d.h. es wird jede Stempelung für sich (also nicht in Summe mit eventuell weiteren Stempelungen) gerechnet. Wenn also keine der (bis zu 3) Stempelungen die 6 Stunden beinhaltet, gibt es keine Pausenberechnung.
    =LET(
    u; WENN($C6<>"SN"; 0; LET( NA;$H$2; NE;$I$2; NNxt;NA>NE; NENxt;NE+NNxt;
    LET(SA;$G6; SE;$H6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$I6; SE;$J6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$K6; SE;$L6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt))
    );
    v; WENN($C6<>"N"; 0; LET( NA;$H$3; NE;$I$3; NNxt;NA>NE; NENxt;NE+NNxt;
    LET(SA;$G6; SE;$H6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$I6; SE;$J6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt)+
    LET(SA;$K6; SE;$L6; SNxt;SA>SE; SENxt;SE+SNxt;
    MAX(;MIN(NENxt;SENxt)-MAX(NA;SA))+MAX(;(MIN(NE;SENxt)-SA)*NNxt) + MAX(;MIN(NENxt;SE+0)-NA)*SNxt))
    );
    w; WENN(ODER($C6="F";$C6="T";$C6="S";$C6="X");
    ODER(REST($L6-$K6;1)>=ZEIT(6;;); REST($J6-$I6;1)>=ZEIT(6;;); REST( $H6- $G6;1)>=ZEIT(6;;)); 0
    );
    WENN(u+v+w>0;ZEIT(;30;);0)
    )
     
    Exl121150, 8. Oktober 2022
    #14
  15. MHS1002 hat Ahnung
    Hi,
    vielen Dank. Die erste Variannte war bzw. ist die richtige und funktioniert nun perfekt!!!
    Das Thema ist somit gelöst. Nochmals vielen vielen Dank an alle die mitgeholfen haben.
    LG
     
    MHS1002, 8. Oktober 2022
    #15
Thema:

Berechnungen Stempel und Pausenzeiten

Die Seite wird geladen...
  1. Berechnungen Stempel und Pausenzeiten - Similar Threads - Berechnungen Stempel Pausenzeiten

  2. Nettotage aus Start- und Enddatum pro Monat berechnen

    in Microsoft Excel Hilfe
    Nettotage aus Start- und Enddatum pro Monat berechnen: Hallo, ich habe ein Sheet mit drei Tabellen. Die erste errechnet mittel Start- und Enddatum die Nettoarbeitstage, in der zweiten sind die Freien Tage eingetragen und die dritte Tabelle sind die...
  3. Berechnung der besten Kombination

    in Microsoft Excel Hilfe
    Berechnung der besten Kombination: Hallo ihr lieben, ich benötige mal euren Rat. Ich möchte gerne in Excel etwas berechnen lassen. Stellt euch vor ihr habt zwei Arten von zelten, in Zelt A passen 8 Personen rein in Zelt B 12....
  4. Einrichtungskosten berechnen

    in Microsoft Excel Hilfe
    Einrichtungskosten berechnen: Hallo Zusammen Ich bin hier mit meinen Excel Skills am Anschlag :confused: Zurzeit arbeite ich an einer Kostenkalkulation von unterschiedlichen Bauteilen, explizit an den Einrichtungskosten, wo...
  5. Formelbezug auf noch nicht existierende Blätter

    in Microsoft Excel Hilfe
    Formelbezug auf noch nicht existierende Blätter: Hallo an alle, ich versuche eine Tabelle zur Prüfung externer Abschlagsrechungen zu erstellen. Es gibt ein Zusammenstellungsblatt das sich jeweils auf den Namen des Tabellenblattes bezieht....
  6. Abfrage eines Feldes mit Berechnung

    in Microsoft Excel Hilfe
    Abfrage eines Feldes mit Berechnung: Moin, ich bin neu im Excel-Programmieren, und habe folgendes Problem nirgendwo gefunden, vielleicht kann mir jemand helfen. Im Feld A1 soll manuell ein Buchstabe eingetragen: z.B.: j / n...
  7. Excel 2016 Daten vom Datum abhängig anzeigen

    in Microsoft Excel Hilfe
    Excel 2016 Daten vom Datum abhängig anzeigen: Liebe Community, nach einer ersten Tabelle mit viel Unterstützung von Klaus-Dieter, vielen Dank hierfür noch mal, habe ich die Tabelle umstrukturiert und für andere Zwecke entfremdet....
  8. Nur eindeutige Werte berechnen aus externer Datei

    in Microsoft Excel Hilfe
    Nur eindeutige Werte berechnen aus externer Datei: Hallo zusammen, ich stehe etwas auf dem Schlauch und hoffe ihr könnt mir weiterhelfen falls es überhaupt möglich ist. Ich habe eine Datei wo die Ergebnisse ausgegeben werden sollen und eine...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden