Office: Schwieriges Problem mit Ranglisten

Hallo Experten!

Ich bin neu hier, beschäftige mich aber schon länger mit Excel /bzw. der Open Office Version

Bei folgendem Problem komme ich nicht mehr weiter:
Entschuldigt den Doppelpost, aber ich bräuchte nochmals dringend einen Tip bei einem diesmal wirklich schweren Excel-Problem:

Folgende Tabelle:

Preisschießen-die Platzierungen
Platz nach Kriterium I - Platz nach Kriterium II
Alf: 1.- 1.
Peter: 2. - 3.
Anna: 2. - 2.
Maria: 4. - 4.
Lutz: 5.- 8.
Uli: 5. - 6.
Armin: 5. - 9.
Emil: 8. - 7.
Isa: 9. - 5.



Wie ihr seht, gibt es laut Kriterium I zwei 2.Plätze und drei 5.Plätze. Für diese Punktegleichen (und nur für diese!) soll Excel nun JEWEILS voneinander isoliert zwei eigene Rangordnungen erstellen (ich weiß, dass Ränge mit dem Befehl RANG(…;…) berechnet werden).
Ich will also wissen, wer von den beiden Zweiten, der 1. und wer der 2. ist (isoliert betrachtet!) und wer von den drei Fünften der 1., der 2. und der 3. ist!
Excel soll also nur für den Fall gleicher Platzierungen nochmals jeweils eigene Rangordnungen erstellen.

Klingt umständlich doch ich bräuchte dies, da ich einen Weg gefunden habe, um aus den beiden Platzierungen die Endplatzierung errechnen zu lassen.


Schon jetzt herzlichsten Dank! :-)

 

Hallo!

Irgendwie begreife ich nicht ganz, worauf du hinaus willst...
Woher weiß Excel denn, welcher von den beiden Zweiten (oder Fünften) besser oder schlechter ist?
Aufgrund von KriteriumII?
Dann hast du doch schon die richtige Reihenfolge bei KriteriumII.
Oder habe ich einen Denkfehler?

 

Es läuft folgendermaßen:

Kriterium I ist die geschossene Ringanzahl minus die benötigte Zeit! Dies ist das entscheidende Kriterium!

Kriterium II soll nur das von Bedeutung sein, wenn mehrere Schützen denselben Platz belegen, wen nes also z.b drei 5.Plätze laut dem entscheidenden Kriterium I gibt!
Vegleichbar ist dies mit einer Fussballtabelle: Entscheidend sind die Punkte, nur bei punktegleichheit entscheidet für die punktegleichen Mannschaften das torverhältnis!

Ich möchte es an meinem Beispiel erläutern(habe es verändert, weil es missverständlich war)

Lutz, Uli und Armin wären nach Kriterium I alle auf Platz 5, in diesem Fall ,und NUR in diesem, soll Kriterium II entscheiden:
Laut Kriterium II ist Uli 6., Armin 9. und Lutz 8.
Kriterium II ist jedoch nicht entscheidend, es gibt bei punktegleichheit unter Kriterium I nur die Reihenfolge der ,in diesem Beispiel, drei 5ten Plätze an.
Laut kriterium II ist Uli unter den drei 5ten Plätzen ISOLIERT betrachtet 1.,
Lutz 2.,und Armin 3.
Genau so eine isolierte Rangaufstellung möchte ich für den Fall der Punktegleichheit unter Kriterium I
Excel soll also nur die Punktegleichen heraussuchen und dafür JEWEILS eine eigene Rangordnung erstellen, in meinem Beispiel also eine eigene Rangordnung für die beiden 2.Plätze und eine eigene Rangordnung für die drei fünften plätze!
Alf z.B. soll völlig unberührt bleiben weil niemand ausser im laut Kriterium I ebenfalls der Erste ist

Wa sich jetzt a8ufgezählt habe ist nur EIN Beispiel ,aber ich hoffe,dass damit das problem klarer wird.

Herzlichen Dank nochmals!

 

Ha, kaum wird's mit Fussball verglichen, schon verstehe ich's...

Ich gehe von diesem Aufbau aus:

Zeile1: Überschriften
A2:A10 Namen
B2:B10 Rang nach KriteriumI
C2:C10 Rang nach KriteriumII

Dann erhälst du in z.B. D2 den "endgültigen" Rang mit

=SUMME(N(100*B$2:B$10+C$2:C$10<=100*B2+C2))

Formeleingabe mit Strg+Shift+Enter abschliessen und dann runterkopieren bis D10.

 

@Schatzi: Spitze! Genauso gehts! :-D
Herzlichen Dank!

Wenn es dir nicht zuviel Arbeit ist, könntest du mir dann bitte genau erklären, wie diese Formel funktioniert? Das wäre für mich wirklich spannend nachzuverfolgen!
Hast du sie selber entworfen oder findet man sie als grobe Form in Excel? Ich habe versucht, sie einigermaßen zu verstehen, komme aber nicht ganz darauf.

