Office: Formel für jeden Mittwoch und Donnerstag

Helfe beim Thema Formel für jeden Mittwoch und Donnerstag in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo. Ich brauche eine Tabelle für Termine nur für Mittwochs und Donnerstag, d.h. in der ersten Zeile sollen automatisch nur diese beiden Tage... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von tiger, 4. November 2010.

  1. tiger User

    Formel für jeden Mittwoch und Donnerstag


    Hallo.
    Ich brauche eine Tabelle für Termine nur für Mittwochs und Donnerstag, d.h. in der ersten Zeile sollen automatisch nur diese beiden Tage erscheinen. Start Mittwoch 10.11.2010 (in Zelle B3) Ich brauche eine Formel dafür. Wer kann mir bitte helfen?
    Vielen Dank,
    tiger
     
  2. schatzi Super-Moderator
    Hallo!

    So?

     BCDEFG
    310.11.201011.11.201017.11.201018.11.201024.11.201025.11.2010
    ZelleFormel
    C3=B3+6-5*REST(SPALTE();2)
    D3=C3+6-5*REST(SPALTE();2)
    E3=D3+6-5*REST(SPALTE();2)
    F3=E3+6-5*REST(SPALTE();2)
    G3=F3+6-5*REST(SPALTE();2)
     
    Zuletzt von einem Moderator bearbeitet: 30. November 2020
    schatzi, 4. November 2010
    #2
  3. tiger User
    Hallo Schatzi.
    Vielen Dank für die schnelle Hilfe!
     
  4. Kallewirsch Erfahrener User

    Formel für jeden Mittwoch und Donnerstag

    Hallo,

    hier noch eine Version, die unabhängig von Zeilen und Spalten ist:

    Arbeitsblatt mit dem Namen 'Tabelle1'
     ABCDEF
    110.11.201011.11.201017.11.201018.11.201024.11.201025.11.2010
    ZelleFormel
    B1=A1+VERWEIS(REST(A1;7);{4;5};{1;6})
    C1=B1+VERWEIS(REST(B1;7);{4;5};{1;6})
    <table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]
    Gruß

    Edgar
     
    Zuletzt von einem Moderator bearbeitet: 30. November 2020
    Kallewirsch, 4. November 2010
    #4
  5. rainberg Erfahrener User
    Hallo miteinander,

    aller guten Dinge sind drei, deshalb noch mein Senf zum Thema :-D

    Arbeitsblatt mit dem Namen 'Tabelle1'
     ABCDEF
    110.11.201011.11.201017.11.201018.11.201024.11.201025.11.2010
    ZelleFormel
    B1=A1+WAHL(WOCHENTAG(A1;2);0;0;1;6;0;0;0)
    C1=B1+WAHL(WOCHENTAG(B1;2);0;0;1;6;0;0;0)
    D1=C1+WAHL(WOCHENTAG(C1;2);0;0;1;6;0;0;0)
    E1=D1+WAHL(WOCHENTAG(D1;2);0;0;1;6;0;0;0)
    F1=E1+WAHL(WOCHENTAG(E1;2);0;0;1;6;0;0;0)
     
    Zuletzt von einem Moderator bearbeitet: 30. November 2020
    rainberg, 5. November 2010
    #5
  6. wilfried07 Erfahrener User
    Hallo Excelfreunde!

    Ich suche eine Formel für eine Datumreihe die
    Montag, Mittwoch, Freitag ausgibt.
    An diesen Tagen arbeite ich.

    Wäre nett wenn mir wer eine Formel basteln könnte.

    Danke

    Gruß
    Wilfried
     
    wilfried07, 5. November 2010
    #6
  7. rainberg Erfahrener User
    Hallo Wilfried,

    Arbeitsblatt mit dem Namen 'Tabelle1'
     ABCDEF
    101.11.201003.11.201005.11.201008.11.201010.11.201012.11.2010
    ZelleFormel
    B1=A1+WAHL(WOCHENTAG(A1;2);2;0;2;0;3;0;0)
    C1=B1+WAHL(WOCHENTAG(B1;2);2;0;2;0;3;0;0)
    D1=C1+WAHL(WOCHENTAG(C1;2);2;0;2;0;3;0;0)
    E1=D1+WAHL(WOCHENTAG(D1;2);2;0;2;0;3;0;0)
    F1=E1+WAHL(WOCHENTAG(E1;2);2;0;2;0;3;0;0)
     
    Zuletzt von einem Moderator bearbeitet: 30. November 2020
    rainberg, 5. November 2010
    #7
  8. rainberg Erfahrener User

    Formel für jeden Mittwoch und Donnerstag

    Hallo Wilfried,

    wenn das Startdatum kein Montag ist, dann so:

    Arbeitsblatt mit dem Namen 'Tabelle1'
     ABCDEFG
    106.11.201008.11.201010.11.201012.11.201015.11.201017.11.201019.11.2010
    ZelleFormel
    B1=A1+WAHL(WOCHENTAG(A1;2);2;1;2;1;3;2;1)
    C1=B1+WAHL(WOCHENTAG(B1;2);2;1;2;1;3;2;1)
    D1=C1+WAHL(WOCHENTAG(C1;2);2;1;2;1;3;2;1)
    E1=D1+WAHL(WOCHENTAG(D1;2);2;1;2;1;3;2;1)
    F1=E1+WAHL(WOCHENTAG(E1;2);2;1;2;1;3;2;1)
    G1=F1+WAHL(WOCHENTAG(F1;2);2;1;2;1;3;2;1)
     
    Zuletzt von einem Moderator bearbeitet: 30. November 2020
    rainberg, 5. November 2010
    #8
  9. Kallewirsch Erfahrener User
    Hallo,

    dazu auch noch die Verweis-Variante:

    Code:
    =A1+VERWEIS(REST(A1;7);{2;4;6};{2;2;3})
    Gruß

    Edgar
     
    Kallewirsch, 5. November 2010
    #9
  10. wilfried07 Erfahrener User
    Hallo Rainer!

    Danke für die Formel diese ist OK.
    Kannst Du mir noch erkären wie sie funktionert.

    =A1+WAHL(WOCHENTAG(A1;2);2;0;2;0;3;0;0)
    wieso 3 ??

    Wie müsste die Formel lauten wenn ic zB Donnerstag
    und Sonntag dazunehme?

    Danke für eine Anwort
    Gruß
    Wilfried
     
    wilfried07, 5. November 2010
    #10
  11. rainberg Erfahrener User
    Hallo Wilfried,

    in der Formel sind hinter der Funktion WOCHENTAG() 7 Argumente , getrennt durch Semikolon, angeordnet.
    - das erste Argument = gleichbedeutend mit dem 1. Tag der Woche
    - das zweite Argument = gleichbedeutend mit dem 2. Tag der Woche
    - das dritte Argument = gleichbedeutend mit dem 3. Tag der Woche
    - usw.

    Wenn z.B. im 3. Argument die Zahl 2 steht, dann bedeutet das nichts anderes wie WENN(WOCHENTAG(A1;2)=3 (also Mittwoch), dann zähle zu A1 2 Tage dazu.
    Also es wird immer die Zahl an Tagen, die dem gerade in A1 stehenden Wochentag zugeordneten Argument addiert.

    Dem nach müsste die Formel unter Einbeziehung des Donnerstag so lauten

    =A1+WAHL(WOCHENTAG(A1;2);2;0;1;1;3;0;0)

    Bei dieser Formel ist das Startdatum immer ein Montag, ansonsten müsstest Du die Formel aus meinem 2. Beitrag anpassen.
     
    rainberg, 5. November 2010
    #11
  12. wilfried07 Erfahrener User
    Hallo Rainer!

    Danke für die Erklärung.

    Gruß
    Wilfried
     
    wilfried07, 5. November 2010
    #12
  13. hiob
    hiob Erfahrener User

    Formel für jeden Mittwoch und Donnerstag

    hi Wilfried, hier mal meine variante... egal welches datum in A2 beginnt die liste mit dem nächsten freitag, montag oder mittwoch...:

    Arbeitsblatt mit dem Namen 'Tabelle3 (3)'
     A
    1 
    2Do, 29.07.2010
    3 
    4Fr, 30.07.2010
    5Mo, 02.08.2010
    6Mi, 04.08.2010
    7Fr, 06.08.2010
    8Mo, 09.08.2010
    9Mi, 11.08.2010
    10Fr, 13.08.2010
    11Mo, 16.08.2010
    12Mi, 18.08.2010
    13Fr, 20.08.2010
    14Mo, 23.08.2010
    15Mi, 25.08.2010
    16Fr, 27.08.2010
    17Mo, 30.08.2010
    ZelleFormel
    A4=MIN(E3-REST(E3-2-1;7)+7*1-1;E3-REST(E3-2-3;7)+7*1-1;E3-REST(E3-2-5;7)+7*1-1)
    A5=A4+WAHL(WOCHENTAG(A4;2);2;;2;;3)
    <table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]
     
    Zuletzt von einem Moderator bearbeitet: 30. November 2020
  14. wilfried07 Erfahrener User
    Hallo hiob!

    Kannst Du mir bitte die Formel erklären.

    Was steht in E3 ? (stehen hier die Tage die gesucht werden?)

    Danke für eine Antwort

    Gruß
    Wilfried
     
    wilfried07, 10. November 2010
    #14
  15. hiob
    hiob Erfahrener User
    hi Willfried, sorry, nee, da ist ein kalendermodul (aus einer real existirenden datei), die ein datum als text liefert, also das startdatum - so wie in A2, ich hatte nur vergessen den bezug auf A2 zu setzen....
     
