Office: Suche Hilfe bei Summenprodukt Formel um Wochentage auszuwerten

Hallo Forumgemeinde,

ich suche mal wieder Hilfe. Es geht um eine Mitarbeiterverwaltung in der ich nun anhand der Wochentage / Monat
die Anzahl der Arbeitstage errechenen möchte.

Dann möchte ich noch die Anzahl der Wochenendtagen inkl. der Feiertage errechnen.

Zusätzlich möchte ich dann die Krankheitstage / Monat errechnen.

Das ganze soll so sein, dass ich die Zellen nicht jedes jahr individuell eingeben muss.


Ich habe mal einen Ansatz und lade ihn mit hoch. Ich hoffe mir kann einer helfen.

Ich denke ich bin auf dem richtigen weg, hab auch schon einige zeit gestöbert und gesucht, finde aber keine entsprechende lösung.


Besten Dank für eure Hilfe!


Gruß
CaMa

 

Das sind die Formeln die leider nicht richtig funktionieren.

Hat jemand eine Lösung?

{=SUMME(WENN(MONAT(A1:A100)=1;D1:H100)=K)}

oder =SUMMENPRODUKT((MONAT(A1:A100)=1)*D1:H100=K)

oder =SUMMENPRODUKT((MONAT(A9:A300)=1)*(D9:H38={"K"."KF"})

oder =SUMMENPRODUKT((MONAT(A9:A300)=1)*(D9:H384={"Mo"."Di"."Mi"."Do"."Fr"}))

oder =SUMMENPRODUKT((MONAT(A9:A300)=1)*(C9:C384="F"))


danke und Gruß
Marcel

 

Hallo Marcel,
wenn ich mich auf den Datenbestand in Deiner Datei beziehen darf, so muss Deine Formel:
=SUMMENPRODUKT((MONAT(A1:A100)=1)*D1:H100=K)
folgendermaßen lauten, damit sie funktioniert:
=SUMMENPRODUKT((MONAT(A9:A479)=1)*(D9:H479="K"))
Es müssen in beiden Kriteriumsausdrücken gleich viele Zeilen enthalten sein - sonst gibt es ein Problem; ferner muss natürlich das "K" als Textkonstante in Anführungszeichen gesetzt werden.

Ferner muss Deine Formel
=SUMMENPRODUKT((MONAT(A9:A300)=1)*(D9:H38={"K"."KF"})
folgendermaßen lauten:
=SUMMENPRODUKT((MONAT(A9:A479)=1)*((D9:H479="K")+(D9:H479="KF")))
Es müssen wieder in allen Kriteriumsaudrücken gleich viele Zeilen verwendet werden. Darüber hinaus funktioniert der Bereichsvergleich mit einer ARRAY-Konstanten nicht (um damit gleichzeitig mehrere Alternativen zu testen).
Dieser würde nur bei einem einspaltigen Bereich funktionieren, z.B.:
=SUMMENPRODUKT((MONAT(A9:A479)=1)*(D9:D479={"K"."KF"}))

 

Hallo Anton,

besten Dank für deine Hilfe.

Das mit dem suchen nach "K" & "KF" funktioniert prima.

Jetzt habe ich noch das Problem, dass die Wochentage bzw. Wochenendtage nicht richtig angezeigt werden.
Es wird sozusagen immer die doppelte Anzahl errechnet.
Ich habe es auf beiden Wegen probiert.

Formel Wochentage:
=SUMMENPRODUKT((MONAT(A9:A479)=1)*((B9:B479="Mo")+(B9:B479="Di")+(B9:B479="Mi")+(B9:B479="Do")+(B9:B479="Fr")))

Formel WE Tage:
=SUMMENPRODUKT((MONAT(A9:A479)=1)*(B9:B479={"Sa"."So"}))


ich könnte ja nun zum ende /2 rechnen. Aber iwo muss ja da noch ein Fehler sein oder nicht?

Vielen Lieben Dank!
Gruß
marcel

 

Hallo Marcel,

auf den ersten Blick hast Du mich damit verblüfft - aber ich habe mir Deinen Datenbestand nochmals genauer angesehen:
Dein Datumsbereich geht von Zelle A9 für den 1.1.2013 bis zur Zelle A478 für den 15.4.2014.
Entsprechend hast Du in Spalte B die Wochentagskürzel eingetragen.
Damit ist aber auch klar, dass der Monat JANUAR (MONAT(...)=1) zweimal vorkommt: nämlich Januar 2013 und der Januar 2014 - und somit haben die verwendeten Formeln auch korrekt gearbeitet.
Wenn Du keine mehrjährigen Zählungen zulassen willst, musst Du auch für die Jahresabfrage einen Kriteriumsausdruck einfügen, z.B:
=SUMMENPRODUKT((JAHR(A9:A479)=2013)*(MONAT(A9:A479)=1)*(B9:B479={"Sa"."So"}))
oder
=SUMMENPRODUKT((TEXT(A9:A479;"JJJJMM")="201301")*(B9:B479={"Sa"."So"}))

 

Hallo Anton,


stimmt, das ist jetzt iwie peinlich ;-)

Sry das war mein Fehler, besten Dank. Funktioniert nun alles prima.

Vielen Dank!!!!

Gruß
Marcel