Office: (Office 2010) Wenn-Funktion ersetzen oder vereinfachen

Hallo liebe Community,

ich habe ein Problem mit der Wenn-Funktion von Excel!
Und zwar moechte ich gerne Datumswerte wie z.B. 708 was fuer 8.Juli steht, mit einer Funktion aendern lassen in den Tag des Jahres, also in diesem Fall auf 189...
ich habe jetzt eine Wenn-Funktion erstellt in der einfach jeder Monat 30 Tage hat, nur wuerde ich gerne mit den genauen Tagen rechnen.
Das Datumsformat zu veraendern geht nicht da diese in fuer ein Programm genauso gebraucht werden und fuer Schaltjahre muss man eigentlich nur eine Zahl aendern wenn es soweit ist...

Hier ist die Formel wenn ich mit 30 Tagen rechne:
=WENN(B9>100;SUMME((((WENN(B9>1000;LINKS(B9;2); LINKS(B9;1)))-1)*30);RECHTS(B9;2));"")

(und koennte sein das da ein paar unnoetige Klammern in der Formel sind, habe beim erstellen irgendwie den Ueberblick verloren)

ich wuerde gerne mit jedem Monat rechnen, also wenn die erste Stelle 1 ist rechnet er nichts dazu, wenn sie 2 ist dann 31 Tage, wenn 3 dann 59 Tage, usw. und dann addiert er die letzten 2. Stellen dazu, sodass der x-te Tag im Jahr herauskommt. Dadurch würde ich aber zuviele Wenn-Funktionen verschachteln....

Gehe ich das ganze zu kompliziert an und es gibt einen einfacheren Weg oder habt ihr eine Idee wie man es mit Wenn-Funktionen loesen kann?
Achja ich wuerde das ganze gerne nur mit Bezug auf die original Zelle loesen ohne zusaetzliche Bezuege auf Hilfs-Tabellen.

Vielen Dank jetzt schon mal!!!

LG nikoleila

 

Hola,

du hast also ein Datum, 708, und das soll in 189 geändert werden? Was ist mit anderen Daten, sollen alle auf 189 geändert werden? Was ist der Sinn dahinter?

Gruß,
steve1da

 

Hallo,

das Datum war nur ein Beispiel, ich habe Daten mit entweder MTT oder MMTT wie z.B. 706 -> 6.Juli, 316 -> 16.März, 1105-> 5.November. Welche mit einer Formel auf den jeweiligen Tag des Jahres geändert werden sollen. In den eben genannten Beispielen wären das der 187., der 75. und der 309. Tag seit Beginn des Jahres. Der Sinn dahinter ist eigentlich das ich mit den berechneten Tagen, dann weitere Berechnungen anstellen kann. Das einfachste Beispiel ist der Mittelwert: bei 29.Juni -> 629 und 1.Juli->701 ergibt dieser mit 665 keinen Sinn mehr.... . Deshalb würde ich gerne mit den Tagen rechnen.

LG nikoleila

 

Hola,

dann schau mal hier:

http://www.excelformeln.de/formeln.html?welcher=253

Gruß,
steve1da

 

Danke schon mal für die Antwort!!

So etwas habe ich auch schon angesehen, aber dafür müsste ein Jahr dabei stehen bzw. ich das Datumsformat vorher schon ändern....
Oder kann man die Tag-Funktion irgendwie an mein Format anpassen?

LG nikoleila

 

Hola,

wenn deine Werte in Spalte A stehen, kann man so ein Datum daraus machen:

Code:

=DATUM(JAHR(HEUTE());WENN(LÄNGE(A1)=3;LINKS(A1;1)*1;LINKS(A1;2)*1);RECHTS(A1;2)*1)

Gruß,
steve1da

 

Hallo,

danke jetzt ist mir wirklich geholfen, ich werde noch ein bisschen weitertüffteln und versuchen es in eine Formel zu bekommen,
aber jetzt bin ich schon viel weiter als vorher! DANKE :)

LG nikoleila

 

Hallo nochmal,

wollte nur mitteilen das ich es jetzt geschafft habe die Berechnung in nur einem Schritt durchzuführen! Also nochmal vielen Dank!!! und hier ist jetzt zum Abschluss nochmal die Formel dafür :) :) :)

=DATUM(JAHR(HEUTE());WENN(LÄNGE(A1)=3;LINKS(A1;1);LINKS(A1;2));RECHTS(A1;2))-DATUM(JAHR(DATUM(JAHR(HEUTE());WENN(LÄNGE(A1)=3;LINKS(A1;1);LINKS(A1;2));RECHTS(A1;2)));1;0)

LG nikoleila

 

Hallo,

folgende Formel müsste genauso funktionieren:

Code:

[COLOR="#0000CD"]=DATUM(JAHR(HEUTE());A1%;REST(A1;100))-DATUM(JAHR(HEUTE());1;0)[/COLOR]

 

Hallo Anton Exl,

danke für deine Antwort, hab jetzt doch deine Formel verwendet, weil es bei leeren Zellen keine #WERT!-Meldungen gibt bzw. habe ich noch eine Wenn-Funktion eingefügt damit bei leeren Zellen keine Negativwerte ausgegeben werden.

Eine Frage habe ich allerdings noch, kann man die Formel so umformen, dass ich nach z.B. Mittelwert-Berechnungen wieder das Originalformat erhalte? Habe gerade versucht die Formel zu verändern, aber mit Datums-Funktionen kenne ich mich nicht wirklich gut aus, von daher bis jetzt nur Fehlversuche....

LG nikoleila

 

Hallo,

meinst du damit, dass du aufgrund der laufenden Tageszahl innerhalb eines Jahres (=Ergebnisse obiger Formeln) wieder die Zahl im Format MTT haben möchtest?
Das müsste wie folgt möglich sein:

Code:

=TEXT(DATUM(JAHR(HEUTE());1;0)+A9;"MTT")*1

Der springende Punkt dabei ist die Behandlung eines eventuellen 29.2.JJJJ - erschwerend kommt hinzu, dass Microsoft im Excel-Arbeitsblatt fälschlicherweise einen 29.2.1900 kennt, die fortlaufende Tageszählung aber beim 1.1.1900 (= fortlaufender Tag 1) beginnt. Deshalb der etwas unelegant wirkende Umweg über die HEUTE()-Funktion.
Der Zusatz "*1" am Schluss bewirkt nur die automatische Konvertierung des Datumstextes "MTT" in die Datumszahl MTT.

 

Hallo,

Super danke!! Für meine Verhältnisse ist die Lösung mehr als elegant!! :P :)
Danke nochmal an euch beide für die schnelle und vor allem kompetente Hilfe!!

LG nikoleila