Office: VBA - Pivot Tabelle mit Version 12 erstellen geht nicht

Hallo zusammen,

irgendwie verstehe ich nicht warum VBA mir nicht eine Pivottabelle in der Version 12 erstellen möchte?.
Wenn ich den Code ohne Version 12 eingebe funktioniert dieser - mit aber nicht.

Hat einer von Euch eine Idee?
(Beispiel Datei im Anhang)

Code:

Sub TestPT()
Dim ptCache As PivotCache
Dim ptTable As PivotTable
Dim i As Integer
With ActiveSheet
    For Each ptTable In .PivotTables
        ptTable.TableRange2.Delete
        Next ptTable
    End With
Set ptCache = ActiveWorkbook.PivotCaches.Add _
    (SourceType:=xlDatabase, _
     SourceData:="A1:F" & ActiveSheet.UsedRange.Rows.Count, _
     DefaultVersion:=xlPivotTableVersion12)
     
Set ptTable = ptCache.CreatePivotTable _
    (TableDestination:=ActiveSheet.Range("H1"), _
     TableName:="Test", _
     DefaultVersion:=xlPivotTableVersion12)
     
With ptTable
    .PivotFields("Kaufdatum").Orientation = xlPageField
    .PivotFields("Kunde").Orientation = xlRowField
    .PivotFields("Getränk").Orientation = xlColumnField
    .PivotFields("Total").Orientation = xlDataField
End With
Columns("A:N").AutoFit
Set ptCache = Nothing
Set ptTable = Nothing
End Sub

Schöne Grüße

 

Grüezi Tauchmann

Mit welcher Excel-Version arbeitest Du denn genau?

Hat Du den Code fürs Erstellen der PT mit dem Recorder aufgezeichnet?
Dieser liefert was die PT-Version anbelangt eigentlich die korrekten Werte....

Wenn ich das in deiner Mappe tue erhalte ich eine PT der Version 10 - wieso willst/musst Du eine Version 12 erzeugen?


Kann es sein, dass die Mappe unter xl2003 oder älter erstellt worden ist, dort die PT hinzugefügt und nun keine andere Version möglich ist?
Wie sieht es aus, wenn Du ein einer in xl2007 erstellten Mappe eine PT hinzufügst?

 

Hallo Thomas,

Also ich arbeite mit Excel 2007

Die Tabelle habe ich aus einem Buch genommen, da die Beschreibung verständlich war :).
In der handgeschriebenen Version kann ich keine PT Version angeben und erzeuge somit eine unschöne und nicht selbsterklärende PT Table.

Die Version 12 macht die erstellten Übersichten verständlicher und schöner (schöner Nebeneffekt)

Die Mappe habe ich unter xl2007 erstellt und kann wenn ich den Recorder verwende die Version 12 erstellen und verwenden.

Das schöne an der beschriebenen Möglichkeit ist, das ich einen Cache erstelle und diesen mehrmals verwenden kann und nicht immer wieder einen neuen brauche. (Performance Steigerung).

Hast du eine Idee wie man das verbinden kann?


Schöne Grüße

Tauchmann

Code:

Sub Test2()
Dim ptCache As PivotCache
Dim ptTable As PivotTable
With ActiveSheet
    For Each ptTable In .PivotTables
        ptTable.TableRange2.Delete
    Next ptTable
End With
ThisWorkbook.PivotCaches.Create(SourceType:=xlDatabase, _
SourceData:="Tabelle1!R1C1:R8C6", _
Version:=xlPivotTableVersion12).CreatePivotTable _
TableDestination:="Tabelle1!R1C8", _
TableName:="TestPT", _
DefaultVersion:=xlPivotTableVersion12
End Sub