jetzt komme ich mir schon fast schäbig vor wenn ich dich noch um einen Gefallen bitte, da du mir schon so geholfen hast, aber wäre es möglich, diese Formel noch durch ein drittes Kriterium zu erweitern, dass dann relevant würde, wenn laut Kriterium I UND Laut Kriterium II Punktegleichstand wäre?

 

Hallo!

In der Formel werden deine Kriterien gewichtet:
KritI wird mit 100 multipliziert,
KritII dann dazu addiert.
Dann zählt die Formel die Anzahl der Einträge, die kleiner oder gleich dem Suchwert sind.
Am einfachsten ist es nachzuvollziehen, wenn du dir eine Hilfspalte (z.B. Spalte F) mit dieser Formel machst

=100*B2+C2 und runterkopieren

auf diese Werte kannst du jetzt auch die RANG-Funktion anwenden:

=RANG(F2;F$2:F$10;1)

Da aber

=RANG(100*B2+C2;100*B$2:B$10+C$2:C$10;1)

nicht funktioniert, gehe ich den Umweg über SUMME(N(..., um die Hilfsspalte zu sparen.
Wenn du noch ein drittes Kriterium einführen willst, dann wichte die Kriterien entsprechend, z.B.

10000*B2+100*C2+D2

und baue dies in die Formel ein

=SUMME(N(10000*B$2:B$10+100*C$2:C$10+D$2:D$10<=10000*B2+100*C2+D2))

Ich hoffe, das war einigermaßen verständlich.

 

ah, schön langsam dämmert es mir :-D

Nur ist mir nicht ganz klar, warum du die Rang-Funktion mit SUMME(N... umschreiben kannst und was dieser Befehl eigentlich bewirkt.
Und warum muss ich die Formeleingabe mit Strg+Shift+Enter abschliessen?

Ich weiß nicht ob diese Fragen jetzt dumm klingen ,aber dazu reicht mein Informatik-Excel-Unterricht aus der Schulzeit nicht mehr aus

 

Mit Strg+Shift+Enter werden sogenannte Matrixformeln abgeschlossen. Diese können zeilen-/spaltenweise ganze Bereiche durchsuchen und das Ergebnis als Array zurück geben.
In der obigen Formel ergibt der Teil
100*B2:B10+C2:C10<=100*B2+C2
ein Array aus Wahrheitswerten, je nachdem, welche der Zeilen die Bedingung erfüllt oder eben nicht. Dieses Array könnte je nach Werten z.B. so aussehen
{WAHR;WAHR;FALSCH;WAHR;FALSCH;FALSCH;WAHR;WAHR;WAHR}
Wahrheitswerte werden jedoch von der Funktion SUMME ignoriert, d.h. die Summe dieses Arrays wäre immer 0.
Hier kommt die Funktion N ins Spiel, die aus Wahrheitswerten Zahlen macht: 1 für WAHR, 0 für FALSCH. Also sieht das Array jetzt so aus:
{1;1;0;1;0;0;1;1;1}
Und dieses Array ergibt mit SUMME nun 6.

 

Super, einfach Super!

Ich habe jetzt alles sehr gut verstanden.
Das ist echt clever ,die Ränge als Zahlen auszudrücken und dann mithilfe von Arrays, N (Das wandelt eine nicht-numerische Zahl in einen Wert um und macht aus WAHR die Zahl1, gell?) und Summe den Endrang auszugeben! ;-)

Auch ich hatte mir schon so eine Umschreibung ausgedacht,jedoch wäre diese viel komplizierter gewesen!

Mathematisch hatte ich es gleich erfasst, mir machten nur die unterschiedlichen Funktionen und die Schreibweisen Probleme, weil ich sie nicht kannte.

Aber da du dies ja prima erklärt hast, ist das Problem nun bestens gelöst, ich bin glücklich, dass ich Excel noch nicht ganz verlernt habe und bald werden sich auch einige Hobby-Schützen und Veteranen dank dir freuen, da das Turnier nun bald beginnen kann und sie endlich ballern dürfen :lol:

 

Hoffentlich kriege ich keine Probleme mit meiner Zivildienst-Leitung...

 

Ne, ne, ich selbst bin Bundeswehr-Flüchtling :lol:
ich erstelle die Tabelle nur für einen Verwandten. Dieser ist Stabsfeldwebel und organisiert daher dieses Jahr ein Turnier.

Ich würde das ja auch nicht machen, wenn es im Dienst für "Deutschlands Schleifer" wäre, aber mein Verwandter ist nun, nachdem ich das für ihn gemacht habe, sicher so nett und legt ein gutes wort ein, falls den Kasperln im Kreisweherersatzamt einfallen sollte, mich nochmals nachmustern zu lassen :lol: