Office: (Office 365) Nummerierung in Spalte in Text umwandeln

Hallo Zuammen,

mit folgendem Code wandel ich markierte Nummerierungen in einer Word-Tabelle in Text um:

Selection.Range.ListFormat.ConvertNumbersToText

Nun hätte ich gerne, dass beim Aufrufen des Makros die komplette Spalte 2 in der Tabelle markiert wird und alle Nummerierungen in der Spalte 2 in Text umgewandelt werden.

Kann mir hierbei jemand helfen?

Vielen Dank für die Unterstützung
Gruß Ulli

 

Hallo Ulli,

setz doch einfach diese Zeile davor: Selection.Tables(1).Columns(2).Select
Schreibmarke muss irgendwo in der gewünschten Tabelle stehen (das muss nicht die erste Tabelle sein).

 

Hallo Gerhard,

vielen Dank, funktioniert einwandfrei.
Jetzt habe ich eine Tabelle , da ist eine Zeile anders aufgeteilt, da kommt eine Fehlermeldung.
Aber die Spalte 2 gibt es da natürlich auch.
Bekommt man das geändert, dass es dort auch geht (siehe Anlage)

Viele Grüße Ulli

 

Hallo Ulli,

wenn du Word-Tabellen mit VBA behandelst und darüber unglücklich werden willst, dann verwende verbundene Zellen. Das macht die Sache in aller Regel kompliziert bis unmöglich, denn VBA "weiß" ja nicht, wie viele Spalten die gesamte Tabelle nun eigentlich hat. In deinem Fall besteht die Lösung darin, zellenweise zu arbeiten (was das Makro natürlich langsamer macht). Beachte auch, dass die Schleife rückwärts arbeiten muss, denn sonst passt sich die automatische Nummerierung unerwünschterweise jedesmal an und du hast am Ende nur Einsen in der Tabelle.

Code:

Sub zellenweise()
Dim anzZeilen As Long, i As Long

anzZeilen = Selection.Tables(1).Rows.Count
    For i = anzZeilen To 1 Step -1
        Selection.Tables(1).Cell(i, 2).Range.Select
        Selection.Range.ListFormat.ConvertNumbersToText
    Next i
End Sub

Eine andere Umgehensweise bestünde in deinem Beispiel evtl. darin, die Information, die in den gelben Kasten soll, als eigenen Absatz über (außerhalb) der Tabelle einzufügen.

 

Hallo Gerhard,
ich habe das mit den verbunden Zeilen wieder geändert und würde gerne mit dem vereinfachten Code arbeiten

Selection.Tables(1).Columns(2).Select
Selection.Range.ListFormat.ConvertNumbersToText

Noch eine Frage: ist es möglich diesen so zu verändern, das er nur von Zeile 3 bis Ende ausgeführt wird.(in spalte 2)

Ganz lieben Dank

Gruß Ulli

 

Hallo nochmal,

da gibts zwei Möglichkeiten:
Entweder du machst es zeilenweise wie in #4 gezeigt und änderst die Anzahl der Schleifendurchgänge:
for i = anzzeilen to 3 step-1

Oder du setzt den Bereich zusammen und machst es wieder in einem Aufwasch:

Code:

Sub nurAb3()
Dim tabelle As Table
Dim bereich As Range
Dim anzzeilen As Long, anfang As Long, ende As Long

Set tabelle = Selection.Tables(1)
anzzeilen = tabelle.Rows.Count
anfang = tabelle.Columns(2).Cells(3).Range.Start
ende = tabelle.Columns(2).Cells(anzzeilen).Range.End

Set bereich = ActiveDocument.Range(anfang, ende)
bereich.ListFormat.ConvertNumbersToText
End Sub

 

Hallo Gerhard,

funktioniert perfekt, herzlichen Dank!!

Gruß Ulli