Office: Inhalt einer Zelle in viele Zeilen und zwei Spalten

Hallo,

meine Zelle A1 sieht bsp. so aus:

Pauluskirchstr. – Hangelar Kirche 12.39 – B 56 (Richtung St.Augustin) – Meindorf 12.48 – Menden Mittelstr. 12.51 – Menden Markt 12.52 – Menden Schulzentrum – Mülld. Fährstr. 12.56 – Hongsburg 13.00 – Wohnpark 13.02 – Npl. Schulzentrum 13.04 – Buisdorf 13.05

ich möchte gern mit ein oder mehreren Funktionen automatisiert sowas draus machen:

A Haltestellenname|B Uhrzeit
Pauluskirchstr.|
Hangelar Kirche|12:39
B 56 (Richtung St.Augustin)|
Meindorf|12:48
Menden Mittelstr.|12:51
Menden Markt|12:52
Menden Schulzentrum|
Mülld. Fährstr. 12:56|
Hongsburg|13:00
Wohnpark|13:02
NPL. Schulzentrum|13:04
Buisdorf|13:05

Kann mir jemand helfen?

Viele Grüße,
Mat

 

Hallo!

Nicht ganz einfach, zumal der Trennstrich ja auch noch ein Sonderzeichen (150) zu sein scheint...
Mit der Hilfsspalte A lässt sich dein Wunsch in B und C aber darstellen:

	A	B	C
1	Pauluskirchstr. – Hangelar Kirche 12.39 – B 56 (Richtung St.Augustin) – Meindorf 12.48 – Menden Mittelstr. 12.51 – Menden Markt 12.52 – Menden Schulzentrum – Mülld. Fährstr. 12.56 – Hongsburg 13.00 – Wohnpark 13.02 – Npl. Schulzentrum 13.04 – Buisdorf 13.05
2
3	Pauluskirchstr.	Pauluskirchstr.
4	Hangelar Kirche 12.39	Hangelar Kirche	12:39
5	B 56 (Richtung St.Augustin)	B 56 (Richtung St.Augustin)
6	Meindorf 12.48	Meindorf	12:48
7	Menden Mittelstr. 12.51	Menden Mittelstr.	12:51
8	Menden Markt 12.52	Menden Markt	12:52
9	Menden Schulzentrum	Menden Schulzentrum
10	Mülld. Fährstr. 12.56	Mülld. Fährstr.	12:56
11	Hongsburg 13.00	Hongsburg	13:00
12	Wohnpark 13.02	Wohnpark	13:02
13	Npl. Schulzentrum 13.04	Npl. Schulzentrum	13:04
14	Buisdorf 13.05	Buisdorf	13:05

Zelle	Formel
A3	=TEIL(" – "&A$1&" – ";FINDEN("##";WECHSELN(" – "&A$1&" – ";" – ";"##";ZEILE(A1)))+3;FINDEN("##";WECHSELN(" – "&A$1&" – ";" – ";"##";ZEILE(A2)))-FINDEN("##";WECHSELN(" – "&A$1&" – ";" – ";"##";ZEILE(A1)))-3)
B3	=WENN(ISTZAHL(1*WECHSELN(RECHTS(A3;5);".";","));LINKS(A3;LÄNGE(A3)-6);A3)
C3	=WENN(ISTZAHL(1*WECHSELN(RECHTS(A3;5);".";","));ZEIT(TEIL(A3;LÄNGE(A3)-4;2);RECHTS(A3;2););"")

 

Vielen herzlichen Dank, dass hilft mir weiter.

 

Mmh, ich hab doch noch eine Frage:

angenommen ich ergänze meine Liste von A15 bis A18 um sowas hier:

A
13.45 Hanftalschule
13.50 Gesamtschule
13.55 Schule Stoßdorfer Str.
14.00 Schulzentrum

Wie kann ich dann mit zwei ähnlichen Formeln sowas hier in B und C machen:

B|C (Uhrzeit)
Hanftalschule|13:45
Gesamtschule|13:50
Schule Stoßdorfer Str.|13:55
Schulzentrum|14:00

Nochmal danke...

LG, Mat

Edit: Schön wäre es, wenn ich beide Fälle mit nur einer Formel abdecken könnte, um einfach die Formeln in B und C runterziehen zu können. Geht sowas?

 

Hallo!

	A	B	C
