Office: (Office 2016) Excel Termin in Outlook Kalender

Hallo zusammen,
ich habe mal wieder ein Problem das ich schlicht und ergreifend nicht gelöst bekomme.
Leider bin ich in VBA ein absoluter Neuling.
Beverly hier aus dem Forum hat mir mit einem (Muster)Programmierung geschickt, siehe hier runter, , leider zeigt es mir da einen Fehler in der ersten Zeile der Prgrammierung an.
Code:
Sub OutlookEintrag()
Dim OutApp As Object, apptOutApp As Object
Set OutApp = CreateObject("Outlook.Application")
Set apptOutApp = OutApp.CreateItem(1)
With apptOutApp
' Beginn - in A1 steht das Datum und in D1 die Starzeit
.Start = Format(Range("A1"), "dd.mm.yyyy") & " " & Format(Range("D1"), "hh:mm")

' Dauer in Minuten wenn fix, dann keine Ende-Zeit erforderlich
' .Duration = 60

' Ende - in A1 steht das Datum und in D2 die Endzeit (nur erforderlich wenn Dauer nicht fix)
.End = Format(Range("A1"), "dd.mm.yyyy") & " " & Format(Range("D2"), "hh:mm")

' Betreff
.Subject = Range("B1")

' Notizen (optional)
.Body = "Dies ist ein Test"

'Ort des Termins (optional)
.Location = "Bei mir zu Hause"

'Kategorie zuschreiben (optional)
.Categories = "Bestellungen"

'Erinnerung setzen (optional)
.ReminderSet = True

'Anzahl Minuten, bei welcher die Erinnerung vor dem Termin erscheint (nur wenn ReminderSet = True)
.ReminderMinutesBeforeStart = 10

'Wird Erinnerungston abgespielt (nur wenn ReminderSet = True)
' .ReminderPlaySound = True

' Eintrag speichern
.Save

'Termin öffnen in Outlook (optional)
' .Display
End With
Set apptOutApp = Nothing
Set OutApp = Nothing
End Sub


Es wäre super nett wenn sich das jemand von euch, der deutlich mehr Ahnung hat als ich, anschauen könnte.

Ich wünsche euch frohe Ostern und ein langes erholsames Wochenende.

Gruß Franky

 

Hi Franky,

wenn du dir meinen Code und den in deiner Mappe genau anschaust wirst du erkennen, dass beide nicht übereinstimmen - und zwar bei allen Zeilen innerhalb der With-Anweisung:

Code:

    With apptOutApp
       .Start = Format(Range("G6"), "dd.mm.yyyy") & " " & Format(Range("F6"), "hh:mm")
       .Duration = 60
       .Subject = Range("G4")
       .Body = "TÜV fällig!"
       .Location = "Raiffeisenstraße 7 in 77933 Lahr"
       .Categories = "Fahrzeugüberwachung"
       .ReminderSet = True
       .ReminderMinutesBeforeStart = 20
       .ReminderPlaySound = True
       .Save
       .Display
    End With

Alle Befehle befinden sich innerhalb eine With-Anweisung, weshalb sie mit einem vorangestellten Punkt . versehen sein müssen, um ihre Zugehörigkeit zu dem in der With-Zeile aufgeführten Objekt (hier apptOutApp) zu kennzeichnen - dieser Punkt fehlt bei dir in allen Zeilen.

---

 

Guten Morgen Karin, guten morgen zusammen,

ja, ich wusste tatsächlich nicht ob die Punkte, vorangesetzt, oder der Aufzählung dienen.
Ich habe die Punkte jetzt gesetzt, allerdings bringt er mir den folgenden Fehler, siehe Bild, und die obere Zeile "SUB OutlookEintrag()" wird gelb markiert, keine Ahnung was die beiden Fehler zu bedeuten haben

Danke und viele Grüße

Franky

 

Hi Franky,

der Code gehört nicht unter DieseArbeitsmappe sondern in ein Standardmodul.

---

 

Hallo Karin,
hab ich in ein Standard Modul gepackt, einen Fehler habe ich leider immer noch,
diesmal einen anderen Fehler.
Das mit der VBA Programmierung ist wirklcih ein Buch mit sieben Siegeln.

Gruß Franky

 

Hi Franky,

und was sagt der Debugger genau? Also nicht nur die Fehlernummer sondern den gesamten Text.

---

 

Hi Karin,
er markiert mir mehrer Zeilen gelb, und dann kam der Fehler siehe Bild, beim Eintrag
.Subject = Range ("G6").

Gruß Franky

 

