Office: Farbfelder in Excel zählen

Hallo,

ich habe eine Excel-Tabelle in der man in den Spalten das Datum und in den Zeilen eine Raumnummer hat.
Bei meiner Exceltabelle geht es um das Eintragen verschiedener Kurse in verschiedenen Räumen zu verschiedenen Zeiten.
Die Kurse haben Kategorien: Seminar, Standard 1, Standard 2, praktische Übung.
Diesen Kategorien habe ich Farben zugeordnet.
Da die Kurse verschiedene Namen haben, man sie mit dem Namen einträgt und sich der Name nicht wiederholt, habe ich Probleme beim "auswerten".
Ich habe die Aufgabe auszuwerten, nach Kategorien (Kategorie 1 und 2 zb.).
Ich hätte es am einfachsten gedacht, wenn man die Farben zählt.
Ist in Spalte B4 bis B11 die Farbe rot, dann soll es hochzählen.
Oder: Ist in Spalte B4 bis B11 die Farbe rot und grün, dann soll es jeweils hochzählen.
auf die Art =ZÄHLENWENN(B4:B11;rot)
In meiner Beispieltabelle wäre in Spalte B4 bis B11 die Farbe rot einmal, also wäre für die erste Abfrage eine 1 erschienen im Zielfeld.
In Spalte B4 bis B11 kommt die Farbe rot 1 mal, die Farbe grün 2 mal vor. Also wäre für die zweite Abfrage eine 3 im Zielfeld erschienen.

Geht so etwas?
Danke für eure Hilfe.

Liebe Grüße,

 

Hallo Venya,

meinst Du so:
Excel: Farbige Zellen zählen - so geht's

Gruß,
Lutz

 

Hallo Venya,

Excel hat über 16 Mio. Farben. Da die Farben zu zählen ist problematisch, da das menschliche Auge nur einige Hundert Farbnuancen unterscheiden kann; in Excel aber ein winziger Unterschied schon eine andere Farbe ist.
Falls du dennoch die Farben zählen willst, könnte es mit VBA erreicht werden.

Gruß Sigi

 

Hallo Venya,

auch wenn man Auswertungen nicht über Zellformate vornehmen sollte, ist es möglich. Hier ein an deine Datei angepasstes Makro, es gehört in ein Standardmodul:

Code:

Option Explicit                                                             '  Variablendeklaration erzwingen (erforderlich)

Sub farb_ausw()
    '  wertet in einem festgelegten Bereich aus, wie oft vordefinierte Hintergrundfarben vorkommen
    '  funktioniert auch mit bedingten Formaten
   
    '  Variablen deklarieren
    Dim rngZelle As Range                                                   '  Zelle im Suchbereich
    Dim rngBereich As Range                                                 '  Suchbereich
    Dim intZeile As Integer                                                 '  Zeilenzähler für Farbdeklaration
    Dim lngFarb As Long                                                     '  temporäre Variable für Farbnummer
    Dim intAnz As Integer                                                   '  Zähler für Farbvorkommen
    Set rngBereich = Range("B4:N12")                                        '  Bereich für Auswertung festlegen
    For intZeile = 1 To 4                                                   '  Schleife für Farbermittlung starten
        lngFarb = Cells(intZeile, 16).DisplayFormat.Interior.Color          '  nächste Farbnummer festlegen
        For Each rngZelle In rngBereich                                     '  Suche nach aktueller Farbnummer
            If rngZelle.Interior.Color = lngFarb Then intAnz = intAnz + 1   '  Farbe gefunden - Zähler plus 1
        Next rngZelle                                                       '  nächste Zelle im Suchbereich
        Cells(intZeile, 18) = intAnz                                        '  Anzahl gefundener Farben eintragen
        intAnz = 0                                                          '  Farbzähler auf Null für nächste Zählung
    Next intZeile                                                           '  nächste Farbe aufrufen
End Sub

 

Hallo Venya,

hier noch mal ein etwas anderes Makro, es gehört in das Modul vom Tabellenblatt mit der auszuwertenden Liste. Das Makro startet automatisch, wenn eine Zelle im Wirkbereich angeklickt wird.

Code:

Option Explicit                                                                 '  Variablendeklaration erzwingen (erforderlich)

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    '  wertet in einem festgelegten Bereich aus, wie oft vordefinierte Hintergrundfarben vorkommen
    '  funktioniert auch mit bedingten Formaten
    
    '  Variablen deklarieren
    Dim rngZelle As Range                                                       '  Zelle im Suchbereich
    Dim rngBereich As Range                                                     '  Suchbereich
    Dim intZeile As Integer                                                     '  Zeilenzähler für Farbdeklaration
    Dim lngFarb As Long                                                         '  temporäre Variable für Farbnummer
    Dim intAnz As Integer                                                       '  Zähler für Farbvorkommen
    Dim isect As Range                                                          '  Wirkbereich
    Set rngBereich = Range("B4:N12")                                            '  Bereich für Auswertung festlegen
    Set isect = Application.Intersect(Target, rngBereich)                       '  Wirkbereich setzen
    If Not isect Is Nothing Then                                                '  wenn Veränderung im Wirkbereich, dann ...
        For intZeile = 1 To 4                                                   '  ... Schleife für Farbermittlung starten
            lngFarb = Cells(intZeile, 16).DisplayFormat.Interior.Color          '  ... nächste Farbnummer festlegen
            For Each rngZelle In rngBereich                                     '  ... Suche nach aktueller Farbnummer
                If rngZelle.Interior.Color = lngFarb Then intAnz = intAnz + 1   '  ... Farbe gefunden - Zähler plus 1
            Next rngZelle                                                       '  ... nächste Zelle im Suchbereich
            Cells(intZeile, 18) = intAnz                                        '  ... Anzahl gefundener Farben eintragen
            intAnz = 0                                                          '  ... Farbzähler auf Null für nächste Zählung
        Next intZeile                                                           '  ... nächste Farbe aufrufen
    End If                                                                      '  Ende Intersect
End Sub

 

Oh super, ich danke euch! Ich werde das alles morgen testen. Ihr seid echt spitze.