Office: Tabellenblatt in bestehende Datei kopieren

mama-dean · 2. Januar 2005

Hallo zusammen!

Ich habe zu meinem Problem noch nichts hier gefunden und frag jetzt halt mal an.

Also ich bin in einer Datei "x" und möchte nun das active Tabellenblatt in eine bereits existierende Datei "y" kopieren. Mein Ansatz sieht bisher so aus, aber es funktioniert nicht.

Code:

ActiveSheet.Copy Before:=Workbooks(dsname2).Sheets(1)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Ich kann anstelle der Variable "dsname2" nicht den Dateinamen oder den Index nehmen, da sich das ständig ändert. Ich mach das ganze nicht nur mit einer Datei sondern mit 82 und die heißen alle anders und aus irgendeinem Grund, den ich nicht kenne, ändert Excel bei jeder Datei den Index (von 1 bis 3, jedesmal anders).

Hat da jemand ne Idee?

Gruß Jule

:)

JFreudens · 3. Januar 2005

Hi Jule,

der Copy-Befehl sieht prinzipiell gut aus und funktioniert bei mir auch, wenn ich
- der Variablen den Namen einer geöffneten anderen Mappe zuweise oder
- statt der Variablen einen konkreten Mappennamen angebe.
Es scheint also an der Zuweisung der Variablen dsname2 zu liegen.

Poste doch bitte mal den kompletten Code.

Gruß
Johannes

mama-dean · 3. Januar 2005

Hallo Johannes!

Code:

Sub nn()
On Error Resume Next
Application.DisplayAlerts = False
For f = 1 To 82
dsname = "P:\Beu\beu" & f & ".xls"
Workbooks.Open (dsname)

Workbooks.Add
dsname2 = "P:\Beu\leer" & f & ".xls"
ActiveWorkbook.SaveAs (dsname2)
ActiveWorkbook.Close (xlSaveChanges)

For s = 1 To 21
Sheets(s).Select
For e = 1 To 5000
If Cells(e, 10).Text = "Beurteilung" Then
If Cells(e + 1, 10).Text = "" Then
ActiveSheet.Copy Before:=Workbooks(dsname2).Sheets(1)
ActiveWorkbook.Close (xlSaveChanges)
s = s + 1
End If
End If
Next e
Next s
ActiveWorkbook.Close (xlSaveChanges)

Next f
Application.DisplayAlerts = True
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Kurze Erklärung:
Also ich gehe der Reihe nach mit "f" meine 82 Dateien (dsname) durch. Erstelle jeweils eine Gegendatei dazu (dsname2). Dann gehe ich mit "s" meine 21 Tabellenblätter (es sind immer 21). Bestätigt das Blatt mein "If", dann soll es nach "dsname2" kopiert werden.
Da aus den Datein (dsname) unterschiedlich viele Tabellenblätter kopiert werden, bringt es auch nichts, sie in eine neue Datei zu kopieren. Es sollen jeweils alle entsprechenden Tabellenblätter die Gegendatei kopiert werden. Es würde also jeweils nur bei dem ersten Blatt von dsname funktionieren und dann stünde ich wieder vor dem gleichen Problem.

Ich hoffe, dass du verstehst was ich meine.

Lumpensammler · 4. Januar 2005

Hallo, Jule,

vielleicht sollte die Anweisung zum Schließen von dsname2 nach dem Kopieren durchgeführt werden (genau wie die Speicherung).

Gruß
LS

JFreudens · 4. Januar 2005

Hi,

das Hauptproblem war, dass du die Zieldatei schon wieder geschlossen hattest, bevor du die Blätter kopiert hast. Das Kopieren funktioniert aber nur in geöffnete Dateien, wie LS ja auch schon geschrieben hat.

Der Code war recht schwer lesbar. Du solltest dir unbedingt angewöhnen, "sprechende" Variablenbezeichnungen zu verwenden.

Innerhalb einer For-Next-Schleife sollte man nur in Ausnahmefällen (wenn man weiß, was man tut), die Laufvariable händisch manipulieren. Damit meine ich die Zeile s=s+1. Das geht meistens schief und führt nicht zum gewünschten Ergebnis.

Schau dir mal die modifizierte Fassung an. Ich denke, sie tut ansatzweise das, was du dir (bzw. uns) vorgestellt hast.

Ciao
Johannes
Code:

Option Explicit
Sub nn()
Dim QuellBook As Workbook
Dim Kopie As Workbook
Dim DateiZähler As Integer
Dim BlattNummer As Integer
Dim ZeilenNummer As Integer
Dim dsName As String
Dim dsName2 As String

On Error Resume Next
'Application.DisplayAlerts = False ' Meines Erachtens nicht notwendig
' Application.ScreenUpdating = False ' Zur Beschleunigung diese Zeile aktivieren
For DateiZähler = 1 To 82

dsName = "P:\Beu\beu" & DateiZähler & ".xls"
dsName2 = "P:\Beu\leer" & DateiZähler & ".xls"
Set QuellBook = Workbooks.Open(dsName)

Set Kopie = Workbooks.Add
QuellBook.Activate

For BlattNummer = 1 To 21
With QuellBook.Sheets(BlattNummer)

For ZeilenNummer = 1 To 5000

If .Cells(ZeilenNummer, 10).Text = "Beurteilung" Then
If .Cells(ZeilenNummer + 1, 10).Text = "" Then
.Copy Before:=Kopie.Sheets(1)
Exit For ' Einmal kopieren reicht
End If
End If

Next ZeilenNummer
End With
Next BlattNummer

QuellBook.Close (xlSaveChanges) ' Obwohl daran ja gar nichts geändert wurde

Kopie.SaveAs (dsName2)
Kopie.Close
' Hier hätte man noch eine Abfrage eibauen können, ob überhaupt Tabellen in die
' Mappe dsname2 kopiert wurden. Falls nicht, könnte man sich das Speichern einer
' leeren Mappe ggfs. ersparen.

Next DateiZähler
' Application.DisplayAlerts = True
Application.ScreenUpdating = True
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

mama-dean · 4. Januar 2005

Hallo Johannes!

Es funktioniert.

Ich hatte auch vorher schon mal probiert, die Datei offen zu lassen, hab aber die erste Datei nicht wieder activ gekriegt.

Vielen Dank und noch viel Spaß im neuen Jahr!

Gruß Jule

Office: Tabellenblatt in bestehende Datei kopieren

Tabellenblatt in bestehende Datei kopieren

Tabellenblatt in bestehende Datei kopieren

Tabellenblatt in bestehende Datei kopieren

Tabellenblatt in bestehende Datei kopieren - Similar Threads - Tabellenblatt bestehende Datei

commandbutton fließend auf dem Tabellenblatt einrichten

Tabellenblatt in neue Mappe kopieren

Beträge in anderem Tabellenblatt anzeigen lassen mit Bezug auf einen Monat und ohne Leerzellen

Daten aus einem Tabellenblatt in ein anderes kopieren ohne Leerzellen anzuzeigen

Export in bestehendes Tabellenblatt

bestehendes Tabellenblatt-kopier-Makro auf Spalten-kopieren ändern

VBA Tabellenblatt aus bestehendem File kopieren, umbenennen und ans ende stellen