Office: Mail aus Excel versenden. Feststellen, ob der Versand userseitig abgebrochen wurde

GibsonSG · 4. August 2014

Moin zusammen.

Mit
Code:

Dim appOutlook As Outlook.Application
Dim mail As Outlook.MailItem

Set appOutlook = CreateObject("Outlook.Application")
Set mail = appOutlook.CreateItem(olMailItem)

With mail
.subject = subject
.Body = mailBody
.BCC = mailAdressList
End With

mail.Display

etc.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

kann der User aus Excel heraus eine von mir vordefinierte Mail versenden.
Der User kann aber den Versand der Mail im Mailfenster abbrechen.
Wie kann ich feststellen, ob der User die Mail verschickt hat oder einfach nur das Mailfenster geschlossen hatte?

:)

EarlFred · 5. August 2014

Hallo,

die Frage ist ein Excel-Klassiker *wink.gif*

Leicht modifiziert:
Code:

Option Explicit
Sub MailErstellenUndAnzeigen()

Dim appOutlook As Outlook.Application
Dim mail As Outlook.MailItem

'Wird die Instanz auch irgendwo wieder zugemacht, wenn keine offen war?
Set appOutlook = CreateObject("Outlook.Application")
Set mail = appOutlook.CreateItem(olMailItem)

With mail
Set DieseArbeitsmappe.olMail = mail
.Subject = Subject
.Body = mailBody
.BCC = mailAdressList
.Display
End With

Set mail = Nothing
Set appOutlook = Nothing
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Und im Klassenmodul "DieseArbeitsmappe" (kann bei anderssprachigem Excel auch anders heißen, gemeint ist das Codemodul der Arbeitsmappe) folgende Ergänzung:
Code:

Option Explicit
Public WithEvents olMail As Outlook.MailItem

Private Sub olMail_Close(Cancel As Boolean)
On Error Resume Next
MsgBox "User schließt das Fenster und hat die Mail " & IIf(Not olMail.Sent, "nicht ", "") & "gesendet."
End Sub

Private Sub olMail_Send(Cancel As Boolean)
MsgBox "User hat die Mail gesendet!"
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Anstelle der MsgBoxen fügst Du eben Deinen Code ein.
Die Fehlerbehandlung beim Close-Ereignis übergeht den Fehler, wenn das Objekt beim Senden nicht mehr sauber referenziert ist. Das kannst Du auch ordentlich machen, der Mustercode dient nur der Veranschaulichung, welche Ereignisse du wie abfangen kannst.

Was spielst Du für eine SG?

Grüße
EarlFred

GibsonSG · 6. August 2014

Danke für die Antwort.

Den Code muss ich später probieren, wenn ich wieder am Excelsheet sitze.

Ich spiele ganz nach AC/DC (Angus Young) Fan Manier unter anderem eine Gibson SG '61 Reissue *happy

Office: Mail aus Excel versenden. Feststellen, ob der Versand userseitig abgebrochen wurde

Mail aus Excel versenden. Feststellen, ob der Versand userseitig abgebrochen wurde

Mail aus Excel versenden. Feststellen, ob der Versand userseitig abgebrochen wurde

Mail aus Excel versenden. Feststellen, ob der Versand userseitig abgebrochen wurde - Similar Threads - Mail Excel versenden

Versenden E-Mail aus Excel Liste via VBA & Outlook

E-Mail aus Excel mit Knopfdruck versenden

aus Excel Mail versenden mit mehreren Anhängen

E-Mail versenden an mehrere Empfänger aus Excel-Datei

Excel-Zellen per Mail versenden

Excel Mail versenden

Frage: Terminplanung aus Excel - Termine in outlook automatisiert versenden?