Office: VBA Ausführung trotz Blattschutz

Ich habe eine Excel Tabelle mit mehreren Arbeitsblättern. Dort sollen teilweise eingaben möglich sein.

Unter anderem habe ich ein Arbeitsblatt bei dem nach einer Eingabe über eine Sortierung (VBA Programmierung) die Zeilen automatisch sortiert werden, das funktioniert auch so weit. Nun ist aber das Problem dass, sobald ich das Arbeitsblatt schütze von VBA die meldung erscheint dass der Befehl nicht ausgefürt werden kann.

Wie kann ich das vermeiden?

Vielen Dank schon mal für eure Hilfe

 

Hallo McCallion,

probiers mal so:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("B:B")) Is Nothing Then
me.unprotect
Range("B1").CurrentRegion.Sort Key1:=Range("A1"), Order1:=xlAscending, _
key2:=Range("B1"), order2:=xlAscending, _
Header:=xlYes
me.protect
End If
End Sub

Die 3. Zeile hebt den Blattschutz auf, die drittletzte aktiviert ihn wieder.
"Me" ist dabei die Referenzierung auf das Arbeitsblatt, in dessen Modul dieser Code steht.


Ich hoffe geholfen zu haben.

 

Hallo fette Elfe,

du hast mir teilweise geholfen.

Bei dieser Art muss ich aber das Kennwort für den Blattschutz eingeben.

Das Problem ist dass ich die Tabelle an verschiedene Leute senden muss. Die sollen das Passwort für den Blattschutz aber nicht bekommen.

Gibt es eine alternative die mir für diesen VBA Quellcode den schutz automatisch aufhebt ohne dass ich das PW eingeben muss?

So long

 

Hallo,

Du musst nur das PW inter Protect/ unprotect eintragen:

Code:

me.Protect("PW")

Gruß

Edgar

 

Gibt es auch eine möglichkeit das PW verschlüsselt ein zu geben, sonst kann sich ja jeder den quellcode anzeigen lassen und hat somit das PW.

 

Nicht dass ich wüsste, aber Du kannst das VBA Projekt mit einem Passwort versehen, so dass man sich den Quellcode nicht anschauen kann.

Dazu im VBA Editor einen rechtsklick auf das Modul machen in dem das Makro steht und dann unter Eigenschaften ein Passwort hinterlegen.

 

Probier mal so:

Das funktioniert normalerweise nicht. Du kannst Excel aber austricksen.
-Bevor Du auf Blattschützen stellst, blendest Du die Filter ein.
-Dann schützt Du das Blatt
-Jetzt folgendes Makro in VBA unter "DieseArbeitsmappe"
-Datei speichern und schließen. WICHTIG!!! erst beim nächsten
Dateiaufruf kannst du beide Funktionen benutzen:


ohne Passwort, Code so:


Sub Workbook_Open()

ActiveSheet.Protect userinterfaceonly:=True

ActiveSheet.EnableOutlining = True 'für Gliederung

ActiveSheet.EnableAutoFilter = True 'für Autofilter

End Sub



Falls du es Passwortgeschützt hast, dann Code so:


Sub Workbook_Open()

ActiveSheet.Protect userinterfaceonly:=True, Password:="Passwort"

ActiveSheet.EnableOutlining = True 'für Gliederung

ActiveSheet.EnableAutoFilter = True 'für Autofilter

End Sub



und wenn mehrere Blätter in einer Datei, dann Code so:


Private Sub Workbook_Open()
For Sh = 1 To Sheets.Count

With Sheets(Sh)

.Protect userInterfaceOnly:=True, Password:="Passwort"

.EnableOutlining = True 'für Gliederung

.EnableAutoFilter = True 'für Autofilter

End With
Next
End Sub


Hoffe ich konnte helfen! :lol: