Office: Mit Userform Programmausführung anhalten, aber mit Bearbeitungsmöglichkeit

Irina Spalko · 30. September 2019

Hallo,

ich möchte, dass während der Ausführung eines Programmes an einer Stelle eine Userform angezeigt wird (mit den Buttons OK und Abbrechen). Während die Userform angezeigt wird, soll eine Bearbeitung der Exceldatei erfolgen und anschließend OK (Weiterausführen des Programms) oder Abbrechen (Stopp des Programms) geklickt werden.

Ich habe es bisher nur hinbekommen, dass das Programm bei Anzeige der Userform anhält, aber eine Bearbeitung der Exceldatei gesperrt ist. Oder: wenn eine Bearbeitung während er Anzeige möglich ist, dann wurde das Programm nicht angehalten, sondern weiter ausgeführt (mit Userform.Show vbModeless).

Weiß jemand, wie ich das Programm mit einer Modeless Userform anhalten kann bis OK oder Abbrechen geklickt wird?

Danke!

:)

Storax · 1. Oktober 2019

So könnte der Code in der Userform aussehen
Code:

Option Explicit
Dim mCancelled As Boolean
Dim mOkay As Boolean
Private Sub btnAbbrechen_Click()
mCancelled = True
Hide
Code2 Me
End Sub

Private Sub btnOk_Click()
mOkay = True
Hide
Code2 Me
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
' Prevent the form being unloaded
If CloseMode = vbFormControlMenu Then Cancel = True

' Hide the Userform and set cancelled to true
Hide
mCancelled = True
End Sub

Property Get Okay() As Boolean
Okay = mOkay
End Property
Property Get Cancelled() As Boolean
Cancelled = mCancelled
End Property
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Und so könnte man testen
Code:

Option Explicit

Sub Code1()

Dim f As New frmContinue

' Code until call of userform

f.Show vbModeless

End Sub

Sub Code2(f As Object)

If f.Okay Then
MsgBox "Continue"
Else
MsgBox "Do not continue"
End If

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

haklesoft · 1. Oktober 2019

Hallo,

ich kann eine andere Variante beisteuern: Code:

Option Explicit

' #####################
' Code in der UserForm1
' #####################

Dim iWeiter As Integer

Public Function zeigeUF() As Integer
Me.Show vbModeless

While iWeiter < 1
DoEvents
Wend

zeigeUF = iWeiter ' Rückgabe an Aufrufer
End Function

Private Sub CommandButton1_Click() ' Abbruch
iWeiter = 2
Unload Me
End Sub

Private Sub CommandButton2_Click() ' OK
iWeiter = 3
Unload Me
End Sub

Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
If CloseMode = vbFormControlMenu Then iWeiter = 1
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Code:

Option Explicit

' #########################
' Code im aufrufenden Modul
' #########################

Sub starteUF()
Dim iErg As Integer
iErg = UserForm1.zeigeUF

MsgBox "Rückgabe aus UserForm: " & iErg, vbOKOnly, "Weiter gehts, UserForm geschlossen"

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Irina Spalko · 2. Oktober 2019

Danke an euch beide!

Da ich das in einer Schleife benötige, habe ich Variante 2 genommen. Klappt wunderbar!

Storax · 2. Oktober 2019

\@haklesoft: Lesestoff hier

Doing. It. Wrong.
There are a number of red flags invariably raised in many UserForm tutorials:

Unload Me, or worse, Unload UserForm1, in the form’s code-behind.
The former makes the form instance a self-destructing object, the latter
resets the default instance, and that’s not necessarily the executing
instance – and that leads to all kinds of funky unexpected behavior, and
embarrassing duplicate questions on Stack Overflow. Every day.

UserForm1.Show at the call site, where UserForm1 isn’t a local
variable but the “hey look it’s free” default instance, which means you’re
using an object without even realizing it (at least without New-ing it up
yourself) – and you’re storing state that belongs to a global instance, which
means you’re using an object but without the benefits of object-oriented
programming. …
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Hier mit mehr Beispielen, die man IMHO mal selber testen sollte, um den Unterschied zu sehen.

haklesoft · 2. Oktober 2019

Danke. Besser geht immer. *mrcool

Office: Mit Userform Programmausführung anhalten, aber mit Bearbeitungsmöglichkeit

Mit Userform Programmausführung anhalten, aber mit Bearbeitungsmöglichkeit

Mit Userform Programmausführung anhalten, aber mit Bearbeitungsmöglichkeit

Mit Userform Programmausführung anhalten, aber mit Bearbeitungsmöglichkeit

Mit Userform Programmausführung anhalten, aber mit Bearbeitungsmöglichkeit - Similar Threads - Userform Programmausführung anhalten

Userform Login Benutzername in Zelle schreiben

Datum in Userform formatieren

UserForm zum bearbeiten von Tabellen und speichern

VBA Code Tabellenblatt kopieren und UserForm

UserForm wechseln

Daten aus UserForm in Tabellenblatt übertragen

userform schliessen, Inhalt soll erhalten bleiben