Office: Feld an bestehende Tabelle mit VBA anfügen

peter k · 20. November 2003

Hallo @ all,

den gängigen Code aus der OH zum erstellen eines neuen TableDefs mit Feldern kennt Ihr sicher, der ist aber trotz gegenteiliger Aussage in der Hilfe nicht geeignet, um an eine bestehende Tabelle ein oder mehr Felder anzufügen.
Zumindet habe ich es nicht hinbekommen.
Kann mir bitte jemand sagen, wie ich es hinbekommen kann ?

Schönen Gruss, Peter

P.S.:
A00 auf win2k
Tabellen liegen in A00 Backend

:)

Reinhard Kraasch · 22. November 2003

Code:

Public Sub AddField1(Optional DBName = "I:\samples\sample.mdb", _
Optional TblName = "MeineTabelle", _
Optional FldName = "MeinNeuesFeld", _
Optional FldType = dbText, _
Optional FldSize = 50)
Dim DB As DAO.Database, Tdf As DAO.TableDef, Fld As DAO.Field
Set DB = DBEngine.OpenDatabase(DBName)
Set Tdf = DB.TableDefs(TblName)
Set Fld = Tdf.CreateField(FldName, FldType, FldSize)
Tdf.Fields.Append Fld
Tdf.Fields.Refresh
Set Fld = Nothing
Set Tdf = Nothing
Set DB = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

geht bei mir problemlos - wie sieht denn dein Code aus!?!

peter k · 22. November 2003

Hallo Reinhard,
danke erstmal für die schnelle Antwort.
Mein 'bisheriger' Code :
Code:

Dim tblDef As TableDef
Dim curDB As DAO.Database

Set tblDef = curDB.CreateTableDef(strTbl)
With tblDef
.Fields.Append .CreateField("strFeld", dbText, 50)
End With
curDB.TableDefs.Append tblDef
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Da hat Access gar nichts gemacht, ausser sich stillschweigend aus der Verarbeitung zu verabschieden, als wäre nichts gewesen.

Bei Deinem Code sagt es mir beim 'append' das die Operation nicht für verknüpfte Tabellen möglich sei...
Bei einer internen geht er bei mir auch ;-)
Das ist aber nicht der Grund bei meinem Code, da der bei einer Tabelle im Frontend auch nicht funzt...

ein bisschen ratlos,
Peter

Reinhard Kraasch · 22. November 2003

Nun ja - in meinem Code musst du natürlich den Pfad zur Backend-Datenbank (und auch den dortigen Tabellennamen) verwenden.

Und in deinem Code fehlt ja fast alles... Zum einen wird weder CurDB noch strTbl initialisiert, weiterhin wird das Feld ja wohl nicht "strFeld" heissen sollen und drittens arbeitest du so ja in der lokalen Datenbank und nicht im Backend!

peter k · 22. November 2003

Hallo Reinhard,

ähem, ja. Du hast recht, ich hatte meinen Code so ziemlich auf das nötigste reduziert, curDB wird bei mir schon initialisiert, strTbl kommt als Parameter in die Funktion, ist so gesehen auch initialisiert.
Ich denke aber, Dein Hinweis

drittens arbeitest du so ja in der lokalen Datenbank und nicht im Backend!
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

trifft den Nagel auf den Kopf und zeigt meinen Fehler.
Ich denke, Ich bekomme mein Problem nun dank Deiner Hilfe in den Griff.
Wenn ich dazu komme (lerne gerade intensivst XML), werde ich für die nachfolgenden Sucher meine Lösung für den Zugriff auf das Backend hier anhängen.

Danke, Peter

peter k · 22. November 2003

Hallo Reinhard,
Hallo @ all.

So, da bin ich wieder, ich hatte Deinen Code mal fuer mich angepasst, und es lief auch wunderbar.
Bis zu dem Punkt, dass ich eine Trennung eingebaut habe, welche prüft, ob die fragliche Tabelle im Backend liegt oder lokal ist.
Den Code gebe ich mal zu besten :
Code:

Public Function tbl_alleFelder(strTbl As String, _
fldName As String, fldType As String, _
Optional fldSize As String)
Dim tblDef As DAO.TableDef
Dim tabDef As DAO.TableDef
Dim fldDef As DAO.Field
Dim curDB As DAO.Database
Dim DB As DAO.Database
Dim DBbeName As String

' Name der Backend-Datei ermitteln
DBbeName = tbl_DB_BEname

Set DB = CurrentDb
Set tabDef = DB.TableDefs
' bis hierhin und nicht weiter ...
If DB.TableDefs(strTbl).Connect > "" Then
' Tabelle ist aus Backend verknuepft
Set curDB = DBEngine.OpenDatabase(DBbeName)
Else
' Tabelle ist lokal vorhanden
Set curDB = CurrentDb
End If

