Office: (Office 2016) In den Zellen G6 bis I6 darf nur ein x gemacht sein!

Hallo ich bin Neu,

und habe folgendes Problem:

ich möchte eine Auswahl treffen, dass heißt in den Zellen G6; H6 und I6 darf nur in einer Zelle nur ein X stehen.

Wenn ich in G6 ein "x" mache dann darf ich in H6 sowie I6 kein "x" machen können!

Ich hab schon versucht über Datenprüfung das zu machen, bekomme es aber nicht hin.

Wäre super wenn mir jemand helfen kann....

Grüße euer Weismänn

 

Hola,

=zählenwenn($G$6:$I$6;"x")<2

Gruß,
steve1da

 

steve1da,

ich werde Verrückt...es Funktioniert :-)

Vielen Dank

 

Hallo steve1da,

ich hab mich leider zu früh gefreut, wenn ich das "x" Manuell mit der Tastatur eingebe und Return drücke geht es,

aber ich habe eine Programierung über VB gemacht, dass heißt mit einem klick in die Zelle ensteht ein "x"

und damit funktioniert es leider nicht...hast du vielleicht noch eine Idee?

Grüße Weismänn

 

Hi,

Code:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Intersect(Target, Range("C6:E6")) Is Nothing Then Exit Sub
    If Application.CountIf(Range("C6:E6"), "x") > 0 Then
        MsgBox "Bereits eingetragen"
    Else
        Target = "x"
    End If
End Sub

Bis später,
Karin

 

Hallo Karin,

Danke dir zuerst mal...

jetzt habe ich das Problem, wenn ich das "X" wieder entfernen will (wenn ich mich verklickt habe) mit einem klick

dann muss ich über die Tastatur mit entfernen löschen!

Wäre es möglich das es wie in meiner Liste (Programierung_x) die ich Angehängt habe geht?...Klick "x" wird ein x erzeugt

und wieder klick "x" und das x wird wieder entfernt.

Grüße Weismänn

 

Hi,

ich würde an deiner Stelle besser das Doppelklick-Ereignis verwenden, denn beim Klick in die Zelle hat man sich leicht vertan - beim Doppelklick dagegen hat man ausreichend Zeit zu überlegen was man tut

Code:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Intersect(Target, Range("C6:E6")) Is Nothing Then Exit Sub
    Cancel = True
    If Application.CountIf(Range("C6:E6"), "x") > 0 Then
        If Target.Value = "x" Then
            Target.ClearContents
        Else
            MsgBox "Bereits eingetragen"
        End If
    Else
        Target = "x"
    End If
End Sub

Bis später,
Karin

 

Hallo Karin,

Lieben Dank, da meine Kollegen sich nun schon daran gewöhnt haben nur einen Klick zu machen...
und du weißt ja wie das ist mit dem umgewöhnen.

Wie würde es aussehen wenn man nur einen Klick machen soll?

Danke für deine schnelle Hilfe

Grüße Weismänn

 

Hi,

dann erziehe deine Kollegen entsprechend zur Sicherheit im Umgang mit Excel - man muss ja nicht unbedingt Fehleranfälligkeit unterstützen... :p

Der Code müsste genau so aussehen, nur anstelle Doppelklick- eben SelectionChange-Ereignis und Cancel = True löschen.

Bis später,
Karin

 

Hallo Karin,

DANKE...aber ich glaube du hast recht!!

Ich werde die Listen so Umstellen mit einem Doppelklick.

Danke noch mal für deine tolle Hilfe :-)

Grüße Weismänn

 

Hallo Karin,

nun hab ich noch ein Problem...schau dir mal meine neue Excel-liste an...

ich bekomme es einfach nicht hin!! Bin aber auch kein Profi wie du.

Wär super wenn du mir dabei noch helfen könntest.

Grüße Weimänn

 

Hi,

und welches ist das Problem? Das kann man doch schon mal hier im Beitrag beschreiben ohne dass man dazu die Mappe herunterladen muss...

Bis später,
Karin

 

Hallo Karin,

ich dachte es wär einfacher zu verstehen...

Ich möchte von Zeile C6:F6; C7:F7; C8:F8 usw bis C29:F29 nur ein"x" gemacht werden kann und

G6:I6; G7:I7; G8:I8 usw bis G29:I29 nur ein "x" gemacht werden kann...hoffe ich hab es verständlich rüber gebracht.

Grüße Weimänn

 

Hi,

dann so

Code:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Not Intersect(Target, Range("C6:F29")) Is Nothing Then
        Cancel = True
        If Application.CountIf(Range(Cells(Target.Row, 3), Cells(Target.Row, 6)), "X") > 0 Then
            If Target.Value = "X" Then
                Target.ClearContents
            Else
                MsgBox "Nur ein Kreuz möglich!"
            End If
        Else
            Target = "X"
        End If
    ElseIf Not Intersect(Target, Range("G6:I29")) Is Nothing Then
        Cancel = True
        If Application.CountIf(Range(Cells(Target.Row, 7), Cells(Target.Row, 9)), "X") > 0 Then
            If Target.Value = "X" Then
                Target.ClearContents
            Else
                MsgBox "Nur ein Kreuz möglich!"
            End If
        Else
            Target = "X"
        End If
    End If
End Sub

Bis später,
Karin

 

Hallo Karin,

vielen vielen DANK genau das wollte ich...ich bin schwer begeistert...

Grüße Weismänn