Office: Termine von Excel nach Outlook!!

Tobeat · 12. Februar 2013

Hallo liebe Gemeinde,

dies ist meine erste Frage und der Grund warum ich mich hier angemeldet habe. Ich habe Formeltechnisch in Excel ein bisschen Erfahrung und habe eine Tabelle gebaut, die mir den Verbrauch von ätherischen Ölen, je nach benutzung ausrechnet. Soweit so gut. Nun bekomme als Endergebnis ein Datum und die KW dazu. Ich fände es durchaus praktisch, wenn ich ein Makro programmieren könnte, dass mir dann den jeweiligen, anstehenden Wechseltermin, als Erinnerung im Outlook zeigt.
Ich habe zwar schon versucht, ein bisschen was mit Makros anzufangen, muss aber zugeben, dass ich absolut unbegabgt bin und dieses VBA Zeug mehr als nur Böhmische Dörfer für mich sind *frown.gif*

Ich danke schon mal für Antworten *wink.gif*

Liebe Grüße
Tobias

:)

Tobeat · 13. Februar 2013

Ich bin mir sicher, dass meine Erklärung etwas dürftig ist. Sollte sich jemand das durchlesen und denken, für eine Antwort habe ich zu wenig Infos, dann schreibt das bitte *Smilie ich würde auch eine Beispiel-Datei hochladen *wink.gif*

JoergF · 14. Februar 2013

Hallo Tobias,

probiere mal folgendes:

Code:

Sub OLTerminEintragen()

Application.ScreenUpdating = False ' Bildschirmaktualisierung aus (schneller!)
Application.DisplayAlerts = False ' Warnmeldungen aus (schneller!)

Dim olApp As Object ' Outlook.Application
Dim olTermin As Object ' Outlook-Termin (Outlook.AppointmentItem)

Dim strBetreff As String
Dim strOrt As String
Dim datStart As Date
Dim datEnde As Date
Dim strNotiz As String
Dim strKategorie As String

'*** Beispiele ***
strBetreff = "Betreff des Termins"
strOrt = "Ort des Termins"
datStart = "14.02.13 08:00"
datEnde = "14.02.13 10:00"
strNotiz = "Notiz zu dem Termin"
strKategorie = "Testkategorie"

Set olApp = CreateObject("Outlook.Application") ' Outlook.Application
Set olTermin = olApp.CreateItem(1) ' Outlook-Termin (Outlook.AppointmentItem)

With olTermin ' diesem Termin zuordnen:
.Subject = strBetreff ' Betreff
.Location = strOrt ' Ort
.Start = datStart ' Startzeit festlegen
.End = datEnde ' Endzeit festlegen
.BusyStatus = olBusy ' Anzeigen als: olBusy = Gebucht; olFree = Frei; olOutOfOffice = Abwesend; olTentative = Mit Vorbehalt
.Body = strNotiz ' Inhalt Notizen
.Categories = strKategorie
.Save ' speichern
End With

Set olTermin = Nothing
Set olApp = Nothing

Application.ScreenUpdating = True ' Bildschirmaktualisierung ein
Application.DisplayAlerts = True ' Warnmeldungen ein

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Viel Erfolg
Jörg

Tobeat · 14. Februar 2013

Lieber Jörg,

vielen Dank für deine Antwort. Es funktioniert schon mal sehr gut *Smilie

gibt es eine Möglichkeit, die sich ändernden Daten mithilfe eines Befehls dann in dieser Formel mit zu ändern? Da sich ja z.B. das Datum alle 2-4 Wochen ändern würde?
und... ich nehme an, um das Makro auszuführen muss ich die Datei immer wieder öffnen. Gibt es einen Automatismus der dass z.B. alle 2 Wochen von selbst tut?

Liebe Grüße

JoergF · 14. Februar 2013

Hallo Tobias,

für eine Wiederholung des Termins suche in der VBA-Hilfe mal das Stichwort "GetRecurrencePattern". Da sind auch Beispiele dabei. Den Automatismus übernimmt damit dann Outlook, so dass das Excel-Makro nicht mehr benötigt wird.

Wenn Du den Termin, den Du in Outlook eingetragen hast, jeweils ändern möchtest, dann musst Du danach suchen und anschließend die entsprechenden Parameter ändern - findest Du in der VBA-Hilfe ebenfalls Beispiele zu.

Ansonsten würde eine Beispielmappe nicht schaden.

Code:

For Each olTermin In olApp.GetNamespace("MAPI").GetDefaultFolder(olFolderCalendar).Items
If olTermin.Subject = strBetreff And _
olTermin.Location = strOrtK And _
olTermin.Start = CStr(datStart) Then ' Betreff, Ort und Beginn identisch?
bTerminExist = True ' Termin existiert schon
Exit For ' For-Schleife kann verlassen werden
End If
Next
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Viel Erfolg
Jörg