Set tblDef = curDB.TableDefs(strTbl)
Set fldDef = tblDef.CreateField(fldName, fldType)
tblDef.Fields.Append fldDef
tblDef.Fields.Refresh
Set fldDef = Nothing
Set tblDef = Nothing
Set curDB = Nothing
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Sicher bin ich wieder zu blöd, richtig nachzudenken, oder habe irgend einen anderen Fehler eingebaut...
Aber welchen, ich werde noch verrückt, aber da ändert sich wohl auch nur noch die Bezeichnung.
Also fals mir bitte nochmal jemand auf die Sprünge helfen möge.

Danke im voraus,
Peter

Nouba · 23. November 2003

der folgende Kode ist ungetestet
Code:

Public Function tbl_alleFelder( _
BackendName As String _
, TblName As String _
, FldName As String _
, FldType As String _
, Optional FldGroesse)

Dim ws As DAO.Workspace
Dim tdfX As DAO.TableDef
Dim tdfLinked As DAO.TableDef
Dim dbCur As DAO.Database
Dim dbX As DAO.Database
Dim blnFeldVorhanden As Boolean
Dim i As Integer

On Error GoTo Fehlerbehandlung

'// aktuellen Workspace festlegen
Set ws = DBEngine.Workspaces(0)

'// aktuelle Datenbank (Frontend)
Set dbCur = CurrentDb()

'// Backend Datenbank exklusiv öffnen
Set dbX = ws.OpenDatabase(BackendName, True)

'// wenn die Tabelle im Backend existiert,
'// wollen wir aktiv werden
If TabelleExistiert(dbX, TblName) Then
Set tdfX = dbX.TableDefs(TblName)

'// mit unserer Tabelle
With tdfX
'// wenn es das Feld schon gibt, setzen wir
'// die Variable blnSchonVorhanden auf Wahr
For i = 0 To .Fields.Count - 1
If .Fields(i).Name = FldName Then
blnFeldVorhanden = True
Exit For
End If
Next i

'// das Feld kann angehangen werden
If Not blnFeldVorhanden Then
If IsMissing(FldGroesse) Then
.Fields.Append .CreateField(FldName, FldType)
Else
.Fields.Append .CreateField(FldName, FldType, FldGroesse)
End If

'// Feldliste der Tabelle auffrischen
.Fields.Refresh

'// alten Link nötigenfalls im Frontend löschen
If TabelleExistiert(dbCur, TblName) Then
dbCur.TableDefs.Delete TblName
End If

'// Verknüpfung zur temporären Tabelle herstellen
Set tdfLinked = dbCur.CreateTableDef(TblName)

'// Verbindungszeichenkette auf Backend festlegen
tdfLinked.Connect = ";DATABASE=" & BackendName

'// Tabellenname bekanntgeben
tdfLinked.SourceTableName = TblName

'// den Tabellenerklärungen anhängen ...
dbCur.TableDefs.Append tdfLinked

'// und aktualisieren
dbCur.TableDefs.Refresh

' damit wir es auch im Datenbankfenster sehen
RefreshDatabaseWindow

End If
End With
Else
MsgBox "Tabelle ist nicht im BE vorhanden!"
End If

RausHier:

Set tdfX = Nothing
Set tdfLinked = Nothing
Set dbX = Nothing
Set dbCur = Nothing
Set ws = Nothing

On Error GoTo 0
Exit Function

Fehlerbehandlung:
MsgBox "Fehler: " & Err.Number & " (" & Err.Description & ") in Routine " _
& "tbl_alleFelder"
Resume RausHier

End Function

Private Function TabelleExistiert( _
Database As DAO.Database _
, strTableName As String) As Boolean

Dim tdf As DAO.TableDef

On Error Resume Next

Database.TableDefs.Refresh
Set tdf = Database(strTableName)

'// z.B. Zugriff aus Sicherheitsgründen verweigert, Tabelle nicht vorhanden, etc.
TabelleExistiert = (Err = 0)

End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Office: Feld an bestehende Tabelle mit VBA anfügen

Feld an bestehende Tabelle mit VBA anfügen

Feld an bestehende Tabelle mit VBA anfügen

Feld an bestehende Tabelle mit VBA anfügen

Feld an bestehende Tabelle mit VBA anfügen - Similar Threads - Feld bestehende Tabelle

Formular: Dropdown-Felder "verknüpfen"?

Formular Wert per Klick in ein anderes Feld übernehmen

Schätzspiel auswerten

Keine Feldaktualisierung über Abschnittsumbrüche hinaus

Felder: Hochgestellter Text bleibt nicht erhalten

Feld in Abhängigkeit eines Dropdowns

Intelligente Tabelle mit mehreren Überschrift-Feldern