Office: Namen in Spalte auslesen und die Zeile darüber

Hallo,
Ich habe eine Tabelle. In der Spalte C sind viele Namen(10 verschiedene). Die Namen sind jeweils einem Projekt zugeordnet(siehe Beispiel)

A B C D
1 Projekt Schraube Hans 200 Std
Dieter 100 Std

2 Projekt Mutter Klaus
Heiner
Frank

3 Projekt Schaum Dieter
Werner

4 Projekt Maus Heinrich
Hans

Nun möchte ich auf einem extra Tabellenblatt den Namen Hans haben und unter dem Namen sollen jeweils seine Projekte, in denen er mitarbeitet, angezeigt werden. Die Stunden auslesen und zusammenrechnen habe ich schon hinbekommen, weiß aber nicht was ich machen muss um die gesamte Zeile auszulesen. Das Problem ist, das die Namen wie oben nicht immer den gleich Abstand zu Projektzeile haben. Aber alle 5 Zeilen ist ein neues Projekt(5,10,15,20,25,30,35,...).
Hat jemand eine Idee?
Danke!

Grüße Ole

 

Hallo!

Könnte man so versuchen:

	A	B	C	D	E	F	G	H
1	1	Projekt Schraube	Hans	200			Hans
2			Dieter	100			1	Projekt Schraube
3							4	Projekt Maus
4	2	Projekt Mutter	Klaus
5			Heiner
6			Frank
7
8	3	Projekt Schaum	Dieter
9			Werner
10
11	4	Projekt Maus	Heinrich
12			Hans
13

Zelle	Formel
G2	{=WENN(ZÄHLENWENN(C:C;G$1)<ZEILE(A1);"";MAX(A$1:INDEX(A:A;KKLEINSTE(WENN(C$1:C$99=G$1;1*ZEILE($1:$99));ZEILE(A1)))))}
H2	=WENN(G2="";"";SVERWEIS(G2;A:B;2;))
G3	{=WENN(ZÄHLENWENN(C:C;G$1)<ZEILE(A2);"";MAX(A$1:INDEX(A:A;KKLEINSTE(WENN(C$1:C$99=G$1;1*ZEILE($1:$99));ZEILE(A2)))))}
H3	=WENN(G3="";"";SVERWEIS(G3;A:B;2;))
G4	{=WENN(ZÄHLENWENN(C:C;G$1)<ZEILE(A3);"";MAX(A$1:INDEX(A:A;KKLEINSTE(WENN(C$1:C$99=G$1;1*ZEILE($1:$99));ZEILE(A3)))))}
H4	=WENN(G4="";"";SVERWEIS(G4;A:B;2;))

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

 

Woah geil! Danke:)
Herzlichsten Dank:)
Eine Frage noch. Die Liste soll als neues Tabellenblatt eingefügt werden.
Wo muss ich dann den Names des Tabellenblattes einfügen, von dem ich die Daten entnehmen möchte.

Grüße

 

Hallo!

Der Blattname kommt jeweils vor die entsprechenden Bezüge, mit Ausrufezeichen getrennt:

{=WENN(ZÄHLENWENN(Blatt!C:C;G$1)<ZEILE(A1);"";MAX(Blatt!A$1:INDEX(Blatt!A:A;KKLEINSTE(WENN(Blatt!C$1:C$99=G$1;1*ZEILE($1:$99));ZEILE(A1)))))}

Wenn dein Blattname Leer- oder Sonderzeichen beinhaltet, dann gehört er zusätzlich noch in 'Hochkommas'!

 

Dankschön:)
Peinlich, aber beim der Formel? Muss das so dahin?

=WENN(G4="";"";SVERWEIS(G4;Blatt!A:B;2;))

?
Weil das bei mir nicht funktioniert

Grüße Ole

 

Entschuldigung!
Ich nehme es zurück! Vielen Lieben Dank für die schnelle Hilfe:)