Office: (Office 2003) Prüfung aus Access-VBA ob bestimmte Exceldatei geöffnet ist reagiert sonderbar.

flowi · 7. August 2009

Hallo Forum,

ich bin hier seit ein paar Tagen heftigst am VBA-Programmieren. Es ist auch alles recht erfolgversprechend. Gerade eben habe ich eine Funktion geschrieben, die eine Exceldatei öffnet und die Referenz der geöffneten Datei zurück gibt.

Ich Programmiere zwar in Access 2007 habe jedoch die Excelobjektbib. der Version 11 eingebunden, da das Programm auf 2003 laufen muss.

Folgendes Problem. Dieser Codeausschnitt unten funktioniert wie er soll - aber nur manchmal.

Code:

'Überprüfung ob Datei bereits geöffnet ist. Dazu Abfrage des Namens aller
'geöffneten Excel-Workbooks (Dateien)
For Each xlWorkb In xlApp.Workbooks

'Wenn Übereinstimmung gefunden dann Funktionsvariable auf True setzen und
'Schleife verlassen. Da der Filename den ganzen Pfad enthält, wird auf der
'anderen Seite des Vergleiches das Wildcard benutzt.
If xlWorkb.Name = NameFromPath(FileName) Then
xlApp.Workbooks.Item(xlWorkb.Name).Activate
Set OpenExcelFile = xlApp.Workbooks.Item(xlWorkb.Name)
MsgBox ("Ja, die war wohl schon geöffnet")
Exit Function
End If
Next
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Manchmal wird erkannt, dass mindestens eine Excel-Datei geöffnet ist und der Code innerhalb von "For Each" abgearbeitet, aber manchmal eben nicht. Dann springt er von der "For Each" anweisung direkt hinter die "Next" Anweisung und öffnet die Datei ein zweites mal. Warum denkt das Programm dass die Sammlung "Workbooks" leer sei obwol das defacto nicht so ist? Gibt es da irgendwelche Mutmaßungen - Inaktiv, schreibgeschützt geöffnet oder so? (Ob die Objektzuweisung innerhalb von "For Each" funktioniert habe ich noch nicht getestet, kann also komplett falsch sein)

Vielen Dank im Vorraus

Florian

__________________________________________
Anhang: Die Komplette Funktion:
Code:

Public Function OpenExcelFile(FileName As String) As Workbook
'Funktion prüft, ob Excel bzw die Exceldatei bereits geöffnet ist und ob die Datei
'unter übergebenem Namen existiert. Die Funktionsvariable übergibt die Objektreferenz der Datei
'mit dem übergebenen namen oder ein "Nothing" wenn eine Referenzierung fehlgeschlagen ist.

'Deklaration der Objektvariablen vom Typ Excelanwendung. Achtung: Es muss die Objektbibliothek
'von Excel eingebunden worden sein.
Dim xlApp As excel.Application
Dim xlWorkb As Workbook

'Excelobjekt initialisieren
Set xlApp = excel.Application

'Überprüfung ob Datei bereits geöffnet ist. Dazu Abfrage des Namens aller
'geöffneten Excel-Workbooks (Dateien)
For Each xlWorkb In xlApp.Workbooks

'Wenn Übereinstimmung gefunden dann Funktionsvariable auf True setzen und
'Schleife verlassen. Da der Filename den ganzen Pfad enthält, wird auf der
'anderen Seite des Vergleiches das Wildcard benutzt.
If xlWorkb.Name = NameFromPath(FileName) Then
xlApp.Workbooks.Item(xlWorkb.Name).Activate
Set OpenExcelFile = xlApp.Workbooks.Item(xlWorkb.Name)
MsgBox ("Ja, die war wohl schon geöffnet")
Exit Function
End If
Next

'Wenn die Datei noch nicht geöffnet ist, prüfen ob Datei mit übergebenem Namen existiert
'und wenn ja, öffnen und mit der Funktionsvariablen referenzieren. Wenn die Datei nicht
'existiert Fehlermeldung ausgeben.

If FileExists(FileName) = True Then
Set OpenExcelFile = xlApp.Workbooks.Open(FileName)
MsgBox ("Habs geöffnet")
xlApp.Visible = True
Exit Function
Else
MsgBox ("Datei wurde nicht gefunden")
End If

'Referenz lösen
Set xlApp = Nothing

End Function
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

:)

ebs17 · 8. August 2009

Code:
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

'Excelobjekt initialisieren
Set xlApp = excel.Application

'Überprüfung ob Datei bereits geöffnet ist. Dazu Abfrage des Namens aller
'geöffneten Excel-Workbooks (Dateien)
For Each xlWorkb In xlApp.Workbooks
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Du nimmst keine Rücksicht darauf, ob Excel bereits in einer anderen Instanz geöffnet ist und sich dort offene Arbeitsmappen befinden.

Ansatz: Auf eine geöffnete Arbeitsmappe könntest Du wie folgt zugreifen:
Acc2002/XP - 3 Felder nach Excel exportieren

