Office: wenn-dann Verweis oder Vergleich?

Hallo an die wissende Gemeinde!

Folgendes Problem: ich möchte ein Formular erstellen, bei dem ein Feld per Formel automatisch mit Daten gefüllt wird, die in einem extra Arbeitsblatt (gleiche Datei) bereits vordefiniert sind.

Die vorgegebenen Daten gliedern sich wie folgt:
Spalte A: Datumswert, nach dem System "Woche vom...". Bsp: 03.01.11
Spalte B: Aufgabenbereich 1 (werden mit Namen gefüllt.)
Spalte C und D: Aufgabenbereich 2 (Spalte C: Verantwortlicher, Spalte D: Partner)

In dem Arbeitsblatt für das Formular werden die Daten zusammengeführt.
Feld "Datum" = Werte aus "Spalte A"
Feld "Aufgabenbereich" = Wert 1 oder 2
Feld "Verantwortlicher" = hier soll die gesuchte Formel stehen nach dem Prinzip: (Bsp) wenn Datum = 03.01.11 und Aufgabenbereich = 1, dann Name aus Spalte B bzw.
wenn Datum = 03.01.11 und Aufgabenbereich = 2, dann Name aus Spalte C.

Hat da jemand eine Idee?

Gruß
Stephan

 

hi Stephan, noch ohne fehlermeldung... ... meinst du so?

=SVERWEIS(A3;Tabelle1!A:C;1+B3;0)

in meiner tabelle formularblatt stand das datum in A3 der wert für den Aufgabenbereich in B3...

 

hallo hiob,

danke für deine schnelle Antwort. Ich hab es ausprobiert, aber komm nicht so recht drauf.

anbei eine beispieldatei.

Gruß
stephan

 

hi Stephan, das geht doch... bei mir jedenfalls..: (als alternative für die INDEX()-formel in B5 in B6 ein einfacher SVERWEIS()..:

oder eben nur mit VERWEIS()..: für B5..:

=VERWEIS(I3;Datenquelle!A4:D1000)

Arbeitsblatt mit dem Namen 'Formularblatt'
	A	B	C	D	E	F	G	H	I
2
3	Verantwortlicher	Peter				Aufgabenbereich	1	Datum	03.01.2011
4
5	Partner	Mary
6		Mary
7

Zelle	Formel
B3	=SVERWEIS(I3;Datenquelle!A:C;1+G3;0)
I3	=Datenquelle!A4
B5	=INDEX(Datenquelle!D:D;VERGLEICH(I3;Datenquelle!A:A;0))
B6	=SVERWEIS(I3;Datenquelle!A:D;4;0)

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

 

hi hiob,

ich bin leider gestern abend erst wieder dazu gekommen, zu probieren.
Es tut mir leid, aber mit der sverweis-Formel komme ich nicht weiter. Das Problem liegt meiner Meinung nach darin, dass in einer Formel zwei Bedingungen verglichen und danach Werte ausgewählt werden müssen.
und das klappt bei mit nicht mit der sverweis - Formel. Als Spaltenindex hast du "1+G3" angegeben, aber eigentlich ist das doch eine der beiden Bedingungen, die für die Abfrage benötigt werden.
Meiner Ansicht nach müsste es eine Formel mit einer UND-Verknüpfung sein: wenn...G3=Datenquelle B1:D1 UND I3=Datenquelle A:A, dann Werte aus den Spalten B und C der Datenquelle.
Ist kompliziert, aber vielleicht kannst du meine Beschreibung ja durchschauen...

Vielen Dank
Stephan[/u]

 

hi Stephan, das ist schon möglich, dann hatte ich es anders verstanden... aber du hattest ??? gesetzt, besser wäre ein händisch eingetragenes ergebnis... ich versteh nicht, was du für ein ergebnis haben möchtest, lade doch bitte die datei noch mal hoch mit selbst eingetragenen ergbnissen (wenn's geht mit mehr als einem ergebnis...)

 

Hallo,

vielleicht hilft das:

Arbeitsblatt mit dem Namen 'Formularblatt'
	A	B	C	D	E	F	G	H	I
3	Verantwortlicher	Peter				Aufgabenbereich	1	Datum	03.01.2011
4
5	Partner
6

Zelle	Formel
B3	=WENN(($G$3=1)*($A3="Partner");"";INDEX(Datenquelle!$B$4:$D$5;VERGLEICH(Formularblatt!$I$3;Datenquelle!$A$4:$A$5;0);Formularblatt!$G$3+(Formularblatt!$A3="Partner")*1))
I3	=Datenquelle!A4
B5	=WENN(($G$3=1)*($A5="Partner");"";INDEX(Datenquelle!$B$4:$D$5;VERGLEICH(Formularblatt!$I$3;Datenquelle!$A$4:$A$5;0);Formularblatt!$G$3+(Formularblatt!$A5="Partner")*1))

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

Gruß

Edgar

 

Hallo Edgar,

ich glaube, dass ist es!
Bin jetzt nicht zuhause, so dass ich es nur an der Beispieldatei testen kann, aber es sieht sehr vielversprechend aus!
DAnke schon mal.

(Melde mich bezüglich Erfolgserlebnissen nochmal zurück!)

Gruß
Stephan