Office: Gruppierung verschwinden lassen

Hallo liebe Leuts,

ich habe in einer Tabelle mehrere Gruppierungen angewendet, sowohl bei Spalten als auch bei Zeilen.
Gibts es eine Möglichkeit die vielen "Plus" auszublenden und natürlich bei Bedarf wieder erscheinen zu lassen?
Ich möchte dadurch den nutzbaren sichtbaren Bereich vergrößern und natürlich sieht es ohne "Plus" rechts und links schöner aus.

Vielen Dank für Eure Hilfe.
Grüße Dhil

 

Hallo,

entweder Du willst gruppieren (dann musst Du auch mit den + im Rand des Excel-Fensters leben) oder Du willst eben nicht gruppieren. Einen 3. Weg auf die Schnelle gibt es nicht (außer eventuell durch gezielte VBA-Programmierung).

Ich verstehe auch nicht wirklich, warum die + im Excel-Fensterrand stören - sie werden ohnehin nicht ausgedruckt, falls man das Blatt ausdruckt.

 

Aufheben einer Gliederung
Auf der Registerkarte Daten in der Gruppe Gliederung auf den Pfeil neben Gruppierung aufheben, und dann auf Gruppierung aufheben.
In dem Folgefenster wird nach Art der Gruppierung gefragt. "Zeilen oder Spalten" entsprechend auswählen.
Wenn die Gruppierung wieder sichtbar sein soll, den Button Gruppieren auswählen und die Option "Gruppieren". Wieder "Zeile oder Spalte" auswählen und die Gruppierung ist wieder sichtbar.

 

Hallo,

folgendes VBA-Makro zB. blendet ein/aus die Zeilen 7-9, die Spalten C-E und die Spalten L-O.
Es ist am besten in einem allgem. Codemodul zu speichern.
Aufgerufen kann das Makro über die Tastenkombination Alt-F8 werden.

Code:

Public Sub EinAusblenden()
  With ActiveSheet
    'Zeilen 7-9 ein/ausblenden
    With .Rows("7:9")
      .Hidden = Not .Item(1).Hidden
    End With
    'Spalten C-E ein/ausblenden
    With .Columns("C:E")
      .Hidden = Not .Item(1).Hidden
    End With
    'Spalten L-O ein/ausblenden
    With .Columns("L:O")
      .Hidden = Not .Item(1).Hidden
    End With
  End With
End Sub

 

Hallo,

habe nun beide Antworten ausprobiert:

Die Lösung von CCBFAQ lässt die Gruppierung verschwinden, jedoch sind die mit der Gruppierung verbunden Zeilen / Spalten dann wieder sichtbar.

Die von Exl121150 aufgeführte Lösung bewirkt dass die Gruppierung geöffnet wird und somit die hinter der Gruppierung liegenden Spalten / Zeilen ebenfalls sichtbar sind.

Ich hoffe, dass ich die Lösungen auch richtig angewendet habe und vielleicht habe ich mich jedoch auch nicht mit meiner Frage konkret genug ausgedrückt: Die Funktion der geschlossenen Gruppierung soll beibehalten werden, jedoch sollten die "Plus-Zeichen" nicht mehr sichtbar sein.

Werde wohl mit der Sichtbarkeit der "Plus-Zeichen" leben.
Besten Dank an CCBFAQ und Exl121150.

Mit Grüßen Dhil

 

Hallo,

mein VBA-Vorschlag wendet überhaupt keine Gruppierung an!! Daher kann auch keine Gruppierung geöffnet (?) werden.

Das, was mein Makro macht, ist das abwechslungsweise Ausblenden bzw. wieder Einblenden von im Makro angegebenen Zeilen (bzw. Spalten):
Beim 1. Mal Anwenden werden die Zeilen/Spalten ausgeblendet, beim 2. Mal Anwenden werden die Zeilen/Spalten wieder eingeblendet, beim 3. Mal Anwenden werden die Zeilen/Spalten ausgeblendet, usw.

Würde dagegen mein VBA-Makro eine Gruppierung ausführen, wären natürlich die Plus/Minus-Zeichen im Fensterrand des Excel-Arbeitsblattes zu sehen.
Diese +/- Zeichen kann man nicht unterdrücken, falls man das Mittel der Gruppierung einsetzt.

 

Hallo Exl121150,

danke für Deine Erläuterung, werde es nochmal versuchen, denn ich habe Deinen Makro in meine Datei mit schon vorhandenen Gruppierungen angewendet. Und diese sind dann mit dem Makro geöffnet worden .. ;-)

Grüß
Dhil

 

Hallo,

ich habe nun den von Exl121150 aufgeführte VBA-Vorschlag in meinen Tabellen eingebaut, und es funktioniert genau so, wie ich mir das gewünscht habe.

Vielen Dank an Exl121150


mit Grüßen
Dhil

 

Hallo zusammen

Hier ein paar Details zum Thema Gliederung/Gruppierung in Excel.

BG
Howdy

Code:

Sub pcdGruppierungen()

    Rem Gliederungssymbole ausblenden/anzeigen
    ActiveWindow.DisplayOutline = False
    ActiveWindow.DisplayOutline = True


    Rem Gruppierungen erstellen und löschen

    Rem Zeilengruppierungen erstellen, löschen und alle löschen
    ActiveSheet.Rows("10:15").Rows.Group
    ActiveSheet.Rows("10:15").Rows.Ungroup
    ActiveSheet.Rows.Ungroup
    
    Rem Spaltengruppierungen erstellen, löschen und alle löschen
    ActiveSheet.Columns("BG:BJ").Columns.Group
    ActiveSheet.Columns("BG:BJ").Columns.Ungroup
    ActiveSheet.Columns.Ungroup
    
    
    Rem Gruppierung erweitern (Detail anzeigen)
    
    Rem Alle Zeilen der Gliederungsstufe 2 anzeigen (Stufe kann 2-9 sein)
    ActiveSheet.Outline.ShowLevels RowLevels:=2
    Rem Alle Spalten der Gliederungsstufe 2 anzeigen (Stufe kann 2-9 sein)
    ActiveSheet.Outline.ShowLevels ColumnLevels:=2
    
    Rem Einzelne Zeilen Gruppierung erweitern (Beispiel für Gruppierung in Zeile 24)
    ActiveSheet.Rows(24).ShowDetail = True
    Rem Einzelne Spalten Gruppierung erweitern (Beispiel für Gruppierung in Spalte 3)
    ActiveSheet.Columns(3).ShowDetail = True

    
    Rem Gruppierung zuklappen (Detail ausblenden)
    
    Rem Die Zeilen aller Gruppierungen ausblenden
    ActiveSheet.Outline.ShowLevels RowLevels:=1
    Rem Die Spalten aller Gruppierungen ausblenden
    ActiveSheet.Outline.ShowLevels ColumnLevels:=1
    
    Rem Die Zeilen einzelner Gruppierungen zuklappen (Beispiel für Gruppierung in Zeile 24)
    ActiveSheet.Rows(24).ShowDetail = False
    Rem Die Spalten einzelner Gruppierungen zuklappen (Beispiel für Gruppierung in Spalte 3)
    ActiveSheet.Columns(3).ShowDetail = False

End Sub

 

Das ist meiner Ansicht nach nicht korrekt. Die +-Zeichen können mit folgender Zeile ausgeblendet werden:
ActiveWindow.DisplayOutline = False