Office: (Office 2016) Wert für berechnetes Feld in VBA eintragen

Helfe beim Thema Wert für berechnetes Feld in VBA eintragen in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Moin zusammen :D Ich hoffe ich könnt mir helfen. Zu meinem Problem Ich habe eine Pivot Tabelle und arbeite hier u.a. mit berechneten Werten. Der... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von ThomasN, 11. Dezember 2019.

  1. ThomasN Neuer User

    Wert für berechnetes Feld in VBA eintragen


    Moin zusammen :D
    Ich hoffe ich könnt mir helfen. Zu meinem Problem
    Ich habe eine Pivot Tabelle und arbeite hier u.a. mit berechneten Werten.
    Der simpelste berechnete Wert lautet: =5
    Nun meine Frage: Kann ich diese 5 per vba z.b. zu einer 3 machen?

    Mein bisheriger Code ist:
    Sub test()
    Dim RW As Integer
    RW = Range("V1").Value
    Application.CutCopyMode = False
    Sheets("Daten Liquidität").Select
    ActiveSheet.PivotTables("PivotTable1").CalculatedFields("RW CBR EK"). _
    StandardFormula = "RW"
    End Sub

    aber funktioniert natürlich nicht Wert für berechnetes Feld in VBA eintragen :(
    Eine Hilfszeile kommt leider nicht in Frage, da ich derer viele bräuchte
    Wäre dankbar über jede Hilfe :)
     
  2. Exl121150 Erfahrener User
    Hallo,

    in der beiliegenden Excel-Datei habe ich im
    • im Arbeitsblatt "Tabelle1" die List-Tabelle "TabDaten" eingefügt;
    • im Arbeitsblatt "Daten Liquidität" die PivotTable "PivotTable1" eingefügt, welche die Tabelle "TabDaten" als Datenquelle verwendet.
      Die PivotTable enthält die Spalte "Piv_Preis", die ihre Werte aus dem berechneten PivotTable-Feld "Preis" bezieht. Die enthaltene Formel lautet "=Betrag/Menge".
    Im allgemeinen Codemodul "Modul1_Neu" habe ich die folgenden 4 Makros eingefügt, die auch in dieser Reihenfolge ausgeführt werden sollen:
    1. Makro "Teste1_Formel"
    2. Makro "Teste2_Felder_Hinzufügen"
    3. Makro "Teste3_FormelÄndern"
    4. Makro "Teste4_Felder_Entfernen"

    Code:
    Option Explicit
    
    Sub Teste1_Formel()
      Dim Ws As Worksheet
      Dim Pv As PivotTable
      Dim Fld As PivotField
      
      Set Ws = ThisWorkbook.Worksheets("Daten Liquidität")
      Set Pv = Ws.PivotTables("PivotTable1")
      
      'Bestehendes berechn.Feld "Preis" der PivotTable-Datenquelle wird mit einer (neuen) Formel bestückt.
      'Die Felder "Betrag" und "Menge" müssen in der Datenquelle existieren.
      Pv.CalculatedFields.Item("Preis").Formula = "=Betrag/Menge"
    End Sub
    Sub Teste2_Felder_Hinzufügen()
      Dim Ws As Worksheet
      Dim Pv As PivotTable
      Dim Fld As PivotField
      
      Set Ws = ThisWorkbook.Worksheets("Daten Liquidität")
      Set Pv = Ws.PivotTables("PivotTable1")
     
      'Der PivotTable-Datenquelle wird ein neues Feld "PrivAlt" hinzugefügt und mit der Formel "=5" versehen.
      Set Fld = Pv.CalculatedFields.Add(Name:="PrivAlt", Formula:="=5")
      'In der PivotTable "PivotTable1" des Arbeitsblattes erhält dieses die Feldüberschrift "Piv_PrivAlt"
      'und als Werte werden lauter 5 angezeigt:
      Pv.AddDataField field:=Fld, Caption:="Piv_PrivAlt", Function:=xlSum
    End Sub
    Sub Teste3_FormelÄndern()
      Dim Ws As Worksheet
      Dim Pv As PivotTable
      Dim Fld As PivotField
      
      Set Ws = ThisWorkbook.Worksheets("Daten Liquidität")
      Set Pv = Ws.PivotTables("PivotTable1")
     
      'Die Formel, die im angezeigten Feld "Piv_PrivAlt" wirksam werden soll, soll jetzt geändert werden -
      'und zwar auf "= Menge + 5".
      'Diese Formeländerung muss im zugrunde liegenden berechn.Feld "PrivAlt" durchgeführt werden:
      Pv.CalculatedFields.Item("PrivAlt").Formula = "=Menge + 5 "
    End Sub
    
    Sub Teste4_Felder_Entfernen()
      Dim Ws As Worksheet
      Dim Pv As PivotTable
     'Dim Fld As PivotField
      
      Set Ws = ThisWorkbook.Worksheets("Daten Liquidität")
      Set Pv = Ws.PivotTables("PivotTable1")
      
      'Das berechn.Feld "PrivAlt" der "PivotTable1" soll wieder entfernt werden.
      'Dadurch wird auch die angezeigte Pivot-Spalte "Piv_PrivAlt" entfernt.
      Pv.CalculatedFields.Item("PrivAlt").Delete
      
    End Sub
    
    Es sind gleichzeitig Kommentare enthalten, die die Funktionalität verdeutlichen.
     
    Exl121150, 13. Dezember 2019
    #2
