Office: Optimierung einer Formel für eine Arbeitserfassung

Hallo Leute,

ich habe bereits vor längerem mit eurer Hilfe eine Arbeitserfassung aufgebaut, und diese läuft soweit super :) dafür schonmal vielen Dank.

Nun habe ich eine Frage: Und zwar, wie ich folgende Formel optimieren kann:

=WENN(A7="Fr";6,5;WENN(ODER(A7="Sa";A7="So";J7="Neujahr";J7="Karfreitag";J7="Ostermontag";J7="Tag der Arbeit";J7="Christi Himmelfahrt";J7="Pfingstmontag";J7="Fronleichnam";J7="Tag der Deutschen Einheit";J7="Allerheiligen";J7="1. Weihnachtsfeiertag";J7="2. Weihnachtsfeiertag";J7="Urlaub";J7="1/2 Tag Urlaub";J7="Resturlaub";J7="Krank";B7="");0;8))/24

Meine Arbeitserfassung hat in der Spalte A den Wochentag stehen, in Spalte B steht das Datum. In Spalte C und D werden die Anfangs- und Endzeiten eingetragen. In Spalte E werden die geleisteten Stunden berechnet. In Spalte F steht die Soll-Arbeitszeit

Die oben genannte Formel steht in der Spalte zur Soll-Arbeitszeit und sie funktioniert weitestgehend, sodass an Wochentagen außer Freitags immer 8 Stunden Soll-Arbeitszeit eingetragen werden, an Freitagen dann aber 6:30 Std. Sollarbeitszeit.

Wenn ich in der Spalte J nun Feiertage eintrage, soll das Feld auf 0:00 gesetzt werden. Dies funktioniert auch in allen Spalten, außer Freitags. Dort wird dann, statt 0:00 6:30 eingetragen.

Frage:
Wie muss ich die Formel aufbauen, damit beim Eintragen von Feiertagen auch in Zeilen mit Freitag der Wert 0:00 eingetragen wird?

Vielen Dank schonmal jetzt vorab für eure Hilfe :)

 

Hallo!

Ändere in der Formel die Reihenfolge der Abfragen.

 

Hallo,

=WENN(ODER(A7="Sa"; ... ;B7=""); 0; WENN(A7="Fr"; 6,5; 8))/24
wobei in der ODER(...)-Klammer alle deine Tage mit 0-Std. Sollzeit enthalten sind (wie gehabt).

 

Okay, habe etwas getüftelt, und mit folgender Abfrage klappts nun:

=WENN(ODER(A7="Sa";A7="So";J7="Neujahr";J7="Karfreitag";J7="Ostermontag";J7="Tag der Arbeit";J7="Christi Himmelfahrt";J7="Pfingstmontag";J7="Fronleichnam";J7="Tag der Deutschen Einheit";J7="Allerheiligen";J7="1. Weihnachtsfeiertag";J7="2. Weihnachtsfeiertag";J7="Urlaub";J7="1/2 Tag Urlaub";J7="Resturlaub";J7="Krank";B7="");0;WENN(A7="Fr";6,5;8))/24


Was muss ich tun, damit z.B. bei Eingabe von 1/2 Tag Urlaub im in Spalte J die Soll-Arbeitszeit auf 4:00 gesetzt wird?

 

Hallo,

=WENN(ODER(A7="Sa"; A7="So";J7="Neujahr";J7="Karfreitag";J7="Ostermontag";J7="Tag der Arbeit";J7="Christi Himmelfahrt";J7="Pfingstmontag";J7="Fronleichnam";J7="Tag der Deutschen Einheit";J7="Allerheiligen";J7="1. Weihnachtsfeiertag";J7="2. Weihnachtsfeiertag";J7="Urlaub"; J7="Resturlaub";J7="Krank"; ;B7=""); 0; WENN(J7="1/2 Tag Urlaub";4;WENN(A7="Fr"; 6,5; 8)))/24

 

Puuuh... :) Das ist ja immermehr verschachtelt :D

Vielen Dank für eure Hilfe, funktioniert echt super das ganze :)

 

Hallo!

Die Formel wird übersichtlicher, wenn du die Namen deiner Feiertage in einer Extra-Liste zusammenfasst. Zum einen ist das praktischer für eventuelle Anpassungen, zum anderen brauchst du dann auch nicht jeden Feiertag einzeln abzufragen, sondern es reicht z.B. (ZÄHLENWENN(Feiertage!A:A;J7)>0)

 

Diese Listen habe ich quasi in einem extra Registerreiter (nennt sich bei mir Hilfsdaten). Ist nur die Frage, inwiefern das kompatibel ist zu Excelversionen ab z.B. 2002 (wird bei mir auf der Arbeit leider noch immer eingesetzt... )

 

Hallo!

Da mach dir mal keine Sorgen. ZählenWenn gibt es schon ewig.

 

Okay, und wenn ich nun z.B. bei der Daten Gültigkeitsprüfung beim Verweis eine Liste angebe, statt einem Tabellenbereich, ist das dann auch kompatibel zu Excel 2002? Oder muss ich da was beachten? Zwar wird auf der Arbeit bald Office 2010 eingeführt (endlich...), aber ich möchte es solange natürlich noch so haben, das auch Excel 2002 mit der Datei umgehen kann.

 

Hallo!

Auch das sollte kein Problem sein.

 

Okay :) bin schon fleißig am umschreiben :), mal gucken ob ich das alles hinbekomme.

 

Ich nochmal :)

Ich habe nun, bis auf eine Formel, alle Formeln zusammengekürzt, nur eine bereitet mir Kopfzerbrechen.

Um folgende Formel gehts:

Code:

=WENN(UND(C7="";D7="");D7-C7;WENN(ODER(A7="Sa";A7="So";J7={"Neujahr";"Karfreitag";"Ostermontag";"Tag der Arbeit";"Christi Himmelfahrt";"Pfingstmontag";"Fronleichnam";"Tag der Deutschen Einheit";"Allerheiligen";"1. Weihnachtsfeiertag";"2. Weihnachtsfeiertag";"Urlaub";"1/2 Tag Urlaub";"Resturlaub";"Krank"};B7="");0;D7-C7-"0:30"))

gekürzt habe ich sie so:

Code:

=WENN(UND(C7="";D7="");D7-C7;WENN(ODER(A7="Sa";A7="So";ZÄHLENWENN(Inhalt;J7)>0;B7="");0;D7-C7-"0:30"))

Inhalt enthält alle Wörter, die in der Ursprungsformel in Zelle J7 abgefragt werden.

In dieser Spalte wird die Arbeitszeit berechnet, mit der Formel, so wie im ersten Codeschnipsel abgebildet funktioniert das auch.

Nun habe ich eine Zeile, in der ich nur einen halben Tag arbeite, also berechnet Excel mit der ersten Formel korrekt 4 Stunden, aber mit der 2. überarbeiteten Formel lässt Excel das Feld leer, als seien in den Feldern C7 & D7 keine Uhrzeiten eingetragen worden.

edit: hat sich erledigt :D hab den Fehler schon gefunden :D

 

Hallo,

mal wieder eine Frage :)

Ich habe mir eine Tabelle gebaut, in der ich sehen kann, wieviele Tage Resturlaub (voller Tag = R, halber Tag = r/) und wieviele Tage Urlaub (voller Tag = X, halber Tag = x/) man genommen hat.

Die Formel ist folgende:
=ZÄHLENWENN(B8:B38;"X")+ZÄHLENWENN(B8:B38;"x/")/2+ZÄHLENWENN(B8:B38;"R")+ZÄHLENWENN(B8:B38;"r/")/2

Nun wird aber immer +1 gezählt, obwohl bei den Werten x/ oder r/ nur 0,5 gezählt werden soll.

Wie muss ich diese Formel umbauen, damit bei den halben Tagen auch nur 0,5 gezählt wird? Hab da grade nen Brett vorm Kopf

 

Hallo!

Ich nehme an, dass der Fehler eher bei deinen Daten zu finden sein wird, denn deine Formel rechnet bei mir korrekt.

	B	C
8	X	3
9	x/
10	R
11	r/
12

<br />

Formeln der Tabelle[parsehtml]

Zelle	Formel
C8	=ZÄHLENWENN(B8:B38;"X")+ZÄHLENWENN(B8:B38;"x/")/2+ZÄHLENWENN(B8:B38;"R")+ZÄHLENWENN(B8:B38;"r/")/2

</td></tr></table>[/parsehtml] <br /><br /><span style="font-family:Arial; font-size:9pt; font-weight:bold;background-color:#ffffff; color:#000000; ">Excel Tabellen im Web darstellen &gt;&gt; </span><a style ="font-family:Arial; font-size:9pt; color:#fcf507; background-color:#800040; font-weight:bold;" href="http://www.excel-jeanie-html.de" target="_blank"> Excel Jeanie HTML 4 </a>