Office: (Office 2007) Kommentarfeld-Größe automatisch anpassen

Hallo Excel-Experten *Smilie
wieder mal eine Frage eines Anfängers ...
ich möchte die Kommentarfeld-Größe automatisch an den Inhalt anpassen. Leider war es mir noch nicht möglich hier ein geeignetes Thema zu finden, mit dem ich klar komme.
Mein Code formatiert zwar automatisch, jedoch sehe ich einen Teil mancher Kommentare nicht, wenn kein Zeilenumbruch im Text ist... also die Zeile geht über den Bildschirmrand *eek.gif*
Kann man den Code so ändern, dass ich die Breite vorgebe und die Höhe variabel lasse?

Das ist mein aktueller Code:


Code:

:)

 

Hallo ?,

vielleicht so.

' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************
Option Explicit
Const maxLength As Long = 85 'Maximale Zeichen pro Zeile
Private Sub AutosizeComments()
Dim Cell As Range
For Each Cell In ActiveSheet.Cells.SpecialCells(xlCellTypeComments)
With Cell.Comment.Shape.TextFrame
.Characters.text = breakText(.Characters.text, maxLength)
.AutoSize = True
End With
Next
End Sub

Private Function breakText(ByVal text As String, ByVal länge As Long) As String
Dim tmp As String, str As String
Dim lenT As Integer, i As Integer, n As Integer
text = Replace(text, vbLf, " ")
lenT = Len(text)
n = 1
i = 1
Do
tmp = Mid(text, i, länge)
If lenT - i >= länge Then
n = Len(tmp) - InStr(1, StrReverse(tmp), " ") + 1
Else
n = Len(tmp)
End If
str = str & Trim(Left(tmp, n)) & vbLf
i = i + n
Loop While i < lenT
breakText = Left(str, Len(str) - 1)
End Function





« Gruß Sepp »

 

Hallo Sepp,

vielen Dank für die erstklassige Antwort/Lösung.
Einen kleinen Fehler hat das Makro aber noch.. bei längeren Texten hört er Teilweise auf einen Zeilenumbruch zu generieren.
Kannst du mir sagen woran das liegen könnte?

außerdem muss man folgende Zeile mit ins Makro schreiben *Smilie

Code:

Danke,
Can

 

ich hab mir das Ergebnis noch einmal genau angeschaut.
Die Zeilenumbrüche in den Kommentaren werden bis einschlißlich der 4. Zeile gemacht!
also werden ab der 5. Zeile keine Umbrüche generiert!

Ich bitte um Hilfe *Smilie ich finde keinen Grund, wieso das Makro nur bis zur 4. Zeile "richtig" funktioniert. -.-

Viele Grüße Can

 

Hallo ?,

was du mit

meinst, erschließt sich mir nicht.

Bei längeren Kommentaren darf man nicht mit ".Characters.Text" arbeiten, weil dessen Länge auf 255 Zeichen begrenzt ist.

So geht's auch mit langen Kommentartexten.


' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************
Option Explicit
Const maxLength As Long = 90 'Maximale Zeichen pro Zeile
Private Sub AutosizeComments()
Dim objCmnt As Comment, strTmp As String
For Each objCmnt In ActiveSheet.Comments
With objCmnt
.Text breakText(.Text, maxLength)
.Shape.TextFrame.AutoSize = True
End With
Next
End Sub

Private Function breakText(ByVal Text As String, ByVal länge As Long) As String
Dim tmp As String, str As String
Dim lenT As Integer, i As Integer, n As Integer
Text = Replace(Text, vbLf, " ")
lenT = Len(Text)
n = 1
i = 1
Do
tmp = Mid(Text, i, länge)
If lenT - i >= länge Then
n = Len(tmp) - InStr(1, StrReverse(tmp), " ") + 1
Else
n = Len(tmp)
End If
str = str & Trim(Left(tmp, n)) & vbLf
i = i + n
Loop While i < lenT
breakText = Left(str, Len(str) - 1)
End Function



« Gruß Sepp »

 

Sorry, wegen dem

das hat sich erledigt *Smilie

Jetzt komme ich leider immer noch nicht weiter, da mir das Makro nichts mehr in die Kommentarfenster schreibt, jedoch wird die Fenstergröße formatiert.

ich bin am verzweifeln ^^

 

Hallo ?,

lade die Datei hoch in der der Code nicht läuft.




« Gruß Sepp »