Office: Mini-Aggregat-Aufstellung (ähnlich Pivot) mit nur 1 Formel

Szenario 1: Einfache Aggregierung von Daten

A1:C9:

PHP:

Peter     12,00    04.05.2020
Martin    23,00    05.05.2020
Thorsten 129,00    05.05.2020
Peter     43,99    06.05.2020
Tobias    23,99    06.05.2020
Amelie    12,00    06.05.2020
Martin    23,99    07.05.2020
Elena    200,00    07.05.2020
Peter     12,49    07.05.2020

soll zu

PHP:

Peter     22,83
Martin    23,50
Thorsten 129,00
Tobias    23,99
Amelie    12,00
Elena    200,00

werden, zu Mehrfacheinträgen also der Mittelwert von B:B gebildet werden:

=WAHL({1.2};
EINDEUTIG($A1:INDEX($A:$A;ANZAHL2($A:$A)));MITTELWERTWENN($A1:$A999;
EINDEUTIG($A1:INDEX($A:$A;ANZAHL2($A:$A)));$B1:$B999))

oder auch mit LET

=LET(q;EINDEUTIG(A1:INDEX(A:A;ANZAHL2(A:A)));WAHL({1.2};q;MITTELWERTWENN(A1:A999;q;B1:B999)))

(benötigt XL365 oder XLWeb)

Quelle: Mittelwert gleicher Daten aus Tabelle
Variante mit 2 Kriterien und SUMMEWENNS: Hilfe bei Formel
___________________________________________________________

Szenario 2: Flatterdaten zählen und wandeln in Pivot-Quelle

A1:D9:

PHP:

Spalte1    Spalte 2    Spalte3    Spalte4
Apfel          
Banane    Apfel      
Kirsche    Banane    Melone    Pflaume
Kiwi          
Orange    Apfel      
Karotte          
Melone    Mandari      
Pflaume          


soll werden zu

PHP:

Spalte1    1
Apfel      3
Banane     2
Melone     2
Pflaume    2
Kirsche    1
Kiwi       1
Orange     1
Karotte    1
Mandari    1


Dazu kommt folgende dynamische Formel in G2 (Spalte A und Zeile 1 sind tabu):

=LET(
n;1;Quelle;"n=0: ab Zeile 1| n=1: ab Zeile 2 (ohne Überschriften)";
m;1;Ziel;"m=0: ohne Feldbezeichnung|m=1: mit Feldbezeichnung";
z;ANZAHL2(1:1);
y;ANZAHL2(A:A);
x;A1:INDEX(A:Z;y;z);
i;INDEX(x;SEQUENZ((y-n)*z-m;;z*(1+n)-m)/z;REST(SEQUENZ((y-n)*z-m;;0);z)+1);
j;FILTER(i;(i<>0));
k;EINDEUTIG(j);
WAHL({1.2};k;ZÄHLENWENN(x;k)))

angeregt durch: Excel2016 - Begriffe in einem Bereich zählen - MS-Office-Forum