Thema:

Formel für jeden Mittwoch und Donnerstag

Die Seite wird geladen...
  1. Formel für jeden Mittwoch und Donnerstag - Similar Threads - Formel Mittwoch Donnerstag

  2. Formel auf andere Zellen unterschiedlicher Größe anwenden

    in Microsoft Excel Hilfe
    Formel auf andere Zellen unterschiedlicher Größe anwenden: Hallo zusammen, ich habe eine Formel gebastelt, die wie angehängt in der Beispiel-Excel zu sehen ist, funktioniert. Kann ich die Formel so vereinfachen, dass ich nicht 3x die angepasste Formel...
  3. Summewenns erkennt text aus der formel nicht

    in Microsoft Excel Hilfe
    Summewenns erkennt text aus der formel nicht: Hallo zusammen, ich habe ein Problem das meine Formel Summewenns nicht den ausgegebenen Text in der Zelle erkennt!! Bekomme das einfach nicht hin. In der Zelle B8:B60 wird der Monat mit einer...
  4. Hilfe für Formel erstellen

    in Microsoft Excel Hilfe
    Hilfe für Formel erstellen: Ich möchte den Fremdwährungsbestand automatisieren. Das heisst den Bestand automatisch bewirtschaften. Zum Beispiel Wieviel Noten ich von einer Sorte bestellen muss, wenn Lagerbestand nur noch 10...
  5. Formel verkleinern

    in Microsoft Excel Hilfe
    Formel verkleinern: Frage an die Community, kann man diese Formel...
  6. Bedingte Formatierung funktioniert nicht

    in Microsoft Excel Hilfe
    Bedingte Formatierung funktioniert nicht: Hallo, ich habe eine Excel Datei erstellt und es funktioniert alles, bis auf eine bedingte Formatierung. Ich verstehe einfach nicht wieso. Habe in der Liste schon andere Formatierungen, die sehr...
  7. Formel zum ermitteln des zweiten Mittwoch im Monat

    in Microsoft Excel Hilfe
    Formel zum ermitteln des zweiten Mittwoch im Monat: Servus an alle Experten in diesem Forum, ich hoffe, mir kann jemand mit dem folgenden Problem weiterhelfen: Ich benötige eine Formel, welche mir (u. a.) den nächsten 2. Mittwoch im Monat in eine...
  8. Formel für jeden Mittwoch im Jahr 2014

    in Microsoft Excel Hilfe
    Formel für jeden Mittwoch im Jahr 2014: Hallo zusammen, ich benötige eine Formel, die mir jeden Mittwoch im Jahr 2014 ausgibt, idealerweise sogar noch mit der Info, ob an dem Tag ein Feiertag war bzw. alternativ die Feiertage einfach...

Users found this page by searching for:

  1. excel befehl alle mittwoche datum

  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden