Office: Laufzeitfehler 9 - Alternativtext

Hallo,

Möchte zu einen Laufzeitfehler "9" Alternativtext zuweisen.

Code:

    Sheets("ZVV").Select
    Sheets("ZVV").Copy Before:=Sheets(1)
    Sheets("ZVV").Name = "Daten"
    Sheets("ZVV (2)").Select

Sprich wenn meine Makro nicht mit Tabelleblatt ZVV gestartet wird, soll auch nicht ausgeführt werden. Jedoch sollte diese Person wissen wieso diese Fehler kommt.

Ist so etwas möglich?

Gruß

Hakan

 

Hallo,

so ein Makro muss, abgesehen von Deinen 4 Programmzeilen, folgende Struktur aufweisen:

1) Die Codezeile "On error goto CodeMarke" vor der 1. Zeile, die einen Fehler produzieren könnte
2) Weiteren Programmcode
3) Die Codezeile "Exit Sub", welche das Ende des regulären Prozedurencodes anzeigt.
4) Die Codezeile mit der CodeMarke, gefolgt von einem Doppelpunkt (im Beispiel: "Fehler_Makro1:")
5) Den Fehlerbehandlungscode (in diesem Fall: IF ... END IF)
6) Gegebenenfalls noch eine Variante der "Resume"-Anweisung, falls nach der (erfolgreichen) Fehlerbehandlung der Programmablauf vor dem "Exit Sub" wieder fortgesetzt werden soll (im folgenden Beispiel nicht enthalten!).

Code:

Sub Makro1()

    On Error GoTo Fehler_Makro1
    
    Sheets("ZVV").Select
    Sheets("ZVV").Copy Before:=Sheets(1)
    Sheets("ZVV").Name = "Daten"
    Sheets("ZVV (2)").Select
    
    Exit Sub
    
Fehler_Makro1:
    If Err.Number = 9 Then
      MsgBox Prompt:="Fehler 9: Indexfehler" & vbCrLf & "Kein Blatt 'ZVV' vorhanden!!", _
             Buttons:=vbCritical + vbOKOnly, _
             Title:="Fehlendes/Falsches Blatt"
    Else
      MsgBox Prompt:="Fehler " & Err & ": " & vbCrLf & Err.Description, _
             Buttons:=vbCritical + vbOKOnly, _
             Title:="Sonstiger Fehler"
    End If

End Sub

 

Hi Hakan,

wenn ich dich richtig verstanden habe meinst du, dass eine von dir festgelegte Fehlermeldung angzeigt wird falls Tabellenblatt ZVV nicht vorhanden ist?

Code:

Sub Fehlerbehandlung()
    Dim wshTabelle As Worksheet
    ' nächste Zeile im Code ausführen wenn Fehler (Tabellenblatt ZVV nicht vorhanden)
    On Error Resume Next
    ' Tabellenblatt ZVV der Variablen zuweisen
    Set wshTabelle = Worksheets("ZVV")
    ' Fehlerbehandlung zurücksetzen
    On Error GoTo 0
    ' Variable ist belegt wenn ZVV vorhanden
    If Not wshTabelle Is Nothing Then
        Sheets("ZVV").Copy Before:=Sheets(1)
        Sheets("ZVV").Name = "Daten"
    ' Variable ist nicht belegt wenn nicht ZVV vorhanden
    Else
        MsgBox "Tabellenblatt 'ZVV' nicht vorhanden"
    End If
    ' Variable zurücksetzen
    Set wshTabelle = Nothing
End Sub

Bis später,
Karin

 

Hallo Karin,

jepp.... genau so meine ich. Es klappt...

Jedoch habe ich vergessen zu erwähnen, wenn oben genannte Fehler auftaucht, soll gesamte Macro stoppen.


übrigens... habe ich mich gewundert woher du rausgefunden hast wie ich heisse :) bis ich meine Text unter dem Gruß gelesen habe :=))

Gruß

 

Hi Hakan,

ich finde es angenehmer, meinen Gegenüber mit einem Vornamen ansprechen zu können, denn ich bin ebenfalls ein Mensch und kein Computer, dem so etwas egal ist. Deshalb freue ich mich immer, wenn ein Vorname unter einem Beitrag steht und nutze natürlich auch die Möglichkeit, den User auf der anderen Seite der Leitung damit anzusprechen. :-)

Das Makro wird doch beendet, wenn das Tabellenblatt nicht gefunden wird - ich verstehe also deine Frage nicht ganz.

Bis später,
Karin

 

Hallo Karin,

Ich muss mich entschuldigen :) ich hab deine Code etwas umarbeiten müssen.

Es klappt so wie es sein soll :) Danke dir Herzlich



Grüße aus Karlsruhe

Hakan