Office: Zellenvergleichen

Hallo zusammen,
ich stehe leider vor ein kleines Problem.
Ich möchte in Excel (O365) zwei Zellen vergleich.
Folgende Varianten gibt es:
a) In J4 und K4 steht kein Datum / Ergebnis "Zeige nichts an"
b) In J4 steht ein Datum und in K4 steht kein Datum / Ergebnis "Zeige eine 1" an
c) In J4 steht kein Datum und in K4 steht ein Datum / Ergebnis "Zeige eine 2" an
d) In J4 steht ein Datum und in K4 steht ein Datum / Ergebnis "Zeige eine 3" an

Das Datum muss jedoch nicht verglichen werden. Es ist nur ein Wert.

Ich hoffe ihr könnt mir irgendwie weiterhelfen.

Vielen Dank schon mal im Voraus
Gruß Stefan

 

Hola,

auf die Schnelle:
=WENN(ANZAHL2(J4:K4)=1;VERGLEICH(WAHR;INDEX(J4:K4<>"";0);0);WENN(UND(J4="";K4="");"";3))
Gruß,
steve1da

 

Moin

Code:

=WENNFEHLER(1/(1/MMULT(--ISTZAHL(J4:K4);{1;2}));"")

 

Hallo,

falls die Texte mit angezeigt werden sollen ("Zeige nichts an"/"Zeige eine N"):
="Zeige " & WENNFEHLER("eine " &1/(1/SUMME(ISTZAHL(J4:K4)*{1.2}));"nichts an")

 

Hallo,

setzt man die "LET"-Funktion ein (die eingedeutscht angeblich künftig "SEI" heißen soll):
=LET(Z;SUMME(ISTZAHL(J4:K4)*{1.2});"Zeige "&WENN(Z;"eine "&Z;"nichts an"))

 

Hallo zusammen,
ganz lieben Dank. Ihr habt mir sehr weitergeholfen.

Lg
Stefan