Guten Morgen Karin, guten Morgen zusammen,
ich bekomme es leider nicht hin, keine Chance trotz das ich verschiedene Dinge versucht habe, wie verbunde Zellen und Spalten zu löschen, Spalten verschieben usw.
Beim Debuggen kommt nur Laufzeitfehler und die gelb markierte Zeile, siehe Foto.

Hat von euch noch jemand eine Idee?

 

in A1 und D1 steht kein Datum

 

Hi Franky,

das ist doch logisch dass da ein Fehler kommt - mit .Start ist die Startzeit gemeint (siehe Kommentare in meinem ursprünglichen Code!!), bei dir steht jedoch in A1 ein Text. Mit ein wenig Nachdenken und Beibehalten der Kommentare - die ich bewusst eingefügt hatte und nicht deshalb, damit du sie einfach weglassen bzw. ignorieren sollst - hättest du selbst daruf kommen können

---

 

Hi,

nun ja, die Fehlermeldung ist etwas irreführend. Aber welche Startzeit soll deiner Meinung nach der Eintrag "TÜV/HU:", der in A1 steht, ergeben? Kein Wunder macht da Excel die Grätsche.

 

Du willst doch sicher alle Termine eintragen und nicht aus Versehen auch noch mehrfach oder?
Sieh dir mal meinen Vorschlag an. Und nicht die Spalte i übersehen.

 

Hallo Karin, hallo zusammen

ich hatte den Code schon entsprechend abgeändert das auch diese betitelt werden wo ein Datum und Uhrzeit drin steht.

Und ich wusste auch nicht das ich deine Informationen im Code stehen lassen kann.

Allerdings kam der/die Fehler immer noch.

Ich habe auch versucht, gearde die TÜV überfälligen Datums über ein WENN/DANN Formel in eine neue Spalte zu bekommen um diese Datum dann fürs VBA zu verwenden, allerdings bekomme ich gerade nicht mal das hin.


So meine Birne platzt bald, jetzt blicke ich dann überhaupt nichts mehr.
Wenn ich mich bisschen erholt habe versuche ich es nochmal.

Schönen Mittag zusammen.

Gruß Franky

 

Hi Franky,

der Code in deiner hochgeladenen Mappe soll das Datum aus A1 und die Uhrzeit aus D1 nehmen und daraus das Startdatum einschließlich Startzeit für die Erinnerung zusammensetzen - und zwar in dieser Codezeile:

Code:

       .Start = Format(Range("A1"), "dd.mm.yyyy") & " " & Format(Range("D1"), "hh:mm")

In A1 steht aber kein Datum (sondern anscheinend der Betreff für den Termin) und deshalb kommt bei dir die Fehlermeldung in genau dieser Codezeile.

Ein Datum steht dagegen z.B. in A3 und die Uhrzeit in D3 und allen weiteren Zeilen.
Wenn du alle Termine auf einen Ritt eintragen willst, dann kannst du das mit folgendem Code machen:

Code:

Sub OutlookEintrag()
    Dim OutApp As Object, apptOutApp As Object
    Dim lngZeile As Long
    Set OutApp = CreateObject("Outlook.Application")
    For lngZeile = 3 To Cells(Rows.Count, 1).End(xlUp).Row
        ' nur eintragen wenn das Datum größer als das aktuelle Datum
        If Cells(lngZeile, 1) > Date Then
            Set apptOutApp = OutApp.CreateItem(1)
            With apptOutApp
               .Start = Format(Cells(lngZeile, 1), "dd.mm.yyyy") & " " & Format(Cells(lngZeile, 4), "hh:mm")
               .Subject = Range("A1")
               .Body = "TÜV fällig!"
               .Location = "Raiffeisenstraße 7 in 77933 Lahr"
               .Categories = "Fahrzeugüberwachung"
               .ReminderSet = True
               .ReminderMinutesBeforeStart = 20
               .ReminderPlaySound = True
               .Save
               .Display
            End With
            Set apptOutApp = Nothing
        End If
    Next lngZeile
    Set OutApp = Nothing
End Sub

Unberücksichtigt bleiben dabei alle Termine, deren Datum vor dem jeweils aktuellen Datum liegen.


Übrigens: Kommentare schreibt man in einen Code, damit man auch später noch weiß, was der Code an einer bestimmten Stelle machen soll. Und dadurch, dass man diese Zeile(n) mit einem ' auskommentiert erkennt Excel, dass es sich dabei um keinen Code sondern einen Kommentar (oder anderen Text) handelt.

---

 

vielleicht raucht deine Birne auch nur weil du nicht mehr blickst in welchen Foren du deine Fragen platziert hast.
Informiere dich über Crossposting und was deswegen von dir erwartet wird.
für alle Anderen im vbaForum: VBA-Forum - Das Forum zu Microsoft VBA