Tobeat · 14. Februar 2013

Hier einmal ein Anhang um sich den Überblick zu verschaffen *wink.gif*

habe gerade noch folgendes problem festgestellt... beim ersten mal hat alles funktioniert. ich hatte den termin wie gewünscht, durch den bezug = Range ("D5*biggrin.gif*5") in meinem outlook.
zu demonstrationszwecken, habe ich den termin herausgelöscht und wollte noch einmal auf die schaltfläche drücken. nur den termin erstellt es mir leider nicht mehr... es passiert sozusagn nichts :/
Ideen? ^^

JoergF · 14. Februar 2013

... das ist ein Excel-Dateiformat, welches ich hier nicht einlesen kann, da ich mit Excel 2003 arbeite. Speicher das mal als 2003er-Version.

Mfg
Jörg

Tobeat · 14. Februar 2013

ups, sorry ^^ ich hoffe das die formeln jetzt alle noch kompatibel sind *biggrin.gif* hab hier und da glaub ich mal mehr als 7 verschachtelungen gebraucht *biggrin.gif* aber vielleicht hast du ja noch den ein oder anderen tipp mehr für mich *wink.gif*

noch mal ein ganz dickes lob, dass sich hier so sehr zeit genommen wird für mein problem *wink.gif* *wink.gif*

JoergF · 14. Februar 2013

Hallo Tobias,

die Datei kann ich jetzt zwar laden, aber ich bekomme Fehlermeldungen aus einzelnen Zellen. Das liegt wohl daran, dass Excel 2003 die Funktion "Kalenderwoche" noch nicht kennt. Ich kann diese hier zwar per VBA "nachbilden", kann die Blätter mit dem Blattschutz aber nicht aktualisieren. Schick' die Datei doch nochmals ohne irgendwelchen Schutz, dann kann ich mir das noch einmal ansehen.

MfG
Jörg

Tobeat · 14. Februar 2013

auf ein neues ^^

Blattschutz ist nun in jedem Tabellenblatt deaktiviert. Ich hoffe dass es die einzige Formel ist die nicht funktioniert *wink.gif*

JoergF · 15. Februar 2013

Hallo Tobias,

Du musst natürlich das Eintragen der Termine in einer Schleife programmieren:
Code:

Sub OLTerminEintragen()

Application.ScreenUpdating = False
Application.DisplayAlerts = False

Dim olApp As Object
Dim olTermin As Object
Dim strBetreff As String
Dim strOrt As String
Dim datStart As Date
Dim datEnde As Date
Dim strNotiz As String
Dim strKategorie As String
Dim intZeile As Integer
Dim intRows As Integer

Set olApp = CreateObject("Outlook.Application")

' Spalte F ("Datum für Makro") letzte Zeile berechnen
intRows = Range("F" & Rows.Count).End(xlUp).Row

strBetreff = "Wechsel Kartusche"
strNotiz = "Listen Check - Hausbeduftung PVL"
strKategorie = "Hausbeduftung PVL"

' Schleife für jeden Datumseintrag in Spalte F
For intZeile = 5 To intRows
strOrt = Cells(intZeile, 2)
datStart = Cells(intZeile, 6)
datEnde = Cells(intZeile, 4)
' Debug.Print strOrt, datStart, datEnde
Set olTermin = olApp.CreateItem(1)
With olTermin
.Subject = strBetreff
.Location = strOrt
.Start = datStart
.End = datEnde
.BusyStatus = olBusy
.Body = strNotiz
'.Categories = strKategorie
.Save
End With
Next

Set olTermin = Nothing
Set olApp = Nothing
Application.ScreenUpdating = True
Application.DisplayAlerts = True

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Mfg
Jörg

Tobeat · 18. Februar 2013

Heftig *wink.gif* Danke Jörg *Smilie Wie gesagt, meine Kenntnisse in Sachen Makros sind super begrenzt *biggrin.gif* aber du hast die perfekte Lösung gebracht. Tausend Dank dafür *Smilie

Office: Termine von Excel nach Outlook!!

Termine von Excel nach Outlook!!

Termine von Excel nach Outlook!!

Termine von Excel nach Outlook!!

Termine von Excel nach Outlook!!

Termine von Excel nach Outlook!! - Similar Threads - Termine Excel Outlook

Excel Termin in Outlook Kalender

Ausgewählte Excel Termine per VBA in Outlook importieren

Excel Termine über entry ID mit Outlook abgleichen

Excel Termine in bestimmten Outlook Kalender

Tabelle aus Excel über VBA in Outlook mit Formatierung übertragen

Frage: Terminplanung aus Excel - Termine in outlook automatisiert versenden?

Termine von Excel nach Outlook importieren und aktualisieren