15	13.45 Hanftalschule	Hanftalschule	13:45
16	13.50 Gesamtschule	Gesamtschule	13:50
17	13.55 Schule Stoßdorfer Str.	Schule Stoßdorfer Str.	13:55
18	14.00 Schulzentrum	Schulzentrum	14:00

Zelle	Formel
B15	=RECHTS(A15;LÄNGE(A15)-6)
C15	=ZEIT(LINKS(A15;2);TEIL(A15;4;2);)

Aber das auch noch mit deinem ersten Problem in Einklang zu bringen, sehe ich als echte Herausforderung, denn die Darstellung der Daten ist hier ja eine völlig andere...

 

und über eine verschachtelte wenn-dann Formel? :roll:

 

Hallo!

Klar, du kannst versuchen abzufragen, ob die Zeitangabe vorne oder hinten steht und dementsprechend den Eintrag aufzusplitten.
Aber ich denke, das Kind ist bereits mit dieser unvorteilhaften Datendarstellung/-import in den Brunnen gefallen. Solche Probleme sollte man so früh wie möglich beseitigen, sonst zieht das dann eben Monsterformeln nach sich...

 

die unvorteilhaften Datendarstellung ist einem blöden Word-Dokument geschuldet, wo in verschiedenen Spalten unterschiedliche Formate stehen... ich probiers mal mit wenn-dann, denn dann spare ich mir eine Formel immerhin. Nochmal danke für die Hilfe...

LG, Mat

 

Kann man das noch kürzer ausdrücken?

in B3:
=WENN(ISTZAHL(1*WECHSELN(RECHTS(A13;5);".";","));LINKS(A13;LÄNGE(A13)-6);WENN(ISTZAHL(1*WECHSELN(LINKS(A13;4);TEIL(A13;4;2);));RECHTS(A13;LÄNGE(A13)-6);A13))

in C3:
=WENN(ISTZAHL(1*WECHSELN(LINKS(A3;4);TEIL(A3;4;2);));ZEIT(LINKS(A3;2);TEIL(A3;4;2););WENN(ISTZAHL(1*WECHSELN(RECHTS(A3;5);".";","));ZEIT(TEIL(A3;LÄNGE(A3)-4;2);RECHTS(A3;2););""))

Bei mir funktioniert das, ist es auch richtig?

 

Hallo!

Bei mir funktioniert das in Zeile 18 nicht mehr (bei deinen Beispielen).
Probier's mal hiermit (B3 und C3):

=WENN(ISTZAHL(1*WECHSELN(RECHTS(A3;5);".";","));LINKS(A3;LÄNGE(A3)-6);WENN(ISTZAHL(1*WECHSELN(LINKS(A3;5);".";","));RECHTS(A3;LÄNGE(A3)-6);A3))

=WENN(ISTZAHL(1*WECHSELN(LINKS(A3;5);".";","));ZEIT(LINKS(A3;2);TEIL(A3;4;2););WENN(ISTZAHL(1*WECHSELN(RECHTS(A3;5);".";","));ZEIT(TEIL(A3;LÄNGE(A3)-4;2);RECHTS(A3;2););""))

 

Oh ja vielen herzlichen Dank... da war noch der Fehler.

LG, Mat

 

Hallo Schatzi,

mal ne Frage. Ich habe die Formel jetzt erfolgreich angewendet. Die Haltestellen und Zeiten stehen je nach Linie in mehreren Tabellenblättern ab B3/C3.

Kann man mit einem VBA-Makro alle Linien aus all den vorhandenen Tabellenblättern in einem Tabellenblatt beginnend ab B2/C2 hart untereinander automatisch schreiben?

Also Tabellenblatt "1" ("1"=LinienNr):
B|C
Gymnasium|13:45
Gesamtschule|13:50
Schule|13:55
Schulzentrum|14:00

zusammen mit Tabellenblatt "2":
B|C
Burg|14:01
Wohnpark|14:02
Zentrum|14:04

ergibt Tabellenblatt "Linienuebersicht" mit harten Werten:
A|B|C
1|Gymnasium|13:45
1|Gesamtschule|13:50
1|Schule|13:55
1|Schulzentrum|14:00
Leerzeile
2|Burg|14:01
2|Wohnpark|14:02
2|Zentrum|14:04
Leerzeile
3|...|...
usw.

Oder ist das unmöglich?

Viele Grüße,
Mat