Office: Zeile Fixieren mit VBA

Morgen zusammen, möchte das wenn man auf einen Button drückt, das dann in einem anderen Fenster die Zeilen 1 bis 17 stehen bleiben beim Scrollen (fixieren).

Habe es mit folgendem Code Versucht.

Worksheets(DateStr & TimeStr).Range("A17").Select
Worksheets(DateStr & TimeStr).FreezePanes = True

Grüße TF

 

Hallo TF2206,

die Fensterfixierung erfolgt immer oberhalb und links von der ausgewählten Zelle.
Willst Du also die Zeilen 1-17 fixieren, musst Du A18 auswählen.
Würdest Du die Zelle B18 auswählen, würde zusätzlich zu den Zeilen 1-17 auch noch die Spalte A fixiert.

Soweit mir bekannt, funktioniert die Fensterfixierung immer nur im aktiven Blatt. Und man kann auch in VBA nicht mit einem Verweis auf ein Blatt arbeiten, sondern muss expliziet das aktive Blatt ansprechen.
(warum das alles so ist, können eventuell die Cracks hier beantworten, ich weiß es nicht)

D.h. Dein Code müsste wie folgt aussehen:

Code:

Worksheets(DateStr & TimeStr).Activate
Worksheets(DateStr & TimeStr).Range("A18").Select
ActiveWindow.FreezePanes = True

Zusätzlich müssen noch zwei Bedingungen erfüllt sein:
1. darf der Blattschutz nicht aktiviert sein
2. darf in diesem Blatt nicht schon eine Fensterfixierung vorhanden sein. In diesem Fall müsste sei erst aufgehoben werden.

letzteres könnte man wie folgt automatisch lösen:

Code:

Worksheets(DateStr & TimeStr).Activate
If ActiveWindow.FreezePanes = True Then ActiveWindow.FreezePanes = False
Worksheets(DateStr & TimeStr).Range("A18").Select
ActiveWindow.FreezePanes = True

Ich hoffe geholfen zu haben.

 

Grüezi zusammen

Nur noch eine kleine Ergänzung - da die Fixierung eine Methode des aktiven Fensters ist muss das Fenster zuvor eben aktiv gemacht werden um die Fixierung zu setzen.

Anschliessend aber gibt es noch eine Methode die kein Selektieren der zu fixierenden Zelle erfordert:

Code:

Sub Fenster_fixieren()
    'Ohne .Select das Fenster fixieren

Dim rngZelle             As Range
Set rngZelle = Range("C3")     'oberhalb und links der Zelle wird fixiert

    With ActiveWindow
        .SplitRow = rngZelle.Row
        .SplitColumn = rngZelle.Column
        .FreezePanes = True
    End With
End Sub

 

Morgen, danke für die Antwort/Lösung... funktioniert perfekt......

Schönen Tag TF

 

Hallo Thomas,

danke für Deine Ergänzung.
Auf den Trick, erst das Fenster zu splitten, und dann die Bereiche festzusetzen, wäre ich wohl nie gekommen.

Allerdings, wenn ich Deinen Code ausprobiere, wird die Trennlinie nicht links-oben der angegebenen Zelle gesetzt, sondern rechts-unten.
Da hat MS wohl nicht wirklich konsequent das gleiche Konzept verfolgt, will mir scheinen.

 

Grüezi Achim

Ich habe das auch erstmal rausgefunden als ich nach einem Weg gesucht habe, die Selektierung zu vermeiden.

Allerdings wird sehr wohl oben und links geteilt - das ist hier nur ein Problem in meinem Code, der so ergänzt gehört:

Code:

Sub Fenster_fixieren()
    'Ohne .Select das Fenster fixieren

Dim rngZelle             As Range
Set rngZelle = Range("C3")     'oberhalb und links der Zelle wird fixiert

    With ActiveWindow
        .SplitRow = rngZelle.Row - 1
        .SplitColumn = rngZelle.Column - 1
        .FreezePanes = True
    End With
End Sub