Office: Wert in Zeile suchen

Hallo Zusammen,

ich habe folgendes Problem. (Eine Beispieldatei habe ich angehangen)

Ich hole mir verschiedene Werte für eine Bestellung (Tabelle1) aus einer Datenbank (Tabelle2).
Mit der Dropdown-Liste (D2) kann ich die verschiedenen Abmessungen des Artikels eintragen (Die Dropdown-Liste holt sich die Werte aus der Datenbank).
In der Zelle F6 (Tabelle1) soll nun, nachdem die Auswahl der Abmessung eingetragen ist, die entsprechende Anzahl der daraus entstehenden Teile erscheinen.
Beispiel: Wenn in D2 "10x20x2" steht, soll in F2 "2" erscheinen, bei 10x30x2, F2="3"...usw.
Da die Abmessung Dynamisch ist weiß ich leider nicht wie ich den entsprechenden Wert ausgeben kann.

Da die Spalte in der der gesuchte Wert immer die Spaltenummer der eingetragenen Abmessung +5 ist, dürfte es doch gar nicht so schwierig sein...
Gibt es eine Fuktion mit der ich einen bestimmten Wert in einer Zeile suchen kann und mir die Spaltennummer ausgibt?
Oder gibt es eine bessere Lösung?

Gruß
Weeezz

 

Hallo!

	D	E	F	G	H	I	J	K	L
1	Abmessung1	Abmessung2	Abmessung3	Abmessung4	Lieferant	Stk/Abm1	Stk/Abm2	Stk/Abm3	Stk/Abm4
2	10x20x2	10x30x2	10x40x2	10x50x2	ESX	2	3	4	5
3	15x15x3	18x17x3	20x22x4	10x15x4	Bolta	1	2	4	1
4	100x200x1,5	150x300x2,5	90x90x3		Kimsa	2	3	1
5	600x500x3	600x600x3	1000x1000x3	1200x1200x4	KMO	20	30	50	70
6	10x10x0,5	15x15x0,5	20x20x0,5	25x25x0,5	Balzuz	10	20	30	50
7
8
9		150x300x2,5	Dropdown-Werte (Abmessung)
10		3	Dazugehörige Stückzahl pro Abmessung

Zelle	Formel
E10	=INDEX(I2:L6;SUMMENPRODUKT((D2:G6=E9)*ZEILE(1:5));SUMMENPRODUKT((D2:G6=E9)*SPALTE(A:D)))

 

Nachtrag:
Da es sich ja um Zahlen handelt, die du suchst, geht's auch noch kürzer:
=SUMMENPRODUKT((D2:G6=E9)*I2:L6)
(Vorausgesetzt, dass dein Suchkriterium nur EINmalig auftaucht!)

 

Hi Schatzi,
Danke erstmal für Deine Antwort.
Ganz so einfach ist es leider nicht. Ich habe vergessen zu erwähnen, das ich sämtliche Daten
in Tabelle 1 aus der Datenbank hole.
Die Nummern in der ersten Spalte der Datenbank sind einmalig und die Datenbank kann bis zu 800 Datensätze enthalten und kann erweitert werden.
In der Tabelle 1 trage ich nur in der ersten Spalte z.B 1-001 ein und alle anderen Werte hole ich mir mittels INDEX oder SVERWEIS
aus Tabelle2. Alle Daten werden somit automatisch ausgefüllt.
In der Dropdown-Liste erscheinen dann auch nur die Abmessungen zu diesem Artikel. Die Formel hierfür
kann man sich im Namensmanager anschauen (Danke nochmal an Silex).
D.h. In Tabelle 1 steht nicht nur eine Zeile sondern viele untereinander (es gibt keine Begrenzung), und wenn ich einen neuen Eintrag vornehme,
passt sich die Dropdownliste an den vorhandene Abmessungen zu diesem Artikel an. Dementsprechen benötige ich eine Formel,
die sich den Wert nur aus der Zeile z.B. 1-001 oder 1-002.... in der Datenbank holt.
Ich habe die Datei mal vervollständigt. In den gelben Feldern in Tabelle 1 gibt man die Artikelnummer an und die Werte werden nun eingetragen.
Ich weiß nur ncht wie ich mir die Werte für die Stk/Abm hole :-/.

Gruß
Weeezz

 

Hallo!

In F2:

=SUMMEWENN(INDEX(Tabelle2!D:G;VERGLEICH(A2;Tabelle2!A:A;););D2;INDEX(Tabelle2!I:L;VERGLEICH(A2;Tabelle2!A:A;);))

 

Aber Hallo!!!!!! :-)
Fantastisch!! Danke für die Super-schnelle Lösung!
Anscheinend kann man mit INDEX und VRGLEICH so ziemlich alles erschlagen.
Ich hab noch ne Menge zu lernen :-/....

 

Hmmm... irgendwie klappt es in meiner Datei nicht.
Mein Wert ist immer 0, egal was ich eingebe.
Die Sytax und die Bereiche bzw. die Werte sind laut Funktionsmanager i.O.
Liegt es vielleicht daran, dass ich schon alle Werte in der Datenbank mit INDEX aus einer anderen Datei hole?

 

Hallo!

Ich würde mal tippen, dass die Werte für "Stk/Abm" in dieser anderen Datei nicht als ZAHL, sondern als TEXT vorliegen. Das kannst du mit der Funktion ISTZAHL, bzw. ISTTEXT prüfen.

 

Jupp, das war's :-).
Ich hab' noch eine andere Frage. Kann ich in Excel auch einen Teil einer Formel bzw. den Namen einer Tabelle in einer Formel aus einem Text und den Inhalt einer Zelle bilden?
Wenn ich mal die von dir erstellte Formel nehme:
"=SUMMEWENN(INDEX(Tabelle2!D:G;VERGLEICH(A2;Tabelle 2!A:A; ); );D2;INDEX(Tabelle2!I:L;VERGLEICH(A2;Tabel le2!A:A; ); ))"
Könnte ich z.B. die 2 in "Tabelle2" durch den Inhalt einer Zelle ersetzen?
Ich möchte die Möglichkeit haben, zwischen verschiedenen Tabellen wählen zu können, indem ich ein einer Zelle 1, 2 oder 3 eintrage und somit den Tabellennamen dynamisch gestalte.
Geht das?

Gruß
Weeezz

 

Hallo!

Ja, das geht mit der Funktion INDIREKT:

=SUMMEWENN(INDEX(INDIREKT("Tabelle"&X1&"!D:G");VERGLEICH(A2;INDIREKT("Tabelle"&X1&"!A:A");););D2;INDEX(INDIREKT("Tabelle"&X1&"!I:L");VERGLEICH(A2;INDIREKT("Tabelle"&X1&"!A:A"););))