Office: (Office 2016) Kopieren mit Auflagen

Hallo zusammen,

benötige Eure Hilfe.

Ausgangssituation: ich habe in Sheet1 Daten in A13:O22. Je nach Konstellation können aber nur Zeilen 13,14 und 15 oder 13,14,15,16,17 usw. befüllt sein.
Nun möchte ich per Button die Zeilen, die ausgefüllt sind, in Sheet 2 A5:Oxx kopieren. Und zwar immer in die nächste freie Zeile.

Hintergrund: die Daten vorne verändern sich immer wieder und ich möchte die einzelnen Zeilen "revisionssicher" in einem extra Sheet speichern.

Mir fehlt nun zum einen, dass er nur die befüllten Zeilen kopiert und zum anderen, dass er fortfolgend in Sheet2 in die nächste freie Zeile einfügt.

Bisher kopiert er nur den kompletten Bereich und zwar immer in dieselben Felder.

Code:

Sub Auswerten()
Worksheets("Sheet1").Range("A13:O22").Copy _
    Destination:=Worksheets("Sheet2").Range("A5")
 End Sub

Vielen Dank vorab.
Daniel

 

Hallo,

folgendes Makro anstelle des bisherigen Makros müsste die flexible Zeilenkopierung durchführen:

Code:

Sub Auswerten()
  Dim rgQuelleZeilen As Range, rgZielZeile As Range
  Dim rgQuelleZeile As Range
  
  Set rgQuelleZeilen = Worksheets("Sheet1").Range("A13:O22")
  Set rgZielZeile = Worksheets("Sheet2").Range("A5")
  
  For Each rgQuelleZeile In rgQuelleZeilen.Rows
    If ZeileHatDaten(rgQuelleZeile) Then
      rgQuelleZeile.Copy Destination:=rgZielZeile
      Set rgZielZeile = rgZielZeile.Offset(1)
    End If
  Next rgQuelleZeile
  
End Sub

Private Function ZeileHatDaten(rgZeile As Range) As Boolean
  Dim rgZelle As Range
  
  For Each rgZelle In rgZeile.Cells
    If Not IsEmpty(rgZelle.Value) Then ZeileHatDaten = True: Exit Function
  Next rgZelle
  ZeileHatDaten = False
  
End Function

 

Hola,

zur Info...
http://www.office-loesung.de/p/viewtopic.php?f=166&t=835417

Gruß,
steve1da