Office: Ordner soll nach Speichern selber wieder schließen

Hallo zusammen.
ich habe ein Formular erstellt, das die Eingaben an eine Tabelle überträgt,
die Daten werden anschließend in eine 2 Datei kopiert
danach geht ein Fenster auf "speichern unter"

und nach speichern soll sich die Datei selbstständig schließen.

habe schon "Workbook.Close" versucht funktioniert nicht

hier ist der Ausschnitt:
Private Sub CommandButton5_Click()

Dim ws1 As Worksheet
Dim ws2 As Worksheet
Dim wb1 As Workbook
Dim wb2 As Workbook

Set wb1 = ThisWorkbook
Workbooks.Open Filename:="G:\Niehoff\Ausgabe"

Set wb2 = Workbooks("Ausgabe")
Set ws1 = wb1.Worksheets("Tabelle3")
Set ws2 = wb2.Worksheets("Tabelle1")
pos = 1

Application.ScreenUpdating = False

wb1.Activate
ws1.Select

With ws1
For n = 1 To ws1.Cells(65536, 1).End(xlUp).Row
If .Cells(n, 8) Like "" Then
.Cells(n, 8).EntireRow.Copy

wb2.Activate
ws2.Select

ActiveSheet.Cells(pos, 1).Select
ActiveSheet.Paste
wb1.Activate
.Select
pos = pos + 1
End If
Next n
End With


'Application.CutCopyMode = False

wb2.Activate
ws2.Select
Application.ScreenUpdating = True
ws2.Cells(1, 1).Select

'Speichern unter Mappe Ausgabe
Application.Dialogs(xlDialogSaveAs).ShowobjWorkbook.Close
hier sollte sich die Mappe Ausgabe wieder schließen

End Sub

viele Grüße
Rainer

:)

 

Hallo Raier,

schreibe Wb2.close True ' speichern, False nicht speichern.

 

Hallo Rainer,

ungetestet.

Private Sub CommandButton5_Click()
Dim ws1 As Worksheet, ws2 As Worksheet
Dim wb1 As Workbook, wb2 As Workbook
Dim lngPos As Long, lngIndex As Long
Dim vntRet As Variant
Dim lngCalc As Long

On Error GoTo ErrExit

With Application
.ScreenUpdating = False
.EnableEvents = False
lngCalc = .Calculation
.Calculation = xlCalculationManual
.DisplayAlerts = False
End With

Set wb1 = ThisWorkbook
Set wb2 = Workbooks.Open("G:\Niehoff\Ausgabe")

Set ws1 = wb1.Worksheets("Tabelle3")
Set ws2 = wb2.Worksheets("Tabelle1")

lngPos = 1

With ws1
For lngIndex = 1 To .Cells(.Rows.Count, 1).End(xlUp).Row
If .Cells(lngIndex, 8) = "" Then
.Rows(lngIndex).Copy ws2.Cells(lngPos, 1)
lngPos = lngPos + 1
End If
Next
End With

Application.Goto wb2.ws2.Cells(1, 1)

'Speichern unter Mappe Ausgabe
vntRet = Application.Dialogs(xlDialogSaveAs).Show

If vntRet Then wb2.Close True

ErrExit:

With Err
If .Number <> 0 Then
MsgBox "Fehler in Prozedur:" & vbTab & "'CommandButton5_Click'" & vbLf & String(60, "_") & _
vbLf & vbLf & IIf(Erl, "Fehler in Zeile:" & vbTab & Erl & vbLf & vbLf, "") & _
"Fehlernummer:" & vbTab & .Number & vbLf & vbLf & "Beschreibung:" & vbTab & _
.Description & vbLf, vbExclamation + vbMsgBoxSetForeground, _
"VBA - Fehler in Modul - Modul1"
.Clear
End If
End With

On Error GoTo 0

With Application
.ScreenUpdating = True
.EnableEvents = True
.Calculation = lngCalc
.DisplayAlerts = True
End With

Set wb1 = Nothing
Set wb2 = Nothing
Set ws1 = Nothing
Set ws2 = Nothing
End Sub





« Gruß Sepp »

 

Hallo Hajo,
Danke hat super funktioniert.

ch hab jetzt nur noch ein Problem und bin mir gar nicht sicher ob man es überhaupt einfach lösen kann.


In meinem Ordner sind die beiden Excel Dateien eine mit dem Namen
Eingabe und die andere Datei heißt Ausgabe.
Der Ordner und die beiden Dateien bleiben immer zusammen müssen aber auf unterschiedlichen Rechnern laufen.

Das Problem was ich habe:
in der 6 Zeile von oben steht:
Workbooks.Open Filename:="G:\Niehoff\Ausgabe"
Das Öffnen der Mappe "Ausgabe" bezieht sich jetzt auf meinen Rechner.

Kann man eine Beziehung zum Ordner "Eingabe" herstellen? Excel weiß ja von wo aus "Eingabe" geöffnet wurde.

Gruß
Rainer

 

Hallo Rainer,

ich hätte ThisWorkbook.Path gesehen.

 

Hallo Hajo,
steh gerade auf der Leitung,
kann nichts damit anfangen
Gruß
Rainer

 

Hallo Rainer,

ich hätte vermutet
Workbooks.Open Filename:=ThisWorkbook.Path & "\Ausgabe"
obwohl ich bei einer Datei immer den Dateityp angebe.

 

Hallo Hajo
perfekt, vielen Dank und noch einen schönen Sonntag
Gruß
Rainer

Ps. vielen Dank auch an Sepp