Office: (Office 2007) Formel von waagerecht auf senkrecht kopieren

Hallo,
bin "armer" Azubi. Hier mein Problem:

in einem Register von einer Arbeitsmappe stehen Ländernamen senkrecht untereinander. Diese hätte ich gerne in eine anderes Register als Formel kopiert, aber waagerecht.

Mit > kopieren >einfügen / transponiert gehts leider nicht, da keine Formelverweis angezeigt wird. Änderungen im Ursprungsregister werden daher nicht übernommen.

Hat jemand ne Lösung für mich???

:)

 

hiho

=INDIREKT("Tabelle1!Z"&SPALTE(A1)&"S"&ZEILE(A1);0)
Tabellennamen und Startzelle anpassen

 

Servus,

danke für deinen Beitrag, bekomme es aber leider nicht hin. Hier noch ein paar Infos:

Das ursprüngliche Registerblatt heißt Land. Dort beginnen die Werte in Zelle G3 und hören in G60 auf. Das sind die senkrechten Werte.

Diese sollen jetzt waagerecht als Formel ins neue Registerblatt (nennen wirs einfach "Neu") eingefügt werden.

Wie würde da die konkrete Formel aussehen? Kann ich die dann einfach waagerecht kopieren?

Vielen Dank!!!

 

hiho

=INDIREKT("Land!Z"&SPALTE(C1)&"S"&ZEILE(A7);0)

*Smilie
oder

=INDIREKT("Land!Z"&SPALTE(C1)&"S3"0)

 

Sorry,
ich versteh's immer noch nicht. Kannst du mir vielleicht kurz die Formel erklären? Bin noch nicht so fit in Excel. Vielleicht füg ich das ganze an der falschen Stelle ein oder setze falsche Werte ein. Fehlen noch Angaben?

Danke!!

 

hiho

die Funktion Indirekt
gibt Dir einfach einen Zellbezug wieder
der als string (Text) vorliegt

=indirekt("A1")

wäre eigentlich nichts anderes als =A1


in der Z1S1 Bezugsmethode

=Indirekt("Z1S3";0)

wäre das = C1
(Zeile 1 und Spalte 3)

da Du wagrecht und senkrecht tauschen willst, musst Du Zeilen zu Spalten und Spalten zu Zeilen machen

=Spalte() gibt an in welcher Spalte (Nr.) du Dich gerade befindest
=Zeile() ->ZeilenNr.

=Zeile(a4) -> würde 4 ergeben

=Spalte(C999) -> würde 3 ergeben da Spalte C

du hast geschrieben ab G3

deshalb

=INDIREKT("Land!Z"&SPALTE(C1)&"S"&ZEILE(A7);0)

da du ja die Formel nach rechts kopieren möchtest

=Spalte(c1) ist ->3
kopierst Du das weiter
steht in der Formel spalte(D1) ->4
usw.

hmmm,
vielleicht ist das leichter Verständlich

=INDIREKT(ADRESSE(SPALTE(C1);7;;;"Land"))

=Adresse(Zeile,Spalte)

ein kleines Edit noch vorige Formel war Falsch

=INDIREKT("Land!Z"&SPALTE(C1)&"S3"0)

da ja spalte G gesucht wurde
richtig wäre

=INDIREKT("Land!Z"&SPALTE(C1)&"S7";0)

 

Hallo SeMi,

eine Alternative wäre noch

=BEREICH.VERSCHIEBEN(Land!$G3;SPALTE(A:A)-1;;; )

Diese Formel hat den Vorteil, bei Änderung des Tabellennamens keine Änderung in der Formel machen zu müssen.

 

markieren, kopieren und beim Einfügen die Option "transponieren" wählen.

 

Hallo Rainer

wieso sollte das mit indirekt nicht gehen
*Smilie

=INDIREKT(RECHTS(ZELLE("Dateiname";Land!A1);LÄNGE(ZELLE("Dateiname";Land!A1))-FINDEN("]";ZELLE("Dateiname";Land!A1);1))&"!Z"&SPALTE(C1)&"S7";0)

p.s aber du hast schon Recht bereich.verschieben ist besser
*Smilie

 

Hallo Chris,

ich habe nicht behauptet, dass es nicht geht, aber ich gebe der Funktion BEREICH.VERSCHIEBN gegenüber INDIREKT meistens den Vorrang, weil sie einfach dynamischer ist.

 

Hallo Rainer

ich meinte dynamisch!!!
indirekt geht auch dynamisch siehe meine Formel
*Smilie

sry, wollte Dich nicht verwirren

 

Danke euch!!!!

Ihr habt mir wirklich weitergeholfen. Hab mich dann für Rainers Lösung entschieden. Sie schien mir etwas einfacher. Und wenn man nicht so viel Ahnung hat ist man nur froh, wenns läuft. Konnte sie dann auch einfach kopieren. Chris, dir auch vielen Dank für deine ausführliche Erklärung.

Gruß Sebastian