Office: Problem mit Formel nach unten ziehen eines Spaltenbereiches

Hallo,

ich bin nicht 100% fit mit Excel und habe folgendes Problem (Excel 2010):

Ich habe Energiemessungen durchgeführt mit einer Auflösung von 0,5s.
Da ich für ein Diagramm eine andere Auflösung haben möchte (20s) (da das Diagramm sonst viel zu viele Messpunkte hat) habe ich einen Mittelwert von jeweils 20 Zellen in einer Spalte gebildet. Z.B. =Mittelwert(C3:C42). für die nächsten 20 Sekunden brauche ich dann =Mittelwert (C43:C82) als nächstes =Mittelwert(C83:C122) usw.

Wenn ich jetzt diese 3 Zellen makiere und nach unten ziehen möchte will ich die Formel =Mittelwert(C123:C162) in der nächsten Zelle stehen haben. Bekomme aber =MITTELWERT(C6:C45).
Wie kann ich Excel sagen, dass ich immer einen Bereich von 40 Zellen nach unten haben will und die nächste Formel darf erst wieder mit dem nächsten 40er Bereich beginnen.

Sorry, ist nicht so gut erklärt, aber ich glaube ihr wisst, was mein Problem ist.

Danke schonmal

Basti

 

Hallo!

Diese Formel kannst du runterziehen:

=MITTELWERT(INDEX(C:C;40*ZEILE(A1)-37):INDEX(C:C;40*ZEILE(A1)+2))

 

Dankeschön...
nur für was steht das (A1)-37 bzw (A1)+2 ?

und wieso Zeile? ich habe die Werte in einer Spalte stehen. (also vertikal)
und wieso A1, wenn die Werte in C stehen?

sorry ich check das nicht so richtig

 

Hallo!

Das ist der mathematische Trick der Formel.
Die Funktion ZEILE gibt die Zeilennummer der angegebenen Zelle zurück:

ZEILE(A1) ergibt 1
ZEILE(A2) ergibt 2
usw.

also:
40*ZEILE(A1)-37 = 40*1-37 = 3
40*ZEILE(A2)-37 = 40*2-37 = 43
usw.

INDEX(C:C;3) ergibt C3, bzw. den Wert dieser Zelle
INDEX(C:C;43) ergibt C43, bzw. den Wert dieser Zelle

 

Ich verstehe irgendwie weniger als vorher :/
Du hast echt viel Ahnung, aber ich eben Null

Ich will einen Mittelwert von C3-C42.
und als nächstes C43-C82
usw.

Wie bekomm ich das hin?

 

Hallo!

Indem du meine Formel verwendest! Porbier's aus!

	A	B	C	D	E	F	G
1
2
3			0,48729216			0,51932304	0,51932304
4			0,24256815			0,46202324	0,46202324
5			0,68023465			0,49065204	0,49065204
6			0,47334145
7			0,78910849
8			0,24489597
9			0,06091945
10			0,20089948

Zelle	Formel
F3	=MITTELWERT(C3:C42)
G3	=MITTELWERT(INDEX(C:C;40*ZEILE(A1)-37):INDEX(C:C;40*ZEILE(A1)+2))
F4	=MITTELWERT(C43:C82)
G4	=MITTELWERT(INDEX(C:C;40*ZEILE(A2)-37):INDEX(C:C;40*ZEILE(A2)+2))
F5	=MITTELWERT(C83:C122)
G5	=MITTELWERT(INDEX(C:C;40*ZEILE(A3)-37):INDEX(C:C;40*ZEILE(A3)+2))

 

krass... Danke
funktioniert wirklich.

Wenn ich das jetzt auf eine Minute gemittelt haben will (also 120 Zellen â 0,5s)

nehme ich =MITTELWERT(INDEX(C:C;120*ZEILE(A1)-117):INDEX(C:C;120*ZEILE(A1)+2))

ja habs gerade probiert auf eine Minute!

DANKE DANKE DANKE