Thema:

Wert für berechnetes Feld in VBA eintragen

Die Seite wird geladen...
  1. Wert für berechnetes Feld in VBA eintragen - Similar Threads - Wert berechnetes Feld

  2. Adjazenzmatrix mit berechneten Werten

    in Microsoft Excel Hilfe
    Adjazenzmatrix mit berechneten Werten: Liebe Gemeinde, ein Neuling hier. Seit einigen Monaten sitze ich an einer (sozialen) Netzwerkanalyse für meine Abschlussarbeit und möchte dafür mit Ähnlichkeitswerten arbeiten. Sprich, wie...
  3. Ausgeblendete Werte in berechnetem Feld berücksichtigen

    in Microsoft Word Hilfe
    Ausgeblendete Werte in berechnetem Feld berücksichtigen: Guten Morgen. Ich stehe an folgendem Problem an: Seit der Umstellung von Office 2010 auf Office 2016 zickt Word bei einer Berechnung einer Tabellenzeile. Die Formel im Feld rechts aussen in...
  4. berechneter wert mit einer liste vergleichen und näheren wert ausgeben

    in Microsoft Excel Hilfe
    berechneter wert mit einer liste vergleichen und näheren wert ausgeben: Hi leute, zu meinen Problem, ich möchte einen Wert berechnen lassen. Dieser berechneter wert soll mit Werten die in Tabelle 2 stehen verglichen werden und der nähere Wert soll dann auf Tabelle...
  5. Zirkelbezug vermeiden, Werte aus berechneten Zellen kommulieren

    in Microsoft Excel Hilfe
    Zirkelbezug vermeiden, Werte aus berechneten Zellen kommulieren: Hallo liebe User, wie ist es möglich die Zelle B11, die sich bei bestimmten Eingaben immer neu berechnet, mit der Zelle B7 so zu addieren, dass sich die Werte kommulieren. Eine Eingabe erzeugt...
  6. In Makro berechnete Werte über Textfeld ausgeben

    in Microsoft Excel Hilfe
    In Makro berechnete Werte über Textfeld ausgeben: Hallo, Ich habe folgendes Problem: Über ein Makro (also in der VBA Umgebung) lasse ich durch mehrere Schleifen ein Wert berechnen. Diesen Wert möchte ich an die Tabelle zurückgeben, und zwar...
  7. Mehrere Formeln durch deren berechneten Wert ersetzen

    in Microsoft Excel Hilfe
    Mehrere Formeln durch deren berechneten Wert ersetzen: Hallo. Ich habe eine Funktion, welche eine andere Funktion erstellt: Funktion => =VERKETTEN(J2;K2;L2;M2;N2) Ergebnis => =VERKETTEN(G3;$H$1;H3) Jetzt hab ich in einer Zelle das Ergebnis...
  8. mit einem Formular berechnete Werte abspeichern

    in Microsoft Access Hilfe
    mit einem Formular berechnete Werte abspeichern: Hallo. Aus 2 Tabellen habe ich ein Formular erstellt. Durch verschiedene Kriterien aus der einen Tabelle wird ein Wert im Formular berechnet, der schon in einem Textfeld in diesem Formular...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden