Office: (Office 2016) Pivottabellen mit mehreren Spalten

Hallo, ich habe ein Problem, dass ich gar nicht in wenigen Worten zusammenfassen kann.
Also...
ich habe eine Pivottabelle. In den Zeilen sind Kunden aufgeführt. In den Spalten sind Umsatz, Menge und Preis und das jeweils für zwei Jahre (also genauer in den Werten Umsatz, Menge und Preis und in den Spalten die Jahre).
Jetzt möchte ich als letzte zwei Spalten die Preisdifferenz zwischen 2021 und 2020 (mehr Jahre sind nicht vorhanden) in € und einer weiteren Spalte in %.
Wie bekomme ich das hin. Die Preisdifferenz bekomme ich hin, in dem ich den Preis noch einmal einfüge und dann bei "Werte anzeigen als" auf Differenz gehe. Aber dann bekomme ich ja zwei Spalten für die beiden Jahre, von denen eine dann leer ist.
Ich möchte aber auch nicht meine Notlösung beibehalten und nur eine Formeln dahintersetzen, da diese ja nicht dynamisch ist. Wenn neue Kunden dazukommen, muss man daran denken händisch die Formel zu kopieren.
Habt ihr andere Ideen?

 

Hallo,

in der beiliegenden Datei habe ich dir eine kleine strukturierte Tabelle "TabUmsätze" eingefügt, weiters eine PivotTable "PivotTable2" mit einem berechneten Feld "Price":

Stellt man die aktive Zelle in den Bereich der PivotTable und führt man über das Kontextmenü (rechte Maustaste) den Befehl "Aktualisieren" aus, so wird die PivotTable mit den Daten der Tabelle aktualisiert und die beiden Spalten "change of price" angefügt:

Das Ganze funktioniert mittels VBA über das PivotTableUpdate-Ereignis des Arbeitsblattes "Tabelle1". Deshalb findet sich im Codemodul dieses Arbeitsblattes folgende SUB, die ausgelöst wird, wenn vorgenannter "Aktualisieren"-Befehl erfolgt:

Code:

Private Sub Worksheet_PivotTableUpdate(ByVal Target As PivotTable)
  With Target
    If .Name = "PivotTable2" Then Call Calc_ChangePrice(Target)
  End With
End Sub

Sub Calc_ChangePrice(PivTab As PivotTable)
  Dim rgPivHdPrice As Range, rgPivHdPriceChg As Range, rgEUR As Range
  Dim pivCols As Long
 
  With PivTab.ColumnRange
    pivCols = .Columns.Count
    Set rgPivHdPrice = .Offset(0, pivCols - 2).Resize(, 2)  'Bereich Spalten-Header Price
    Set rgPivHdPriceChg = rgPivHdPrice.Offset(0, 2)         'Bereich Spalten-Header Price-Change
  End With

' Spaltenkopf neben der PivotTable im PivotTable-Stil
  rgPivHdPrice.Copy Destination:=rgPivHdPriceChg
  With rgPivHdPriceChg
    .Cells(2, 1).Value = "change of price"
    .Cells(3, 1).Value = """EUR "
    .Cells(3, 2).Value = """% "
  End With
  Application.CutCopyMode = False
 
' Price-Change-Spaltenwerte und Formatierung
  Set rgEUR = PivTab.DataBodyRange.Offset(0, pivCols).Resize(, 2)
  With rgEUR.Rows(1)
    .Cells(1).FormulaR1C1 = "=RC[-2]-RC[-1]"
    .Cells(2).FormulaR1C1 = "=IFERROR(RC[-1]/RC[-2],0)"
    .Copy Destination:=rgEUR
  End With
  With rgEUR.Columns(2)
    .Style = "Percent"
    .NumberFormat = "0.0%"
    With .Borders(xlEdgeRight)
         .LineStyle = xlContinuous
         .ColorIndex = xlAutomatic
         .TintAndShade = 0
         .Weight = xlThin
    End With
  End With
End Sub