Office: Min Datum mit Doppelter Bedienung

Hallo zusammen,

ich bin schon 2 tage nach der Suche für Lösung meines problems.
Ich habe eine Tabele s. Anhang
Den Anhang 5943 betrachten

Ich möchte gern MIN(Valuta) zu bekommen, wenn Betrag = 200 ist und "ES"

Sobald ich Min Datum Eingebe z.B. =SUMMENPRODUKT(MAX((E2:E9="ES")*(Betrag$1:Betrag$9=200)*(Valuta$1:Valuta$9))) bekomme ich 00.01.1900,
obwohl sollte eingentlich 10.02.10 rauskommen.
ich vermute dass hängt damit zusammen, dass "ES" und "Betrag" mehrmals vorkommen.

Kann mir jemand helfen

Vielen Dank im Voraus

pleshi

 

Ja wie jetzt? Problem gelöst? ;-)

 

hallo Michael!

Ich habe kleine probleme mit Formatierung, Aber problem nach wie vor nicht gelöst.

:-(

 

Hallo!

ungetestet:
=MIN(WENN((B2:B9=200)*(E2:E9="ES");D2:D9))

Achtung: Matrixformel! Die Formeleingabe mit Strg+Shift+Enter abschließen!

 

Hallo schatzi!

getestet =MIN(WENN((B2:B9=B16)*(E2:E9=F14);D2:D9)) kommt aber die Fehlermeldung #WERT!

:-(((((

 

Und den Matrix-Hinweis hast du beachtet?

 

Hab gerade Anhang hinzugefügt.....

 

Hallo!

Du hast in C16 insgesamt drei(!!!) Formeln stehen! Und mit Strg+Shift+Enter scheinst du auch nicht abgeschlossen zu haben.
Mit der korrekten Formel funktioniert's:

	A	B	C	D	E	F
1	Seite	Betrag	Zeichen	Valuta
2	F	200,00	H	18.10.2010	FH	200,00
3	E	200,00	S	10.02.2011	ES	-200,00
4	E	200,00	S	11.07.2011	ES	-200,00
5						0,00
6						0,00
7						0,00
8						0,00
9						0,00
10
11		Summe Eigen:	-400,00
12		Summe Fremd:	200,00
13
14		Splitt:	-200,00	E	S	ES
15	MAX v. Valuta	Valuta:	11.07.2011
16	MAX v. Betrag	200,00	10.02.2011
17	Anzahl:	2,00

Zelle	Formel
E2	=A2 & C2
F2	=WENN(C2="H"; ABS(B2); -1*ABS(B2))
E3	=A3 & C3
F3	=WENN(C3="H"; ABS(B3); -1*ABS(B3))
E4	=A4 & C4
F4	=WENN(C4="H"; ABS(B4); -1*ABS(B4))
E5	=A5 & C5
F5	=WENN(C5="H"; ABS(B5); -1*ABS(B5))
E6	=A6 & C6
F6	=WENN(C6="H"; ABS(B6); -1*ABS(B6))
E7	=A7 & C7
F7	=WENN(C7="H"; ABS(B7); -1*ABS(B7))
E8	=A8 & C8
F8	=WENN(C8="H"; ABS(B8); -1*ABS(B8))
E9	=A9 & C9
F9	=WENN(C9="H"; ABS(B9); -1*ABS(B9))
C11	=SUMMEWENN(A:A;"E";F:F)
C12	=SUMMEWENN(A:A;"F";F:F)
C14	=SUMME(C11:C12)
D14	=WENN(ABS(C11)=ABS(C12);"Null"; WENN(ABS(C12)>ABS(C11);"F"; "E"))
E14	=WENN(C14=0;""; WENN(C14>0;"H";"S"))
F14	=WENN(C14=0;"";D14&E14)
C15	=WENN(D14="Null"; "";SUMMENPRODUKT(MAX((E2:E9=F14)*(D2:D9))))
B16	=SUMMENPRODUKT(MAX((E2:E9=F14)*(B2:B9)))
C16	{=MIN(WENN((B2:B9=B16)*(E2:E9=F14);D2:D9))}
B17	=SUMMENPRODUKT((E2:E9=F14)*(B2:B9=B16))

Achtung, Matrixformel enthalten!Die geschweiften Klammern{} werden nicht eingegeben.Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

 

Du hast RECHT!!!
ich möchte mich HERZLICHE BEDANKEN und wünsche ein wünderschönes WE.

LG