Office: (Office 2019) Probleme mit WENN(ODER - Verknüpfung

Hallo,

in den Spalten A und B sollen Ziffern stehen, wobei entweder A oder B ausgefüllt ist. In C soll in Anhängigkeit des Wertes in A oder B eine Auswertung gefahren werden:

Wenn A < 5 "niedrig" oder wenn B > 150 "niedrig"
Wenn A > 250 "hoch" oder wenn B < 50 "hoch"
liegt der Wert in A oder B zwischen den zuvor angegebenen Werten soll in C "mittel" erscheinen.

Problem: Obwohl in A die Ziffer 7 steht und B leer ist, wird "hoch" ausgegeben.

Beispieltabelle im Anhang. Irgendwo habe ich da ein Verständnisproblem in der Formel.

 

Hi,
eine leere Zelle wird von Excel bei mathematischen Berechnungen als 0 gewertet. Daher führt bei einem leeren B der Ausdruck B<50 zu WAHR. Das musst du noch abfangen:
=WENN(ODER(UND(A1<=5;A1<>"");B1>150);"niedrig";WENN(ODER(A1>250;UND(B1<50;B1<>""));"hoch";"mittel"))

bzw. da ich mit UND() und ODER() sozusagen auf Kriegsfuß stehe:
=WENN((A1<=5)*(A1<>"")+(B1>150);"niedrig";WENN((A1>250)+(B1<50)*(B1<>"");"hoch";"mittel"))

bzw. da ich verschachtelte WENN nicht mag:
=WENNS((A1<=5)*(A1<>"")+(B1>150);"niedrig";(A1>250)+(B1<50)*(B1<>"");"hoch";WAHR;"mittel")

 

Klasse, vielen Dank!
Wieder was dazugelernt :-)

 

Eine Frage hätte ich jetzt noch:

Wenn anstelle einer leeren Zelle in der Zelle "n.v." eingegeben wird funktioniert die Formel ja nicht mehr. Wie sähe dann die Anpassung aus? Ich versuche leere Zellen in dem Dokument zu vermeiden.

Danke schonmal vorab!

 

Hi,

mal überlegen, wenn man statt auf <>"" auf <>"n.v." prüfen wollte, wie könnte der Befehl dazu wohl lauten?

 

Ja, auf die Idee bin ich auch schon gekommen, allerdings wird, wenn ich z. B. die Ziffer 6 in A eingebe und in B n.v. als Ergebnis "niedrig" angezeigt, obwohl es "mittel" sein müssten.

=WENNS((A1<=5)*(A1<>"n.v.")+(B1>150);"niedrig";(A1>250)+(B1<50)*(B1<>"n.v.");"hoch";WAHR;"mittel")

 

Ah, hab‘ ich grade selbst nicht dran gedacht.
Jeder Buchstabe ist größer als die größte Zahl. Daher kann dann die Gegenprüfung bei kleiner entfallen und dafür muß dann eine entsprechende Prüfung bei größer mit rein. Also entweder (A1>250}*(A1<"A") oder (A1>250)*ISTZAHL(A1). Für B dann analog.

 

Danke, habe eben mein Glück versucht, aber der ausgabewert ist immer noch "niedrig" bei Werten > 5 in A.

Kannst du bitte mal drüberschauen:
=WENNS((A1>250)*ISTZAHL(A1)+(B1>150);"niedrig";(A1>250)+(B1<50)*ISTZAHL(B1);"hoch";WAHR;"mittel")

 

Schau nochmals über deine Bedingungen: war z.B. die Bed. für „niedrig“ nicht A1<=5 ??? etc.

 

Oh ja, mein Fehler... langer Tag heute.

=WENNS((A1<=5)*ISTZAHL(A1)+(B1>150);"niedrig";(A1>250)+(B1<50)*ISTZAHL(B1);"hoch";WAHR;"mittel")

Wenn A oder b mit einer Zahl gefüllt ist funktioniert die Formel, ist in A oder B "n.v." eingetragen stimmt die Ausgabe nicht.

 

Ich zitier mich mal selber…

 

Tut mir leid, ich schnall´s nicht.

 

=WENNS((A1<=5)+(B1>150)*ISTZAHL(B1);"niedrig";(A1>250)*ISTZAHL(A1)+(B1<50);"hoch";WAHR;"mittel")
Ist das sooo schwer???

 

Vielen Dank!

Um auf diene Frage zurückzukommen: wenn man täglich bzw. regelmäßig mit solchen Formeln umgeht, dann ist das sicherlich etwas einfacher als für jemanden, der mit dieser Art von Formeln vielleicht alle zwei Jahre zu tun hat.

Dennoch bin ich sehr dankbar für die Unterstützung in diesem Forum.