Office: (Office 365) Werte aus mehreren Spalten kopieren und darunter einfügen

Hallo zusammen,

leider konnte ich im Internet und auch in diesem Forum keine passende Antwort finden.

Ich habe eine .csv Datei, bei der ich mehrere Spalten habe. Es handelt sich hierbei um Buchhaltungsdaten.

Ich habe beispielsweise in den Spalten A bis G einen Wert stehen und dies in den Zeilen 2 bis 20. Nun möchte ich gerne diese Daten kopieren und jeweils darunter einfügen. Ich dachte hierbei daran, dass ich durch eine Hilfsspalte (H) eine Nummerierung erstelle, diese dann aufsteigend sortiere und somit eine leere Zeile zwischen jeder generiere. Dies hat zwar funktioniert, jedoch ist es sehr umständlich jeden Wert einzeln (also Wert aus A2 in A3, Wert aus B2 in B3 usw.) zu kopieren und darunter einzufügen.

IST Zustand:

Zeile 1 | 111 | 222 | 333
Zeile 2 | 444 | 555 | 666

SOLL Zustand:

Zeile 1 | 111 | 222 | 333
Zeile 2 | 111 | 222 | 333
Zeile 3 | 444 | 555 | 666
Zeile 4 | 444 | 555 | 666

Teilweise habe ich in einem Monat 100 Zeilen... hierbei geht es um die Vereinfachung für mich, sodass ich diese Datei dann einfach in das Buchhaltungsprogramm einspielen kann, ohne alles lästig abzutippen. Ich hoffe ich konnte mein Problem verständlich darstellen und würde mich über eine Hilfestellung freuen...

 

Hola,
dir wird doch schon geholfen. Warum wechselst du das Forum und teilst das nicht mit?
Werte aus mehreren Spalten kopieren und darunter einfügen | HERBERS Excel Forum
Gruß,
steve1da

 

Hallo,

in Zelle A3 des Arbeitsblattes "SOLL Zustand" folgende Formel eingeben/kopieren:
=LET(dt;'IST Zustand'!A3:C7;zl;ZEILEN(dt); dti; HSTAPELN(dt;SEQUENZ(zl)); dt2i; VSTAPELN(dti;dti); WEGLASSEN(SORTIEREN(dt2i;SPALTEN(dt2i));;-1))
Diese eine Formel genügt. Der fett geschriebene Formelteil muss natürlich den korrekten IST-Bereich darstellen (ohne Kopfzeile(n)).

Wenn du auch die Kopfzeile aus Zeile A1:C1 mit integriert haben möchtest, dann würde ich vorschlagen, die unnötige Leerzeile zwischen Kopf und Daten zu entfernen und folgende Formel zu verwenden
in Zelle A1 des Arbeitsblattes "SOLL Zustand":
=LET(udt; 'IST Zustand'!A1:C6; u; ZEILENWAHL(udt; 1); dt; WEGLASSEN(udt; 1); zl; ZEILEN(dt); dti; HSTAPELN(dt; SEQUENZ(zl)); dt2i; VSTAPELN(dti; dti); VSTAPELN(u; WEGLASSEN(SORTIEREN(dt2i; SPALTEN(dt2i)); ; -1)))

 

Hallo,
=LET(x;ZEILENUMBRUCH(ZUSPALTE(A1:C7;1);3);WEGLASSEN(INDEX(x;SEQUENZ(ZEILEN(x)*2;;;0,5);SEQUENZ(;3));1))

oder:
=LET(x;A3:C7;VSTAPELN(A1:C1;INDEX(x;SEQUENZ(RIJEN(x)*2;;;1/2);SEQUENZ(;SPALTEN(x)))))

 

Hallo,
RIJEN in meinem vorherigen Schreiben sollte natürlich ZEILEN sein

=LET(x;A3:C7;VSTAPELN(A1:C1;INDEX(x;SEQUENZ(ZEILEN(x)*2;;;1/2);SEQUENZ(;SPALTEN(x)))))

Ned-Deutsch.

Es kann aber auch:
=VSTAPELN(A1:C1;INDEX(A3:C7;SEQUENZ(ZEILEN(A3:A7)*2;;;0,5);SEQUENZ(;3)))

 

Hallo,

ich hab kein XL365.

Aber in jeder noch so alten XL-Version bedarf es dazu nur in kleinen Formel mit lediglich 3 Funktionen, die allerdings natürlich nicht spillt. D.h. nachfolgende Formel in SOLL Zustand'!A3 müßte einmalig entsprechend weit nach unten und rechts ziehend kopiert werden.
=INDEX('IST Zustand'!$A:$G;KÜRZEN(ZEILE(A2)/2;)+2;)

[Nachtrag:] natürlich müßte dann noch den Ergebnisspalten das entsprechende Datenformat zugewiesen werden