Und: Willkommen im Forum.

flowi · 9. August 2009

Danke, Eberhart für die Antwort. Zumindest habe ich verstanden wo das Problem liegt. Die Lösung ist dann nur eine Frage der Zeit. :-)

Gruß
Florian

ebs17 · 9. August 2009

Möglicher Weg:
(1) Test auf geöffnet: Wie kann ich prüfen, ob eine Datei geöffnet ist?
(2) bei offen siehe Link in #2, sonst Mappe öffnen in vorhandener oder neuer Excelinstanz (je nach Anforderung und Rahmenbedingungen)

Ich Programmiere zwar in Access 2007 habe jedoch die Excelobjektbib. der Version 11 eingebunden, da das Programm auf 2003 laufen muss.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Die Verwendung von Late Binding sollte das Verweisproblem entschärfen.

hcscherzer · 9. August 2009

Hier hab ich auch noch was gefunden hinsichtlich der Prüfung, ob Excel läuft oder nicht: Code:

Option Compare Database
Option Explicit

' Deklarieren der nötigen API-Routinen:
Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As Long) As Long
Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Sub excel_test()
Dim XL1 As Object ' Variable für Verweis auf Microsoft Excel.
Dim ExcelLiefNicht As Boolean ' Attribut für Freigabe am Ende.
Dim pfad As String

' Überprüfen, ob eine Kopie von Microsoft Excel bereits ausgeführt wird.
On Error Resume Next ' Fehlerbehandlung zurückstellen.

' GetObject-Funktionsaufruf ohne erstes Argument gibt einen Verweis auf
' eine Instanz der Anwendung zurück. Wenn die Anwendung nicht
' ausgeführt wird, tritt ein Fehler auf. Als Platzhalter für das erste
' Argument wird ein Komma verwendet.
Set XL1 = GetObject(, "Excel.Application")
If Err.Number 0 Then
ExcelLiefNicht = True
Err.Clear ' Err-Objekt im Fehlerfall löschen.
End If

' Prüfen auf Excel. Wenn Excel ausgeführt wird, wird
' dies in die Tabelle ausgeführter Objekte eingetragen.
DetectExcel

' Objektvariable so festlegen, daß sie auf die gewünschte Datei verweist.
pfad = "D:\TEST.XLS"
Set XL1 = GetObject(pfad)

If ExcelLiefNicht Then
' Microsoft Excel mit zugehöriger Application-Eigenschaft einblenden.
XL1.Application.Visible = True
End If

' Fenster mit der Datei unter Verwendung der Windows-Auflistung des
' XL1-Objektverweises anzeigen.
XL1.Parent.Windows(1).Visible = True
XL1.Parent.Workbooks(pfad).Activate

' hier käme jetzt die Verarbeitung, die auf das XL1 Objekt zugreift

' Wenn diese Kopie von Microsoft Excel beim Starten des Beispiels noch
' nicht ausgeführt wurde, wird Excel mit der Quit-Methode des
' Application-Objekts beendet.
If ExcelLiefNicht = True Then
XL1.Application.DisplayAlerts = False
XL1.Application.Quit
End If

Set XL1 = Nothing ' Verweis auf Anwendung und Tabelle freigeben.
End Sub

Sub DetectExcel()
' Diese Prozedur erkennt, ob Excel ausgeführt wird, und registriert dies.
Const WM_USER = 1024
Dim hWnd As Long

' Wenn Excel ausgeführt wird, wird durch Ausführen dieses
' API-Aufrufs die zugehörige Zugriffsnummer zurückgegeben.
hWnd = FindWindow("XLMAIN", 0)
If hWnd = 0 Then ' 0 bedeutet, daß Excel nicht ausgeführt wird.
Exit Sub
Else
' Excel wird ausgeführt. Verwenden der API-Funktion
' SendMessage, um Excel in der Tabelle ausgeführter
' Objekte einzutragen.
SendMessage hWnd, WM_USER + 18, 0, 0
End If
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Office: (Office 2003) Prüfung aus Access-VBA ob bestimmte Exceldatei geöffnet ist reagiert sonderbar.

Prüfung aus Access-VBA ob bestimmte Exceldatei geöffnet ist reagiert sonderbar.

Prüfung aus Access-VBA ob bestimmte Exceldatei geöffnet ist reagiert sonderbar.

Prüfung aus Access-VBA ob bestimmte Exceldatei geöffnet ist reagiert sonderbar.

Prüfung aus Access-VBA ob bestimmte Exceldatei geöffnet ist reagiert sonderbar. - Similar Threads - Prüfung Access VBA

Mehrfache Wenn Prüfung

Berechnung abhängig von unterschiedlichen Inventurdaten je Standort

Prüfung ob Wert in Spalte mit Wert aus bestimmtem Bereich übereinstimmt

Prüfung ob Spalte leer

Prüfung auf Tabellenwert erfolgt nicht

Bitte um Prüfung Datenbankmodells

Dringend: TEAMS-Anmeldung für Prüfung klappt nicht