Office: MITTELWERTWENN (Funktion)

MITTELWERTWENN (Funktion)
Excel für Microsoft 365 Excel für Microsoft 365 für Mac Excel für das Web Excel 2019 Excel 2016 Excel 2019 für Mac Excel 2013 Excel 2010 Excel 2007 Excel 2016 für Mac Excel für Mac 2011 Excel Web App Excel Starter 2010 Mehr... Weniger In diesem Artikel werden die Formelsyntax und die Verwendung der MITTELWERTWENN  in Microsoft Excel.

Beschreibung
Gibt den Durchschnittswert (arithmetisches Mittel) für alle Zellen eines Bereichs zurück, die einem angegebenen Kriterium entsprechen.

Syntax
MITTELWERTWENN(Bereich, Kriterien, [Mittelwert_Bereich])

Die Syntax der Funktion MITTELWERTWENN weist die folgenden Argumente auf:

• Bereich    Erforderlich. Der Bereich der Zellen, für die der Mittelwert berechnet werden soll, einschließlich Zahlen, Namen, Arrays oder Bezügen, die Zahlen enthalten.
  
  
• Kriterien    Erforderlich. Die Kriterien in Form einer Zahl, eines Ausdrucks, eines Zellbezugs oder eines Texts, mit denen definiert wird, für welche Zellen der Mittelwert berechnet werden soll. Kriterien können beispielsweise als 32, "32", ">32", "Äpfel" oder B4 angegeben werden.
  
  
• Mittelwert_Bereich    Optional. Der tatsächliche Bereich der Zellen, für die der Mittelwert berechnet wird. Fehlt diese Argument, wird "Bereich" verwendet.
  
  

Hinweise

• Zellen in "Bereich", die WAHR oder FALSCH enthalten, werden ignoriert.
  
  
• Ist eine Zelle in "Mittelwert_Bereich" leer, wird sie von MITTELWERTWENN ignoriert.
  
  
• Ist "Bereich" leer oder ein Textwert, wird für MITTELWERTWENN der Fehlerwert #DIV/0! zurückgegeben.
  
  
• Ist eine Zelle in "Kriterien" leer, wird sie in MITTELWERTWENN mit dem Wert 0 berücksichtigt.
  
  
• Entspricht keine der Zellen in "Bereich" den Kriterien, wird für MITTELWERTWENN der Fehlerwert #DIV/0! zurückgegeben.
  
  
• Sie können in den Kriterien Platzhalterzeichen, Fragezeichen (?) und Sternchen (*) verwenden. Ein Fragezeichen ersetzt ein Zeichen, und ein Sternchen ersetzt eine beliebige Zeichenfolge. Wenn Sie nach einem Fragezeichen oder Sternchen suchen möchten, müssen Sie eine Tilde (~) vor das zu suchende Zeichen setzen.
  
  
• "Mittelwert_Bereich" muss nicht dieselbe Größe und Form haben wie "Bereich". Die Zellen, für die tatsächlich der Mittelwert berechnet wird, werden wie folgt ermittelt: Die obere linke Zelle in "Mittelwert_Bereich" wird als Anfangszelle verwendet, und anschließend werden alle Zellen einbezogen, die in Größe und Form "Bereich" entsprechen. Zum Beispiel:
  
  

Bereich	Mittelwert_Bereich	Tatsächlich ausgewertete Zellen
A1:A5	B1:B5	B1:B5
A1:A5	B1:B3	B1:B5
A1:B4	C1:D4	C1:D4
A1:B4	C1:C2	C1:D4

Hinweis: Die MITTELWERTWENN-Funktion misst die zentrale Tendenz, bei der es sich um die Position des Mittelpunkts einer Zahlengruppe in einer statistischen Verteilung handelt. Die drei häufigsten Maßnahmen der zentralen Tendenz sind:

• Mittelwert     Das ist der arithmetische Mittelwert und wird berechnet, indem eine Gruppe von Zahlen addiert und dann durch die Anzahl dieser Zahlen dividiert wird. Der Mittelwert von 2, 3, 3, 5, 7 und 10 ist beispielsweise 30 dividiert durch 6, was 5 ist.
  
  
• Median     die mittlere Zahl einer Gruppe von Zahlen; Das bedeutet, dass die Hälfte der Zahlenwerte enthält, die größer als der Median sind, und die Hälfte der Zahlenwerte enthält, die kleiner als der Median sind. Der Median von 2, 3, 3, 5, 7 und 10 ist beispielsweise 4.
  
  
• Modalwert     ist die am häufigsten vorkommende Zahl in einer Zahlengruppe. Der Modalwert von 2, 3, 3, 5, 7 und 10 z. B. lautet 3.
  
  

Bei einer symmetrischen Verteilung einer Zahlengruppe sind diese drei Maße der zentralen Tendenz identisch. Bei einer schiefen Verteilung einer Zahlengruppe können die Maße abweichen.

Beispiele
Kopieren Sie die Beispieldaten in der folgenden Tabelle, und fügen Sie sie in Zelle A1 eines neuen Excel-Arbeitsblatts ein. Um die Ergebnisse der Formeln anzuzeigen, markieren Sie sie, drücken Sie F2 und dann die EINGABETASTE. Im Bedarfsfall können Sie die Breite der Spalten anpassen, damit alle Daten angezeigt werden.

	Provision
100000	7000
200000	14000
300000	21000
400000	28000
Formel	Beschreibung	Ergebnis
=MITTELWERTWENN(B2:B5;"<23000")	Mittelwert aller Provisionen unter 23000. Drei der vier Provisionen erfüllen diese Bedingung, und sie ergeben die Summe 42000.	14000
=MITTELWERTWENN(A2:A5;"<250000")	Mittelwert aller Immobilienwerte unter 250000. Zwei der vier Immobilienwerte erfüllen diese Bedingung, und sie ergeben die Summe 300000.	150000
=MITTELWERTWENN(A2:A5;"<95000")	Mittelwert aller Immobilienwerte unter 95000. Da keine Immobilienwerte vorhanden sind, die diese Bedingung erfüllen, wird für MITTELWERTWENN der Fehlerwert #DIV/0! zurückgegeben, da versucht wird, durch 0 zu teilen.	#DIV/0!
=MITTELWERTWENN(A2:A5;">250000";B2:B5)	Mittelwert aller Provisionen mit einem Immobilienwert über 250000. Zwei Provisionen erfüllen diese Bedingung, und sie ergeben die Summe 49000.	24500

Beispiel 2

Region	Gewinne (Tausend)
Ost	45678
West	23789
Nord	-4789
Süd (Neue Niederlassung)	0
Mittlerer Westen	9678
Formel	Beschreibung	Ergebnis
=MITTELWERTWENN(A2:A6;"=*West";B2:B6)	Mittelwert aller Gewinne für die Regionen West und mittlerer Westen.	16733,5
=MITTELWERTWENN(A2:A6;"<>*(Neue Niederlassung)";B2:B6)	Mittelwert aller Gewinne für alle Regionen außer neuen Niederlassungen.	18589

:)