Office: Reihe in Excel angeben?

Hallo,
hab ein Problem und möchte gerne eine Reihe in Excel darstellen:
1/1+1/2+1/3+...+1/n
n soll eine Zelle sein, bei der ich eine beliebige Zahl einfügen kann.
Hoffe mir kann jemand helfen :)
Danke

 

Hallo!

=SUMME(1/ZEILE(INDIREKT("1:"&B4)))
Achtung Matrixformel: Die Eingabe der Formel mit der Tastenkombination Strg+Shift+Enter abschließen!

 

Hey,
Super! vielen Danke :)
Hat geklappt. Kannst du mir vielleicht noch genau erklären, was die einzelnen Befehle genau Bedeuten und warum ich mit Strg+Shift+Enter bestätigen muss?=)

 

Hallo!

"1:"&B4
erzeugt den String "1:789", wenn in B4 der Wert 789 steht.

INDIREKT("1:789")
wandelt das in einen Zellbezug

ZEILE(1:789)
erzeugt das Array {1;2;3;4;...;788;789}

SUMME
brauche ich wohl nicht zu erklären...

Da hier ein Array erzeugt wird, musst du Excel darauf hinweisen.
Das passiert mit dem Abschluss als Array-/Matrixformel.

 

hi Schatzi, ich würde das ohne INDIREKT() machen..:

=SUMME(1/ZEILE(A1:INDEX(A:A;$B$4)))

Achtung, Matrixformel !
Die geschweiften Klammern{} werden nicht eingegeben.
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

 

hi Schatzi, ich würde das ohne INDIREKT() machen..:

=SUMME(1/ZEILE(A1:INDEX(A:A;$B$4)))

Achtung, Matrixformel !
Die geschweiften Klammern{} werden nicht eingegeben.
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

 

Hallo!

Jo, funktioniert genauso gut!
Dann lässt sich SUMME auch noch durch SUMMENPRODUKT ersetzen und auf den Matrix-Abschluss kann verzichtet werden.

 

Hallo,

nochmals vielen Dank für die Antworten. Könnte mir jemand vielleicht nochmals mit der Summenproduktform (da diese vermutlich einfach als die Matrixformen sind?) nochmals den genauen Zusammenhang erklären, damit für einen Laien verständlich wird, warum genau so diese Folge zustande kommt und was die einzelnen Befehle auslösen?

Danke

 

Hallo!

Die Formel funktioniert nach dem selben Prinzip wie bereits oben beschrieben.
Was die einzelnen Funktionen machen, kann man in der Excel-Hilfe nachlesen.
Wie die Formel die einzelnen Funktionen abarbeitet, kann man mit der Formelauswertung schrittweise überprüfen.

 

Tut mir leid, aber ich verstehe die Formel trotzdem noch nicht so ganz :-(
Nehmen wir mal diese Formel, da ich diese Matrix-Funktion auch noch nicht so ganz durchschaut habe:
=SUMMENPRODUKT(1/ZEILE(A1:INDEX(A:A;$B$4)))

Summenprodukt bedeutet, dass etwas multipliziert wird und anschließend addiert wird.
Dann hörts bei mir schon fast auf :-?
$B$4 ist das n, dass ich frei bestimmen kann, doch wozu dient das Feld A1, welches bei mir leer ist?
Was bedeuten die Befehle Zeile und Index (ja, ich habe sie mir bereits in der Hilfe durchgelesen) und was bringt der befehl A:A ?

Hoffe mir kann jemand helfen
Ich freue mich über jede Hilfe :)

 

Hallo!

=SUMMENPRODUKT(1/ZEILE(A1:INDEX(A:A;$B$4)))

Angenommen, in B4 steht der Wert "13".

INDEX(A:A;13) verweist dann auf die 13. Zelle des Bereichs A:A, also auf A13.

ZEILE(A1:A13) liefert das Array {1;2;3;4;5;6;7;8;9;10;11;12;13}, also die Zeilennummern der Zellen A1:A13.

1/ZEILE(A1:A13) liefert also das Array {1/1;1/2;1/3;1/4;1/5;1/6;1/7;1/8;1/9;1/10;1/11;1/12;1/13}

SUMMENPRODUKT addiert dann die Werte dieses Arrays und du bist dort, wo du hinwolltest.

(In diesem Fall wird beim SUMMENPRODUKT nichts multipliziert, da hier nur EIN Array verrechnet wird!)

 

Vielen Dank =)