Office: (Office 2019) filtern

hallo an die freundlichen helfer
ich trage trainingskilometer in eine tabelle ( siehe unten ) ein.
Spalte A filter ich monatlich.
Ich hätte dann für die einzelnen sportarten jeweils die kilometer.
Im beispiel formelergebnis für rad 1 + rad 2 im september.2025 ; 82 Km

Vielleicht kann mir jemand hierbei helfen
schonmal vielen dank gruß didje

 

Hola,
bitte ein Datei und kein Bildchen hochladen.
Gruß,
steve1da

 

Hallo,

welche Office Version nutzt du?
Und eine Beispieldatei wäre sinnvoll.

Gruß Uwe

 

ich benutze noch excel 2002

 

Keine Ahnung ob das in der Uralt Version klappt
=SUMMENPRODUKT(TEILERGEBNIS(9;INDIREKT("C"&ZEILE(S1:S100)))*(MONAT(A1:A100)=9)*((B1:B100="rad 1")+(B1:B100="rad 2")))

Alternativ:
=SUMME(WENN((MONAT(A1:A100)=9)*((B1:B100="rad 1")+(B1:B100="rad 2"));C1:C100))
Diese Formel musst du mit Strg-Shift-Enter abschließen.

 

Hallo,

verpasse Deinen Daten eine Überschrift, dann kannst Du filtern und mit TEILERGEBNIS arbeiten:

 

Hallo,

Nur eine kleine Übung für mich. Diese Formel läuft ab Office 2021:
In Zelle F2: Rad 1, in Zelle F3 Rad 2, in G2 Monatsziffer und in H2 Jahreszahl schreiben.
Formel in D1:

Code:

=LET(xa; FILTER(A1:C13; ((B1:B13=F2)+(B1:B13=F3)) * (A1:A13>=DATUM(H2;G2;1)) * (A1:A13<DATUM(H2;G2+1;1)); "kein Passender Wert gefunden"); SUMME(INDEX(xa;;3)))

Gruß Uwe

 

Hi Uwe,

das geht auch so:

Code:

=LET(xa;A1:A13;xb;B1:B13;SUMME(FILTER(C1:C13;((xb=F2)+(xb=F3)>0)*(MONAT(xa)=G2)*(JAHR(xa)=H2);"kein Wert")))

 

Hallo,

mit Excel365 geht es auch so:
=PIVOTMIT($B:.$B; MONAT($A:.$A); $C:.$C; SUMME)
oder
=PIVOTMIT($B:.B;TEXT($A:.$A;"MM.JJJJ");$C:.$C;SUMME)